在這篇博文中，我想分享現代 ABAP 中[正規表示式](https://blogs.sap.com/2021/09/23/regular-expressions-regex-in-modern-abap/)的最新訊息和變化，主要來自 OP 版本 7.55 和 7.56。

以前，在 ABAP 中使用 POSIX 樣式的正規表示式或“uniX 的行動式作業系統介面- POSIX 的全稱是 Portable Operating System Interface for uniX”。 因此，從現在開始，POSIX 語法中的正規表示式已過時，然後使用這種正規表示式語法會導致語法檢查警告。 雖然這可以被 pragma ##regex_posix 隱藏，但強烈建議遷移到 ABAP 支援的其他正規表示式語法，如 PCRE 正規表示式、XPath 正規表示式或 XSD 正規表示式。

# ABAP 正規表示式的回顧

正規表示式對於新使用者來說通常是複雜和令人生畏的。 在深入研究新功能之前，我想簡要介紹一下 RegEx，並展示用 ABAP 明確編寫的示例。 如果您是該主題的專家並且可能會感到無聊，請隨時跳過此部分。

RegEx 的概念已經存在了很長一段時間。當需要複雜的模式時使用它。 如搜尋數字、字母、特殊字元或驗證電子郵件等。許多文字搜尋和替換問題在不使用正規表示式模式匹配的情況下很難處理。 此外，在 ABAP 中，使用正規表示式的搜尋比傳統的 SAP 模式更強大。讓我們以這個簡單的例子為例：

```abap
 FIND 'A' IN 'ABCD1234EFG'
  MATCH COUNT sy-tabix.
  WRITE: sy-tabix.
```

現在，如果您想在不使用 RegEx 的情況下透過正常搜尋模式查詢字串中的所有字母，則需要對所有 26 個字元進行迴圈。 使用 RegEx，可以很容易地搜尋和找到所有七個字元：

```abap
FIND ALL OCCURRENCES OF PCRE '[A-Z]' IN 'ABCD1234EFG'
  MATCH COUNT  sy-tabix.
WRITE: sy-tabix.
```

ABAP 在語句 FIND 和 REPLACE 中以及透過類 CL_ABAP_REGEX 和 CL_ABAP_MATCHER 支援正規表示式。 CL_ABAP_MATCHER 類將使用 CL_ABAP_REGEX 生成的正規表示式應用於字串或內部表。

# Greedy or Lazy?

另一個可能有趣的概念是 RegEx 中貪婪或惰性量詞的含義。 在用 (*,+,...) 定義的貪婪模式中，量化字元被重複儘可能多的次數。 RegEx 引擎將盡可能多的字元新增到匹配中，然後一個一個地縮短，以防模式的其餘部分不匹配。 它的反面將被稱為懶惰模式，它匹配儘可能少的字元。 例如，在 ABAP 中，透過在 * , (.*?) 後面放置一個問號，您要求子表示式匹配儘可能少的字元。 正規表示式的預設行為是貪婪的（實際上 POSIX 意味著無法關閉的貪婪量詞）。

例子：

```abap
DATA(text) = `"Jack" and "Jill" went up the "hill"`.

FIND ALL OCCURRENCES OF PCRE  `"(.*?)"` IN text IGNORING CASE
    RESULTS DATA(result_tab).
IF sy-subrc = 0.
  LOOP AT result_tab ASSIGNING FIELD-SYMBOL(<result>).
    cl_demo_output=>write(  substring( val = text off = <result>-offset len = <result>-length )  ).
  ENDLOOP.
ENDIF.
cl_demo_output=>display( ).
```

貪婪符號“(.*)”將整個輸入句子作為輸出，而懶惰符號“(.*?)”給出三個單詞“Jack”、“Jill”、“hill”。 如果在懶惰的情況下省略表示式“ALL OCCURRENCES OF”，則只會找到第一個“和後面的”之間的子字串，即“Jack”。

直到 7.55 版本，ABAP 僅將 POSIX 庫用於 RegEx。 從那時起，也支援 Perl 庫。 兩個庫在計算匹配的方式上有很大不同。 由於 POSIX 已經過時，我們將在下文中使用 Perl 風格的正規表示式。 您可以透過在 AS ABAP 中執行報表 DEMO_REGEX 來嘗試使用 Regex 來嘗試不同的表示式。

![](https://img-blog.csdnimg.cn/img_convert/e1c80da5a005a8d6332d6c73842af4cf.png)

# PCRE Syntax

PCRE 庫是一組用 C 語言編寫的函式，它們使用與 Perl 5 相同的語法和語義實現正規表示式模式匹配，並擁有自己的原生 API。 PCRE 語法代表“Perl Compatible Regular Expressions”，比 POSIX 語法或許多其他正規表示式庫更強大、更靈活，並且比 ABAP 支援的 POSIX 正規表示式效能更好。

具有 PCRE 語法的 RegEx 可以在 FIND 和 REPLACE 語句的新增 PCRE 和字串的內建函式的引數 PCRE 之後指定。 PCRE 正規表示式的物件可以使用系統類 CL_ABAP_REGEX 的工廠方法 CREATE_PCRE 建立，用於語句 FIND 和 REPLACE 或使用系統類 CL_ABAP_MATCHER。

例子：

```abap
DATA(text) = `oooababboo`.

FIND PCRE 'a.|[ab]+|b.*' IN text
     MATCH OFFSET DATA(moff)
     MATCH LENGTH DATA(mlen).
IF sy-subrc = 0.
  cl_demo_output=>write( substring( val = text off = moff    len = mlen ) ).
ENDIF.
```

搜尋使用 PCRE 正規表示式語法並從偏移量 3 中找到長度為 2 的“ab”。但是，使用加法 REGEX 而不是 PCRE，搜尋會從偏移量 3 或更高的長度為 5 中找到子字串“abbabb”。

# Callouts in PCRE Regular Expressions

透過RegEx callouts，可以在正規表示式模式匹配過程中臨時將控制權交給函式。 PCRE 標註使用語法 (?C...) 指定，其中點代表可選引數。如果你在呼叫 PCRE 的匹配函式之前指定一個 callout 函式，每當引擎執行到 (?C...) 時，它會暫時掛起匹配並將控制權傳遞給那個 callout 函式，它提供有關匹配的資訊。然後呼叫函式執行它應該做的任何任務，然後它向引擎返回一個程式碼，讓它知道是否正常進行剩下的比賽。

在 ABAP 中，PCRE 語法支援在將正規表示式與 CL_ABAP_MATCHER 匹配期間呼叫 ABAP 方法的標註。當執行方法 MATCH 時，PCRE 正規表示式的特殊字元 (?C...) 然後呼叫介面方法 CALLOUT。該示例演示瞭如何從 PCRE 正規表示式呼叫 ABAP 方法。

```abap
REPORT demo_pcre_callout.

CLASS handle_regex DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_abap_matcher_callout.
ENDCLASS.

CLASS handle_regex IMPLEMENTATION.
  METHOD if_abap_matcher_callout~callout.
    cl_demo_output=>write( |{ callout_num } { callout_string }| ).
  ENDMETHOD.
ENDCLASS.

CLASS demo_pcre DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS main.
ENDCLASS.

CLASS demo_pcre IMPLEMENTATION.
  METHOD main.
    DATA(regex) = cl_abap_regex=>create_pcre(
      pattern = `a(?C1)b(?C2)c(?C3)d(?C"D")e(?C"E")` ).

DATA(matcher) = regex->create_matcher( text = `abcde` ).

DATA(handler) = NEW handle_regex( ).
    matcher->set_callout( handler ).
    matcher->match( ).

cl_demo_output=>display( ).
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  demo_pcre=>main( ).
```

正規表示式包含用於標註的特殊字元 (?C...)。 前三個標註傳遞數字資料，其他兩個傳遞字串資料。

本地類“handle_regex”實現介面 IF_ABAP_MATCHER_CALLOUT 並且該類的例項被設定為標註處理程式。 當正規表示式匹配到時，每個callout位置都會呼叫介面方法CALLOUT，可以訪問傳入的引數。

# PCRE syntax for ABAP SQL and ABAP CDS

ABAP SQL 和 ABAP CDS 還透過內建函式 REPLACE_REGEXPR、LIKE_REGEXPR 和 OCCURRENCES_REGEXPR 支援 PCRE 語法。 這些函式訪問在 SAP HANA 資料庫中實現的 PCRE1 庫。 一般 ABAP 的正規表示式與 ABAP 核心中實現的 PCRE2 庫一起使用。

# CDS View Entity

此 SQL 函式在字串中搜尋正規表示式模式，並返回該字串，其中包含使用 CDS 檢視實體中的替換字串替換的正規表示式模式的一次或每次出現。

```abap
REPLACE_REGEXPR(PCRE => pcre,
                VALUE => arg1,
                WITH => arg2,
                RESULT_LENGTH => res[,
                OCCURRENCE => occ][,
                CASE_SENSITIVE => case][,
                SINGLE_LINE => bool][,
                MULTI_LINE => bool][,
                UNGREEDY => bool])
```

以下 CDS 檢視實體將 SELECT 列表中的字串的內建 SQL 函式應用於 DDIC 資料庫表 SPFLI 的列，以使用轉換值替換 MI 到 KM 的距離 id。

```sql
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view entity ZI_regex_test

as select from spfli

{

concat_with_space( cityfrom, cityto, 4    )    as from_City_to,

distance                                       as Distance,

distid                                         as DistanceId,

case

when distid = 'MI' then

replace_regexpr(   pcre => '[^ distid,

with => '1.6 KM',

result_length => 6  )

else 'KM'

end as DistanceIdInKM

}
```

# SQL Expressions

ABAP SQL 現在支援一些新的正則處理功能。

本示例從 spfli 表中選擇來自柏林或東京的航班，並將它們放在 lt_table 中。

```abap
SELECT * FROM spfli
   WHERE
      like_regexpr( pcre = '\bBERLIN\b|\bTOKYO\b', value = cityfrom ) = '1'
   INTO @ls_table.
   APPEND ls_table TO lt_table.
ENDSELECT.
```

以下示例使用正規表示式替換從東京到 Neapel 的航班的目的地“羅馬”。

```abap
SELECT
  carrid as Airline,
  connid as flightNo,
  deptime as Departure_time,
  cityfrom as Departure,
  replace_regexpr( pcre = '\bROME\b', value = cityto , with = 'Neapel' ) as Destination
  from spfli where cityfrom = 'TOKYO'  
  into TABLE @data(lt_replace) .

```

並非所有可以為 ABAP CDS 檢視實體（例如 UNGREEDY）中的 REPLACE_REGEXPR 函式指定的引數也可以為 ABAP SQL 指定。 此功能可以透過 PCRE 語法本身來實現。

# Xpath and XSD Syntax

功能豐富的 PCRE 正規表示式幾乎可以在所有情況下使用。然而，Perl 使用的正規表示式查詢並不能很好地將 XML/HTML 分解成有意義的部分並輕鬆解析它們。為了解決這個難題，ABAP 還支援 Xpath & XSD 正規表示式，並在內部將其轉換為 PCRE 語法。

XPath 代表“XML 路徑語言”，是一種用於指定 XML 文件部分的表示式語言。 XPath 也可用於結構類似於 XML 的文件，如 HTML。 XPath 語法中的正規表示式可以在正常和擴充套件模式下編譯。在擴充套件模式下，模式的大多數未轉義空格（空格和換行符）在字元類之外被忽略，註釋可以放在 # 後面。在ABAP內建函式中，擴充套件模式預設開啟，可以透過正規表示式中的(?-x)關閉。

與正規表示式不同，我們在使用 XPath 時不需要提前知道資料的模式。由於 XML 文件是使用節點結構化的，XPath 使用該結構來瀏覽節點以返回包含我們正在尋找的節點的物件。

例子：XPath 正規表示式的一個特殊功能是字符集的減法。 在以下示例中，從字符集 BasicLatin 中減去字母 a 到 c，第一個匹配項是偏移量為 3 的 d。

```abap
FIND REGEX
  cl_abap_regex=>create_xpath2( pattern = '[\p{IsBasicLatin}-[a-c]]' )
  IN 'abcd' MATCH OFFSET DATA(moff).
```

與 PCRE 相比，XPath 正規表示式允許跳脫字元 \ 而不僅僅是在特殊字元前面。 在以下示例中，帶有引數 xpath 的 match 函式會找到 x，而帶有引數 pcre 的 match 函式則不會。 因此，第一個 FIND 語句在 sy-subrc 中返回值 0，而第二個 FIND 語句返回 4。

```abap
DATA(x) = match( val = `abxcd` xpath = `\x`  occ = 1  ).
DATA(y) = match( val = `abxcd` pcre =  `\x`  occ = 1  ).

FIND REGEX cl_abap_regex=>create_xpath2( pattern = '\x' ) IN 'abxcd'.
FIND REGEX cl_abap_regex=>create_pcre(   pattern = '\x' ) IN 'abxcd'.
```

# XSD Syntax

XSD 代表“Xml Schema Definition”，是 XPath 語法的一個子集。與其他正規表示式相比，XML 模式風格有自己的正規表示式語法和專用符號，但功能非常有限。此功能不足不會成為障礙，因為 XSD 僅用於驗證整個元素是否與模式匹配，而不是用於從大資料塊中提取匹配項。

XML 模式錨定整個正規表示式。因此，您不能新增正規表示式分隔符，也不需要使用錨點（即開頭的 ^ 和結尾的 $）。正規表示式必須匹配整個元素才能被視為有效元素。點從不匹配換行符，並且模式區分大小寫。 XML 正規表示式沒有像 \xFF 或 \uFFFF 這樣的任何標記來匹配特殊字元，也沒有提供指定匹配模式的方法。

非貪婪行為沒有 XSD 語法。 XSD 也無法使用惰性量詞。由於模式錨定在主題字串的開頭和結尾，並且只返回成功/失敗結果，這只是效能問題，導致貪婪和懶惰量詞之間存在差異。透過將貪婪量詞更改為惰性量詞或反之亦然，不可能使完全錨定的模式匹配或失敗。此外，沒有註冊或反向引用的子組沒有 XSD 語法。

不管其侷限性如何，XML 模式正規表示式提供了兩個方便的特性。特殊的速記字元類 \i 和 \c 使得匹配 XML 名稱變得容易。沒有其他正規表示式支援這種可能性。

您不能直接在 FIND & REPLACE 語句中使用 XSD 語法，但您可以使用透過新增 REGEX 的方法 CREATE_XSD 建立的 RegEx 類的物件。

以下示例使用對 PCRE 無效的 XSD 語法，並且找不到任何與 POSIX 匹配的語法。 它也適用於 XPath。

```abap
DATA(xml) = `<a rel="nofollow"><b>...<y><z>`.

REPLACE ALL OCCURRENCES OF
        REGEX cl_abap_regex=>create_xsd( pattern = `\i\c*` )
        IN xml WITH `option:$0`.
  cl_demo_output=>display( xml ).
```

# 結論

如前所述，正規表示式可以讓您解析字串或複雜的替換操作。 它是一個強大的文字處理工具，可用於擴充套件您的 ABAP 功能。 我希望我能讓你對 RegEx 和 ABAP 中支援的語法，即 PCRE、XPath 和 XSD 有一個粗略的瞭解。

儘管 PCRE 功能更強大且可在大多數情況下使用，但最好使用 XPath 或 XSD 從 XML 文件中選擇節點或計算值（如字串、布林值或數字），以更快更高效。 POSIX 語法現在已經過時，需要遷移到 ABAP 支援的任何其他正規表示式語法。 ABAP SQL 和 ABAP CDS 檢視還支援帶有上述內建函式的 PCRE 語法。 更詳細的資訊也可以在 ABAP 關鍵字文件中找到。</z></y></b></a></result></result></result>

現代 ABAP 程式語言中的正規表示式

相關文章