oracle資料庫自動發郵件實現報警功能

我們之前有個需求，需要每天檢查oracle裡的job是否執行成功，人工查比較麻煩，寫了一個儲存過程，定時發郵件。

一共涉及兩個儲存過程，第一個是設定發郵件給誰和發的內容。

CREATE OR REPLACE PROCEDURE CHECK_JOBS_GL
AS
  /******
   檢查定時任務（jobs）是否執行成功，併發郵件。by guoliang 2016年6月28日
  ******/
 V_NUMBER VARCHAR2(10);
 
BEGIN
  -- 檢查dba_jobs表檢視是否有執行錯誤的job
 
    SELECT  COUNT(1) INTO V_NUMBER  FROM USER_JOBS WHERE SCHEMA_USER = 'Mxxxxx' AND failures <> '0';
    IF V_NUMBER = '0' THEN 
     send_mail_gl('guoliang@xxxx.cn','資料庫定時任務執行成功','您好，資料庫定時任務執行成功，請知悉');
     
    ELSE
     send_mail_gl('guoliang@xxxx.cn','請注意,資料庫定時任務執行失敗','您好，資料庫定時任務執行失敗，請排查');
     
    END IF;
DBMS_OUTPUT.put_line(V_NUMBER);
      
END;

第二個就是上面提到的send_mail_gl程式：

CREATE OR REPLACE PROCEDURE SEND_MAIL_GL(p_recipient VARCHAR2, -- 郵件接收人
                                         p_subject VARCHAR2, -- 郵件標題
                                         p_message VARCHAR2 -- 郵件正文
)
IS
  --下面四個變數請根據實際郵件伺服器進行賦值
  v_mailhost VARCHAR2(30) := 'smtp.exmail.qq.com'; --SMTP伺服器地址
  v_user VARCHAR2(30) := 'devops@xxx.cn'; --登入SMTP伺服器的使用者名稱
  v_pass VARCHAR2(20) := 'xxxx'; --登入SMTP伺服器的密碼
  v_sender VARCHAR2(50) := 'devops@xxx.cn'; --傳送者郵箱，一般與 ps_user 對應
  v_conn UTL_SMTP.connection; --到郵件伺服器的連線
  v_msg VARCHAR2(4000); --郵件內容
BEGIN
  v_conn := UTL_SMTP.open_connection(v_mailhost, 25);
  UTL_SMTP.ehlo(v_conn, v_mailhost); --是用 ehlo() 而不是 helo() 函式
  --否則會報：ORA-29279: SMTP 永久性錯誤
  UTL_SMTP.command(v_conn, 'AUTH LOGIN'); -- smtp伺服器登入校驗
  UTL_SMTP.command(v_conn,
                   UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_user))));
  UTL_SMTP.command(v_conn,
                   UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_pass))));
  UTL_SMTP.mail(v_conn, '<' || v_sender || '>'); --設定發件人
  UTL_SMTP.rcpt(v_conn, '<' || p_recipient || '>'); --設定收件人
  -- 建立要傳送的郵件內容 注意報頭資訊和郵件正文之間要空一行
  v_msg := 'Date:' || TO_CHAR(SYSDATE, 'yyyy mm dd hh24:mi:ss') ||
           UTL_TCP.CRLF || 'From: ' || v_sender || '' || UTL_TCP.CRLF ||
           'To: ' || p_recipient || '' || UTL_TCP.CRLF || 'Subject: ' ||
           p_subject || UTL_TCP.CRLF || UTL_TCP.CRLF -- 這前面是報頭資訊
           || p_message; -- 這個是郵件正文
  UTL_SMTP.open_data(v_conn); --開啟流
  UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(v_msg)); --這樣寫標題和內容都能用中文
  UTL_SMTP.close_data(v_conn); --關閉流
  UTL_SMTP.quit(v_conn); --關閉連線
EXCEPTION
  WHEN OTHERS THEN
    DBMS_OUTPUT.put_line(DBMS_UTILITY.format_error_stack);
    DBMS_OUTPUT.put_line(DBMS_UTILITY.format_call_stack);
END SEND_MAIL_GL;