手機寫作業系統之
圖形模式
進入圖形模式，顯示圖片、漢字。
首先介紹設定顯示卡模式中斷：int 10h
檢視文件找到下面資料：
Int 10/AX=4F02h - VESA SuperVGA BIOS - SET SuperVGA VIDEO MODE
這時是設定為SuperVGA模式
AX = 4F02h
BX = new video mode
我們設定成800*600模式 16位色。
Int 10/AX=4F01h - VESA SuperVGA BIOS - GET SuperVGA MODE INFORMATION
這時是讀取SuperVGA模式引數
AX = 4F01h
CX = SuperVGA video mode
ES:DI指向預先保留的256位元組空間，這裡將儲存int 10h傳來的引數，其中第40個位元組開始存有顯示卡地址的32位值。
在kernelloader.asm中又將此地址存入指定的0x10050處（值e0000000）
顯示原理很簡單，向顯示卡地址填入一個16位值，代表顏色，就可以在800X600的框架裡顯示一個點。
下面看程式實現：
修改kernelloader.asm，原始碼如下：
[BITS 16]
jmp main
gdt_entries equ 3 ;共有三個段描述符：null,os code32,os data32
pe equ 1 ;bit PE in CR0
null equ 0h
os_code32_sel equ 8h ;1,gdt,rpl=00
os_data32_sel equ 10h ;2,gdt,rpl=00
VESA: times 256 db 0 ;分配一塊區域存放 vesa 返回的資訊，大小256，我們只需要其中的一個32位值
pdescr times 6 db 0
gdt_table times (gdt_entries*8) db 0
set_video_mode: ;設定顯示卡模式
push es
;設定顯示卡模式
mov ax , 0x4f02
mov bx , 0x4114 ;800X600 ( 5:6:5 ) 16位色彩
int 0x10
;取得該模式下顯示卡地址
mov bx , 0x1000
mov es , bx
mov di , VESA ;es:di指向256空間，int 10h將在此填寫資料
mov ax , 0x4f01
mov cx , 0x114
int 0x10
;第40個位元組開始存有顯示卡地址0xe0000000,將此地址再存入指定的地址0x10050
mov eax , [ es:VESA + 40 ]
;將此地址再存入指定的地址0x10050,
mov [ es:0x50 ] , eax ;eax內容為 0xe0000000
pop es
ret
read_kernel: ;讀入 kernel 程式
push es
.rk:
mov ax , 0x8000 ;kernel.bin 所在的段基址
mov es , ax
mov bx , 0 ;寫入到記憶體0x8000:0000 實體地址=0x80000
mov ah , 2
mov dh , 0 ;磁頭
mov dl , 0 ;驅動器號
mov ch , 0 ;磁軌0
mov cl , 4 ;第4個扇區開始
mov al , 2 ;讀入扇區數,每個扇區為 512B
int 0x13
jc .rk
pop es
ret
main:
mov ax,1000h
mov ds,ax
;設定顯示卡模式
call set_video_mode
;讀入 kernel
call read_kernel
;開啟 A 20 地址線
mov ax , 0x2401
int 0x15
;[1]built up GDT table
cli
mov eax,gdt_table
;item 0:null descriptor,
mov dword[eax],0
mov dword[eax+4],0
add eax,8
;item 1,OS code32 descriptor,
;Base=00000000h,limit=0ffh,G=1,D=1,type=a,dpl=0
mov word[eax],0ffh
mov word[eax+2],0
mov byte[eax+4],00h
mov byte[eax+5],09ah
mov byte[eax+6],0c0h
mov byte[eax+7],00h
add eax,8
;item 2,OS data32 descriptor
;Base=00000000h,Limit=0fffffh,G=1,D=1,Type=2,DPL=0
mov word[eax],0ffffh
mov word[eax+2],0000h
mov byte[eax+4],00h
mov byte[eax+5],092h
mov byte[eax+6],0cfh ;高四位是G D 0 AVL，此處為1100 = c ,低四位是limit bit 16-19 此處為f
mov byte[eax+7],00h
add eax,8
;[2]built false GDT descriptor
mov word[pdescr+0],(gdt_entries*8)
mov dword[pdescr+2],gdt_table+00010000h
lgdt [pdescr]
;[3]enter into protected mode
;重新整理CR0
mov eax,cr0
or eax,pe
mov cr0,eax
jmp flush
flush:
mov ax,os_data32_sel
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov gs,ax
jmp dword os_code32_sel:0x80000 ;跳轉到0x8000:0000保護模式 實體地址0x80000
kernel.asm，原始碼如下：
[BITS 32]
jmp start
start:
mov eax,0x10050 ;參見kernelloader.asm 顯示卡地址指定存在這裡
mov edx,dword [eax]
add edx,80600 ;加上偏移量
mov cx,50 ;迴圈50次
mov ax,0x7ff ;藍色值，
next:
mov word [edx],ax ; 向地址e0013ad8存入值07ff
inc edx
inc edx
dec cx
jnz next ;cx不為0則繼續
jmp $
boot.asm
[BITS 16] ;編譯成16位的指令
[ORG 0x7C00]
jmp main
read_kernelloader: ;讀入 kernelloader 程式
push es
.rk:
mov ax , 0x1000 ;kernelloader.bin 所在的段基址
mov es , ax
mov bx , 0
mov ah , 2
mov dl , 0
mov ch , 0
mov cl , 2
mov al , 2 ;讀入扇區數,每個扇區為 512B
int 0x13
jc .rk
pop es
ret
main: ;主程式
mov ax , 0x0 ;boot.bin 程式的段基址
mov ds , ax
call read_kernelloader ;讀入 kernelloader 程式
jmp dword 0x1000:0 ;跳轉到 kernelloader 處執行
times 510-($-$$) db 0
db 0x55
db 0xAA
makefile
######################
宣告要編譯的所有組成,這裡的ya是本工程名稱，可以取任何名字，這裡就用ya
######################
ya:out/boot.bin out/kernelloader.bin out/kernel.bin out/create_img.o out/write_in_img.o (注意這裡無回車)
開始對各部分編譯，注意不是空格是Tab鍵
out/boot.bin:code/boot.asm
nasm code/boot.asm -o out/boot.bin
out/kernelloader.bin:code/kernelloader.asm
nasm code/kernelloader.asm -o out/kernelloader.bin
out/kernel.bin:code/kernel.asm
nasm code/kernel.asm -o out/kernel.bin
製作核心映象工具
out/create_img.o:code/create_img.c
clang++ code/create_img.cpp -o out/create_img.o
寫入檔案,argv[1]=目標檔案 argv[2]=原始檔 argv[3]=寫入偏移量
out/write_in_img.o:code/write_in_img.cpp
clang++ code/write_in_img.cpp -o out/write_in_img.o
######################
g.sh：
!/bin/sh
echo "=啟動 ya=="
cd /sdcard/A/ya/
make
cd ~
cp -r /sdcard/A/ya/out ./
cd out
chmod 755 ./*
執行命令，當前目錄下生成a.img檔案
./create_img.o a.img
執行命令，向a.img寫入程式碼，內容是boot.bin
寫入磁碟位置從0偏移量起始,佔1個扇區512位元組
./write_in_img.o a.img boot.bin 0
執行命令，向a.img寫入程式碼，內容是kernelloader.bin
boot.bin已經佔用了512位元組,寫入磁碟位置從512偏移量起始,佔2個扇區1024位元組
./write_in_img.o a.img kernelloader.bin 512
執行命令，向a.img寫入程式碼，內容是kernel.bin
boot.bin+kernelloader.bin已經佔用了512+1024 = 1536位元組,寫入磁碟位置從1536偏移量起始，佔1個扇區512位元組
./write_in_img.o a.img kernel.bin 1536
結果複製到手機
cp -f ./a.img /sdcard/A/ya/final
cp -f ./newkernel.bin /sdcard/A/ya/final
cd ~
rm -r out
編譯過程同上一節，編譯完成後執行模擬器，結果顯示：
一條蘭色直線：