首先說下我們專案的對於打包的需求，這裡只針對釋出正式環境的包。 專案的程式碼放在Gitlab,需要打包的應用市場有十多個，apk都需要使用360加固，打包的工作由開發完成，然後將所有市場的apk檔案壓縮成一個zip檔案發給市場的同事上線。最初的流程是由開發用AS打包後手動的進行加固，然後每次釋出光打包-加固-修改apk檔名+發郵件這個流程都得花上半個小時以上。為了提高效率，所以我決定使用gradle+jenkins來完成這個任務。
其實這樣的文章挺多的，但是別人的需求總是不太能完美的解決我的問題，所以我自己通過gradle寫了個task來解決我的需求。
Gradle指令碼
一. 在Project下新建一個目錄reinforce,將360加固相關檔案匯入
二. 修改Android Studio生成apk檔名
build.gradle中新增配置：
android.applicationVariants.all { variant ->
variant.outputs.all {
outputFileName = "pccb-v" + defaultConfig.versionName + "-" +
variant.productFlavors[0].name + "-" + variant.buildType.name + ".apk"
}
}
複製程式碼pccb是我們專案名,生成的apk檔名pccb-v3.2.0-vivo-release.apk這種形式，後面從這個檔名中獲取渠道和版本資訊。
三. 建立gradle指令碼檔案app/pack-release.gradle
我建立了一個task packageRelease，這個task依賴assembleRelease，assembleRelease執行完成後會執行packageRelease的doLast方法。
packageRelease的執行流程：
1. 從outputs/apk/xx/release中找出assembleRelease生成的所有apk。
我這裡有4個渠道，所以最終生成了4個apk檔案。理論上來說我們在打多渠道包的時候，可以使用360加固的多渠道打包功能由一個包就可以生成N個渠道包，但是我這裡有點特殊的是我們十多個渠道的app名字並不是一樣的，總共有4個app名，每個對應幾個渠道。360加固只能修改AndroidManifest.xml中meta-data標籤中的值，所以我這裡必須為每個app名生成一個apk檔案，並且在reinforce/channel中建立了4個多渠道打包模板。
2. 建立一個儲存加固後的apk目錄： 根據版本號建立目錄，build/outputs/release/pccb-x.x.x
3. 將4個原始的apk進行360加固，生成多個渠道的apk，自動簽名 4. 刪除加固後生成的temp.apk和jiagu_sign.apk結尾的檔案，保留渠道名+_sign.apk結尾的檔案
5. 根據需要修改保留的apk的檔名 6. 壓縮pccb-x.x.x資料夾，生成pccb-x.x.x.zip
pack-release.gradle程式碼：
import java.util.zip.ZipEntry
import java.util.zip.ZipOutputStream
ext {
BASE = "../reinforce/"
JAR = BASE + "jiagu.jar"
NAME = ""//360加固賬號
PASSWORD = ""//360加固密碼
KEY_PATH = "" //金鑰路徑
KEY_PASSWORD = "" //金鑰密碼
ALIAS = "" //金鑰別名
ALIAS_PASSWORD = "" //別名密碼
OUTPUT_PATH = "build/outputs/release/" //加固後所有apk的儲存路徑
CHANNEL_CONFIG = BASE + "channel/"//儲存渠道配置
}
class ApkFile {
String channel
File file
}
/**
* 查詢所有apk
* @param buildType release 或者 debug
* @return ArrayList <ApkFile>
*/
def findApkFiles(String buildType) {
println "findApkFiles buildType: " + buildType
File apkDir = new File("build/outputs/apk")
File[] channelDirs = apkDir.listFiles()
List<ApkFile> apkFiles = new ArrayList<>()
for (int i = 0; i < channelDirs.length; i++) {
File channelDir = channelDirs[i]
ApkFile apkFile = new ApkFile()
apkFile.channel = channelDir.name
File[] files = new File(channelDir, "/" + buildType).listFiles()
if (files == null || files.length == 0) {
continue
}
File lastFile = files[files.length - 1]
if (!lastFile.name.endsWith(".apk")) {
continue
}
apkFile.file = lastFile
apkFiles.add(apkFile)
}
return apkFiles
}
/**
* 360加固
* @param apk 加固的原始apk File
* @param outputPath 輸出目錄
* @param channel 原始渠道(baidu,yyb,...)
*/
def reinforce(apk, outputPath, channel) {
println "reinforce apk:" + apk
//jiagu.db中快取了多渠道資訊，如果不刪除會合併到當前多渠道配置
def db = new File(BASE + "jiagu.db")
if (db.exists()) {
if (!db.delete()) {
throw new RuntimeException("delete jiagu.db failure!")
}
}
exec {
commandLine "powershell", "java -jar", JAR, "-login", NAME, PASSWORD
}
exec {
commandLine "powershell", "java -jar", JAR, "-importsign", KEY_PATH, KEY_PASSWORD, ALIAS, ALIAS_PASSWORD
}
exec {
commandLine "powershell", "java -jar", JAR, "-showsign"
}
exec {
commandLine "powershell", "java -jar", JAR, "-importmulpkg", CHANNEL_CONFIG + "template_" + channel + ".txt"
}
exec {
commandLine "powershell", "java -jar", JAR, "-showmulpkg"
}
exec {
commandLine "powershell", "java -jar", JAR, "-jiagu", apk, outputPath, "-autosign", "-automulpkg"
}
}
/**
* 刪除一些臨時檔案
* @param outputDir apk儲存目錄
*/
def filterApk(File outputDir) {
println "*************** filter apk ***************"
File[] files = outputDir.listFiles()
for (int i = 0; i < files.length; i++) {
File file = files[i]
String fileName = file.getName()
if (fileName.endsWith("jiagu_sign.apk") || fileName.endsWith("temp.apk")
|| !fileName.endsWith("_sign.apk")) {
file.delete()
}
}
}
/**
* 修改所有apk檔名
* @param outputDir apk儲存目錄
*/
def renameApk(File outputDir) {
println "*************** rename apk ***************"
File[] files = outputDir.listFiles()
for (int i = 0; i < files.length; i++) {
File file = files[i]
String fileName = file.getName()
String[] prefixArr = fileName.split("-")
String[] suffixArr = fileName.split("_")
String rename = prefixArr[0] + "-" + prefixArr[1] +
"-" + (i + 1) + "-" + suffixArr[suffixArr.length - 2] + ".apk"
file.renameTo(file.getParent() + "/" + rename)
println "rename apk: " + fileName + " --> " + rename
}
}
/**
* zip壓縮apk儲存目錄，生成 build/outputs/release/pccb-x.x.x.zip
* @param outputDir apk儲存目錄
*/
def compressDir(File outputDir) {
println "*************** compress apk output dir ***************"
File zipFile = new File(outputDir.getParent() + "/" + outputDir.getName() + ".zip")
if (zipFile.exists()) {
zipFile.delete()
}
ZipOutputStream zos = new ZipOutputStream(new FileOutputStream(zipFile))
File[] files = outputDir.listFiles()
for (int i = 0; i < files.length; i++) {
File file = files[i]
byte[] bf = new byte[8192]
FileInputStream fis = new FileInputStream(file)
zos.putNextEntry(new ZipEntry(file.getName()))
int len
while ((len = fis.read(bf)) > 0) {
zos.write(bf, 0, len)
}
zos.flush()
fis.close()
}
zos.close()
}
//構建釋出到生產環境的所有渠道apk,生成壓縮檔案 pccb-x.x.x.zip
task packageRelease {
dependsOn("assembleRelease")
doLast {
List<ApkFile> apkFiles = findApkFiles("release")
if (apkFiles.size() == 0) {
throw new RuntimeException("no apk files has found!")
}
String[] nameSlice = apkFiles.get(0).file.name.split("-")
File outputDir = new File(OUTPUT_PATH + nameSlice[0] + "-" + nameSlice[1])
if (outputDir.exists()) {
if (!outputDir.delete()) {
throw new RuntimeException("delete outputDir failure!")
}
}
if (!outputDir.mkdirs()) {
throw new RuntimeException("make outputDir failure!")
}
for (int i = 0; i < apkFiles.size(); i++) {
ApkFile apkFile = apkFiles.get(i)
reinforce(apkFile.file, outputDir.getPath(), apkFile.channel)
}
filterApk(outputDir)
renameApk(outputDir)
compressDir(outputDir)
}
}
複製程式碼四. 應用pack-release.gradle
在build.gradle頂部新增
apply from: 'pack-release.gradle'
複製程式碼jenkins配置
一. General
二.原始碼管理
三.構建
關於Root Build Script和Build File這裡遇到了問題記錄下，我前面指令碼中的目錄下的是 ../reinforce/，然後我在Android Studio中執行 gradlew packageRelease是沒有問題的，但是在jenkins一直找不到對應的檔案。後來找到原因是因為我在Android studio中是從app目錄開始構建的所以沒有問題，但是jenkins中是從project目錄開始構建所以根本找不到對應的目錄。最後通過設定 Root Build Script->app,Build File->build.gradle解決。
四，構建後操作-歸檔檔案
