前言
本篇部落格將會展示 CSAPP 之 BombLab 的拆彈過程，粉碎 Dr.Evil 的邪惡陰謀。Dr.Evil 的替身，殺手皇后，總共設定了 6 個炸彈，每個炸彈對應一串字串，如果字串錯誤，炸彈就會被引爆?，如下圖所示：
字串的長度未知，所以暴力破解是不可取的，也就是說這個實驗就是要逼著拆彈小分隊將 bomb 可執行檔案反彙編，根據彙編程式碼推測出每個炸彈對應的字串。在終端輸入 objdump -d bomb > bomb.asm ，就可以將彙編程式碼寫入 bomb.asm 檔案中，方便後續分析。同時，Dr.Evil 還提供了 bomb.c 原始檔，通過它可以看到炸彈程式的主要結構，程式碼如下：
/***************************************************************************
* Dr. Evil's Insidious Bomb, Version 1.1
* Copyright 2011, Dr. Evil Incorporated. All rights reserved.
*
* LICENSE:
*
* Dr. Evil Incorporated (the PERPETRATOR) hereby grants you (the
* VICTIM) explicit permission to use this bomb (the BOMB). This is a
* time limited license, which expires on the death of the VICTIM.
* The PERPETRATOR takes no responsibility for damage, frustration,
* insanity, bug-eyes, carpal-tunnel syndrome, loss of sleep, or other
* harm to the VICTIM. Unless the PERPETRATOR wants to take credit,
* that is. The VICTIM may not distribute this bomb source code to
* any enemies of the PERPETRATOR. No VICTIM may debug,
* reverse-engineer, run "strings" on, decompile, decrypt, or use any
* other technique to gain knowledge of and defuse the BOMB. BOMB
* proof clothing may not be worn when handling this program. The
* PERPETRATOR will not apologize for the PERPETRATOR's poor sense of
* humor. This license is null and void where the BOMB is prohibited
* by law.
***************************************************************************/
#include <stdio.h>
#include <stdlib.h>
#include "support.h"
#include "phases.h"
/*
* Note to self: Remember to erase this file so my victims will have no
* idea what is going on, and so they will all blow up in a
* spectaculary fiendish explosion. -- Dr. Evil
*/
FILE *infile;
int main(int argc, char *argv[])
{
char *input;
/* Note to self: remember to port this bomb to Windows and put a
* fantastic GUI on it. */
/* When run with no arguments, the bomb reads its input lines
* from standard input. */
if (argc == 1) {
infile = stdin;
}
/* When run with one argument <file>, the bomb reads from <file>
* until EOF, and then switches to standard input. Thus, as you
* defuse each phase, you can add its defusing string to <file> and
* avoid having to retype it. */
else if (argc == 2) {
if (!(infile = fopen(argv[1], "r"))) {
printf("%s: Error: Couldn't open %s\n", argv[0], argv[1]);
exit(8);
}
}
/* You can't call the bomb with more than 1 command line argument. */
else {
printf("Usage: %s [<input_file>]\n", argv[0]);
exit(8);
}
/* Do all sorts of secret stuff that makes the bomb harder to defuse. */
initialize_bomb();
printf("Welcome to my fiendish little bomb. You have 6 phases with\n");
printf("which to blow yourself up. Have a nice day!\n");
/* Hmm... Six phases must be more secure than one phase! */
input = read_line(); /* Get input */
phase_1(input); /* Run the phase */
phase_defused(); /* Drat! They figured it out!
* Let me know how they did it. */
printf("Phase 1 defused. How about the next one?\n");
/* The second phase is harder. No one will ever figure out
* how to defuse this... */
input = read_line();
phase_2(input);
phase_defused();
printf("That's number 2. Keep going!\n");
/* I guess this is too easy so far. Some more complex code will
* confuse people. */
input = read_line();
phase_3(input);
phase_defused();
printf("Halfway there!\n");
/* Oh yeah? Well, how good is your math? Try on this saucy problem! */
input = read_line();
phase_4(input);
phase_defused();
printf("So you got that one. Try this one.\n");
/* Round and 'round in memory we go, where we stop, the bomb blows! */
input = read_line();
phase_5(input);
phase_defused();
printf("Good work! On to the next...\n");
/* This phase will never be used, since no one will get past the
* earlier ones. But just in case, make this one extra hard. */
input = read_line();
phase_6(input);
phase_defused();
/* Wow, they got it! But isn't something... missing? Perhaps
* something they overlooked? Mua ha ha ha ha! */
return 0;
}
不過我們也可以使用下述指令在終端檢視 bomb.c：
$ gdb bomb
(gdb) l
可以看到六個炸彈分別對應著 phase_1() 到 phase_6() 函式，有了這些資訊就可以著手分析彙編程式碼了。
拆彈過程
第一炸彈
在彙編程式碼中搜尋 phase_1，可以看到 phase_1 共出現三次，左側是 phase_1() 被呼叫，右側是 phase_1() 的程式碼：
可以看到 phase_1 中把 $0x402400 寫到了暫存器 %rsi 中，接著呼叫了 strings_not_equal 函式，相當於 strings_not_equal(%rdi, 0x402400)，如果字串不相等即 %rax 為 1 時，第一炸彈就會被引爆。容易猜到 0x402400 應該是正確字串的起始地址，而 %rdi 中存的應該是拆彈小分隊輸入的字串的起始地址。可以使用 GDB 來驗證一下這個猜想：
先在 phase_1 的第三行 callq 401338 <strings_not_equal> 處打上斷點，然後執行程式並輸入 zhiyiYo，使用 display /x $rdi 檢視 %rdi 的值 0x603780，最後使用 x/8c 0x603780 檢視從該地址開始的8個字元，發現和我們輸入的一樣（多了結束符），驗證了上述猜想。
由於我們還不知道真實字串的長度，只知道它的起始地址是 0x402400，所以可以試下長一點的，只要看到 \000 就能說明字串結束了。
(gdb) x/64c 0x402400
0x402400: 66 'B' 111 'o' 114 'r' 100 'd' 101 'e' 114 'r' 32 ' ' 114 'r'
0x402408: 101 'e' 108 'l' 97 'a' 116 't' 105 'i' 111 'o' 110 'n' 115 's'
0x402410: 32 ' ' 119 'w' 105 'i' 116 't' 104 'h' 32 ' ' 67 'C' 97 'a'
0x402418: 110 'n' 97 'a' 100 'd' 97 'a' 32 ' ' 104 'h' 97 'a' 118 'v'
0x402420: 101 'e' 32 ' ' 110 'n' 101 'e' 118 'v' 101 'e' 114 'r' 32 ' '
0x402428: 98 'b' 101 'e' 101 'e' 110 'n' 32 ' ' 98 'b' 101 'e' 116 't'
0x402430: 116 't' 101 'e' 114 'r' 46 '.' 0 '\000' 0 '\000' 0 '\000' 0 '\000'
0x402438: 87 'W' 111 'o' 119 'w' 33 '!' 32 ' ' 89 'Y' 111 'o' 117 'u'
將上述字元連線得到 Border relations with Canada have never been better.，這個就是第一炸彈的正確答案。
第二炸彈 —— 枯萎穿心攻擊
phase_2 的彙編程式碼如下所示：
0000000000400efc <phase_2>:
400efc: 55 push %rbp
400efd: 53 push %rbx
400efe: 48 83 ec 28 sub $0x28,%rsp
400f02: 48 89 e6 mov %rsp,%rsi
400f05: e8 52 05 00 00 callq 40145c <read_six_numbers>
400f0a: 83 3c 24 01 cmpl $0x1,(%rsp)
400f0e: 74 20 je 400f30 <phase_2+0x34>
400f10: e8 25 05 00 00 callq 40143a <explode_bomb>
400f15: eb 19 jmp 400f30 <phase_2+0x34>
400f17: 8b 43 fc mov -0x4(%rbx),%eax
400f1a: 01 c0 add %eax,%eax
400f1c: 39 03 cmp %eax,(%rbx)
400f1e: 74 05 je 400f25 <phase_2+0x29>
400f20: e8 15 05 00 00 callq 40143a <explode_bomb>
400f25: 48 83 c3 04 add $0x4,%rbx
400f29: 48 39 eb cmp %rbp,%rbx
400f2c: 75 e9 jne 400f17 <phase_2+0x1b>
400f2e: eb 0c jmp 400f3c <phase_2+0x40>
400f30: 48 8d 5c 24 04 lea 0x4(%rsp),%rbx
400f35: 48 8d 6c 24 18 lea 0x18(%rsp),%rbp
400f3a: eb db jmp 400f17 <phase_2+0x1b>
400f3c: 48 83 c4 28 add $0x28,%rsp
400f40: 5b pop %rbx
400f41: 5d pop %rbp
400f42: c3 retq
可以看到 phase_2 顯示進行了被呼叫者保護，然後將 %rsp 棧指標減小 28 以騰出空間並將 %rsp 的值賦給 %rsi。接著呼叫了 read_six_numbers 函式，從名字可以看出這個函式應該用來讀入 6 個數字，具體程式碼為：
000000000040145c <read_six_numbers>:
40145c: 48 83 ec 18 sub $0x18,%rsp
401460: 48 89 f2 mov %rsi,%rdx
401463: 48 8d 4e 04 lea 0x4(%rsi),%rcx
401467: 48 8d 46 14 lea 0x14(%rsi),%rax
40146b: 48 89 44 24 08 mov %rax,0x8(%rsp)
401470: 48 8d 46 10 lea 0x10(%rsi),%rax
401474: 48 89 04 24 mov %rax,(%rsp)
401478: 4c 8d 4e 0c lea 0xc(%rsi),%r9
40147c: 4c 8d 46 08 lea 0x8(%rsi),%r8
401480: be c3 25 40 00 mov $0x4025c3,%esi
401485: b8 00 00 00 00 mov $0x0,%eax
40148a: e8 61 f7 ff ff callq 400bf0 <__isoc99_sscanf@plt>
40148f: 83 f8 05 cmp $0x5,%eax
401492: 7f 05 jg 401499 <read_six_numbers+0x3d>
401494: e8 a1 ff ff ff callq 40143a <explode_bomb>
401499: 48 83 c4 18 add $0x18,%rsp
40149d: c3 retq
從 read_six_numbers 可以看出，6個數字的地址分別為 %rsp、%rsp+0x4、%rsp+0x8、%rsp+0xc、%rsp+0x10 和%rsp+0x14。呼叫完 read_six_numbers 之後，phase_2 又將 (%rsp) 和 0x1 進行比較，如果不相等就引爆第二炸彈。接下來的程式碼可以翻譯為：
rbx = rsp + 0x4;
rbp = rsp + 0x18;
while (rbx != rbp) {
rax = 2 * M[rbx - 0x4];
if (rax != M[rbx]) {
explode_bomb();
}
rbx += 0x4;
}
說明讀入的 6 個數字應該是一個等比數列，且 a[n] = 2*a[n-1]，由於 (%rsp) 為 1，後續的幾個數字就是 2、4、8、16 和 32。測試一下發現第二炸彈確實被成功拆除了：
第三炸彈 —— 敗者食塵
phase_3 的彙編程式碼如下所示：
0000000000400f43 <phase_3>:
400f43: 48 83 ec 18 sub $0x18,%rsp
400f47: 48 8d 4c 24 0c lea 0xc(%rsp),%rcx
400f4c: 48 8d 54 24 08 lea 0x8(%rsp),%rdx
400f51: be cf 25 40 00 mov $0x4025cf,%esi
400f56: b8 00 00 00 00 mov $0x0,%eax
400f5b: e8 90 fc ff ff callq 400bf0 <__isoc99_sscanf@plt>
400f60: 83 f8 01 cmp $0x1,%eax
400f63: 7f 05 jg 400f6a <phase_3+0x27>
400f65: e8 d0 04 00 00 callq 40143a <explode_bomb>
400f6a: 83 7c 24 08 07 cmpl $0x7,0x8(%rsp)
400f6f: 77 3c ja 400fad <phase_3+0x6a>
400f71: 8b 44 24 08 mov 0x8(%rsp),%eax
400f75: ff 24 c5 70 24 40 00 jmpq *0x402470(,%rax,8)
400f7c: b8 cf 00 00 00 mov $0xcf,%eax
400f81: eb 3b jmp 400fbe <phase_3+0x7b>
400f83: b8 c3 02 00 00 mov $0x2c3,%eax
400f88: eb 34 jmp 400fbe <phase_3+0x7b>
400f8a: b8 00 01 00 00 mov $0x100,%eax
400f8f: eb 2d jmp 400fbe <phase_3+0x7b>
400f91: b8 85 01 00 00 mov $0x185,%eax
400f96: eb 26 jmp 400fbe <phase_3+0x7b>
400f98: b8 ce 00 00 00 mov $0xce,%eax
400f9d: eb 1f jmp 400fbe <phase_3+0x7b>
400f9f: b8 aa 02 00 00 mov $0x2aa,%eax
400fa4: eb 18 jmp 400fbe <phase_3+0x7b>
400fa6: b8 47 01 00 00 mov $0x147,%eax
400fab: eb 11 jmp 400fbe <phase_3+0x7b>
400fad: e8 88 04 00 00 callq 40143a <explode_bomb>
400fb2: b8 00 00 00 00 mov $0x0,%eax
400fb7: eb 05 jmp 400fbe <phase_3+0x7b>
400fb9: b8 37 01 00 00 mov $0x137,%eax
400fbe: 3b 44 24 0c cmp 0xc(%rsp),%eax
400fc2: 74 05 je 400fc9 <phase_3+0x86>
400fc4: e8 71 04 00 00 callq 40143a <explode_bomb>
400fc9: 48 83 c4 18 add $0x18,%rsp
400fcd: c3 retq
可以看到 phase_3 先讀入了一個數字，接著跳轉到 0x400f6a， 將 (%rsp + 0x8) 和 0x7 進行比較，如果比它大就引爆炸彈，其中 (%rsp + 0x8) 的值就是我們輸入的第一個數字。可以執行 GDB 來驗證一下這個猜想，將斷點打在 0x400f6a 處，對第三炸彈輸入 8 9，結果如下圖所示：
如果輸入的第一個數字小於等於 7，就暫時不會引爆炸彈。接著執行了 jmpq *0x402470(,%rax,8) 指令，這個指令的作用就是讓程式跳轉到 M[0x402470 + %rax * 8] 處，此處 %rax 就是輸入的第一個數字，由於每個地址 64 位為 8 個位元組，所以將 %rax 乘上了 8。下圖顯示了跳轉之前 %rax 的值和跳轉表的 8 個地址：
可以看到輸入的第一個數字 0~7 分別對應著：0x400f7c、0x400fb9、0x400f83、0x400f8a、0x400f91、0x400f98、0x400f9f 和 0x400fa6。在 phase_3 中，上述地址都是一條對 %rax 進行賦值的指令，賦的值的十進位制為 207、311、707、256、389、206、682 和 327。接著將 (%rsp + 0xc) 和 %rax 進行比較，如果不相等就引爆炸彈，否則退出 phase_3，解除炸彈。也就是說第三炸彈的前 2 個數字對應著 8 種正確答案（後面的字串就無所謂了），當前兩個數字為 1 311 時執行結果如下圖所示：
第四炸彈
phase_4 的彙編程式碼如下：
000000000040100c <phase_4>:
40100c: 48 83 ec 18 sub $0x18,%rsp
401010: 48 8d 4c 24 0c lea 0xc(%rsp),%rcx
401015: 48 8d 54 24 08 lea 0x8(%rsp),%rdx
40101a: be cf 25 40 00 mov $0x4025cf,%esi
40101f: b8 00 00 00 00 mov $0x0,%eax
401024: e8 c7 fb ff ff callq 400bf0 <__isoc99_sscanf@plt>
401029: 83 f8 02 cmp $0x2,%eax
40102c: 75 07 jne 401035 <phase_4+0x29>
40102e: 83 7c 24 08 0e cmpl $0xe,0x8(%rsp)
401033: 76 05 jbe 40103a <phase_4+0x2e>
401035: e8 00 04 00 00 callq 40143a <explode_bomb>
40103a: ba 0e 00 00 00 mov $0xe,%edx
40103f: be 00 00 00 00 mov $0x0,%esi
401044: 8b 7c 24 08 mov 0x8(%rsp),%edi
401048: e8 81 ff ff ff callq 400fce <func4>
40104d: 85 c0 test %eax,%eax
40104f: 75 07 jne 401058 <phase_4+0x4c>
401051: 83 7c 24 0c 00 cmpl $0x0,0xc(%rsp)
401056: 74 05 je 40105d <phase_4+0x51>
401058: e8 dd 03 00 00 callq 40143a <explode_bomb>
40105d: 48 83 c4 18 add $0x18,%rsp
401061: c3 retq
可以看到，phase_4 讀入了兩個數字（並且只允許輸入兩個），然後判斷輸入的第一個數字是否小於等於 14，大於 14 就會引爆炸彈。接著呼叫了 func4(輸入的第一個數字, 0, 14) 。從 func4() 返回後判斷 %eax 是否為 0，不為 0 就引爆炸彈，如果 (%rsp + 0xc) 也就是輸入的第二個數字不為 0 也會引爆炸彈。為了順利拆除第四炸彈，有必要分析一下 func4 的執行流程。
0000000000400fce <func4>:
400fce: 48 83 ec 08 sub $0x8,%rsp
400fd2: 89 d0 mov %edx,%eax
400fd4: 29 f0 sub %esi,%eax
400fd6: 89 c1 mov %eax,%ecx
400fd8: c1 e9 1f shr $0x1f,%ecx
400fdb: 01 c8 add %ecx,%eax
400fdd: d1 f8 sar %eax
400fdf: 8d 0c 30 lea (%rax,%rsi,1),%ecx
400fe2: 39 f9 cmp %edi,%ecx
400fe4: 7e 0c jle 400ff2 <func4+0x24>
400fe6: 8d 51 ff lea -0x1(%rcx),%edx
400fe9: e8 e0 ff ff ff callq 400fce <func4>
400fee: 01 c0 add %eax,%eax
400ff0: eb 15 jmp 401007 <func4+0x39>
400ff2: b8 00 00 00 00 mov $0x0,%eax
400ff7: 39 f9 cmp %edi,%ecx
400ff9: 7d 0c jge 401007 <func4+0x39>
400ffb: 8d 71 01 lea 0x1(%rcx),%esi
400ffe: e8 cb ff ff ff callq 400fce <func4>
401003: 8d 44 00 01 lea 0x1(%rax,%rax,1),%eax
401007: 48 83 c4 08 add $0x8,%rsp
40100b: c3 retq
func4 的操作可以使用如下的程式碼來描述：
do {
rsp -= 0x8;
rax = rdx;
rax -= rsi;
// 接下來的三行程式碼感覺沒啥大用，因為正數邏輯右移 31 位之後一定為 0
rcx = rax;
rcx >>= 31 // 此處為邏輯右移
rax += rcx;
rax >>= 1; // rax = rax / 2
rcx = rax + rsi;
if (rcx <= rdi) {
rax = 0;
// 其實就是兩個相等
if (rcx >= rdi) {
rsp += 0x8;
continue;
}
rsi = rcx + 1;
// 下面這條語句應該在 rsp -= 0x8 後執行
// M[rsp] = 0x401003;
} else {
rdx = rcx - 1;
// 下面這條語句應該在 rsp -= 0x8 後執行
// M[rsp] = 0x400fee;
}
} while (rsp != 0x40104d)
有上述虛擬碼可以看到，要想返回的時候 %rax 為 0，就一定不能走到第 23 行，不然執行完 retq 語句後會將 M[%rsp] 的值也就是 0x401003 送到 %rip，程式跳到 lea 0x1(%rcx),%esi 繼續執行，之後 %rax 不可能變成 0。在第 23 行沒被執行的情況下，%rsi 的值一直都是 0，%rcx 的值可以為下面幾種：
- 14/2 = 7，當
%rdi = 7時可以直接返回phase_4並解除炸彈 - (7 - 1) / 2 = 3，當
%rdi = 3時會跳到add %eax,%eax1 次才返回phase_4並解除炸彈 - (3 - 1) / 2 = 1，當
%rdi = 1時會跳到add %eax,%eax2 次才返回phase_4並解除炸彈 - (1 - 1) / 2 = 0，當
%rdi = 0時會跳到add %eax,%eax3 次才返回phase_4並解除炸彈
來測試一下最後一種情況，因為它最複雜：
(gdb) b *0x40100b
Breakpoint 1 at 0x40100b
(gdb) r
Starting program: /home/zhiyiyo/Documents/CSAPP/bomblab/bomb
Welcome to my fiendish little bomb. You have 6 phases with
which to blow yourself up. Have a nice day!
Border relations with Canada have never been better.
Phase 1 defused. How about the next one?
1 2 4 8 16 32
That's number 2. Keep going!
0 207
Halfway there!
0 0
Breakpoint 1, 0x000000000040100b in func4 ()
(gdb) disassemble
Dump of assembler code for function func4:
0x0000000000400fce <+0>: sub $0x8,%rsp
0x0000000000400fd2 <+4>: mov %edx,%eax
0x0000000000400fd4 <+6>: sub %esi,%eax
0x0000000000400fd6 <+8>: mov %eax,%ecx
0x0000000000400fd8 <+10>: shr $0x1f,%ecx
0x0000000000400fdb <+13>: add %ecx,%eax
0x0000000000400fdd <+15>: sar %eax
0x0000000000400fdf <+17>: lea (%rax,%rsi,1),%ecx
0x0000000000400fe2 <+20>: cmp %edi,%ecx
0x0000000000400fe4 <+22>: jle 0x400ff2 <func4+36>
0x0000000000400fe6 <+24>: lea -0x1(%rcx),%edx
0x0000000000400fe9 <+27>: callq 0x400fce <func4>
0x0000000000400fee <+32>: add %eax,%eax
0x0000000000400ff0 <+34>: jmp 0x401007 <func4+57>
0x0000000000400ff2 <+36>: mov $0x0,%eax
0x0000000000400ff7 <+41>: cmp %edi,%ecx
0x0000000000400ff9 <+43>: jge 0x401007 <func4+57>
0x0000000000400ffb <+45>: lea 0x1(%rcx),%esi
0x0000000000400ffe <+48>: callq 0x400fce <func4>
0x0000000000401003 <+53>: lea 0x1(%rax,%rax,1),%eax
0x0000000000401007 <+57>: add $0x8,%rsp
=> 0x000000000040100b <+61>: retq
End of assembler dump.
(gdb) si
0x0000000000400fee in func4 ()
(gdb) disassemble
Dump of assembler code for function func4:
0x0000000000400fce <+0>: sub $0x8,%rsp
0x0000000000400fd2 <+4>: mov %edx,%eax
0x0000000000400fd4 <+6>: sub %esi,%eax
0x0000000000400fd6 <+8>: mov %eax,%ecx
0x0000000000400fd8 <+10>: shr $0x1f,%ecx
0x0000000000400fdb <+13>: add %ecx,%eax
0x0000000000400fdd <+15>: sar %eax
0x0000000000400fdf <+17>: lea (%rax,%rsi,1),%ecx
0x0000000000400fe2 <+20>: cmp %edi,%ecx
0x0000000000400fe4 <+22>: jle 0x400ff2 <func4+36>
0x0000000000400fe6 <+24>: lea -0x1(%rcx),%edx
0x0000000000400fe9 <+27>: callq 0x400fce <func4>
=> 0x0000000000400fee <+32>: add %eax,%eax
0x0000000000400ff0 <+34>: jmp 0x401007 <func4+57>
0x0000000000400ff2 <+36>: mov $0x0,%eax
0x0000000000400ff7 <+41>: cmp %edi,%ecx
0x0000000000400ff9 <+43>: jge 0x401007 <func4+57>
0x0000000000400ffb <+45>: lea 0x1(%rcx),%esi
0x0000000000400ffe <+48>: callq 0x400fce <func4>
0x0000000000401003 <+53>: lea 0x1(%rax,%rax,1),%eax
0x0000000000401007 <+57>: add $0x8,%rsp
0x000000000040100b <+61>: retq
End of assembler dump.
(gdb) c
Continuing.
Breakpoint 1, 0x000000000040100b in func4 ()
(gdb) c
Continuing.
Breakpoint 1, 0x000000000040100b in func4 ()
(gdb) c
Continuing.
Breakpoint 1, 0x000000000040100b in func4 ()
(gdb) c
Continuing.
So you got that one. Try this one.
可以看到當輸入的第一數字為 0 時，確實跳轉到 add %eax,%eax 才能返回，最終第四炸彈被成功拆除。
第五炸彈
phase_5 的彙編程式碼如下所示：
0000000000401062 <phase_5>:
401062: 53 push %rbx
401063: 48 83 ec 20 sub $0x20,%rsp
401067: 48 89 fb mov %rdi,%rbx
40106a: 64 48 8b 04 25 28 00 mov %fs:0x28,%rax
401071: 00 00
401073: 48 89 44 24 18 mov %rax,0x18(%rsp)
401078: 31 c0 xor %eax,%eax
40107a: e8 9c 02 00 00 callq 40131b <string_length>
40107f: 83 f8 06 cmp $0x6,%eax
401082: 74 4e je 4010d2 <phase_5+0x70>
401084: e8 b1 03 00 00 callq 40143a <explode_bomb>
401089: eb 47 jmp 4010d2 <phase_5+0x70>
40108b: 0f b6 0c 03 movzbl (%rbx,%rax,1),%ecx
40108f: 88 0c 24 mov %cl,(%rsp)
401092: 48 8b 14 24 mov (%rsp),%rdx
401096: 83 e2 0f and $0xf,%edx
401099: 0f b6 92 b0 24 40 00 movzbl 0x4024b0(%rdx),%edx
4010a0: 88 54 04 10 mov %dl,0x10(%rsp,%rax,1)
4010a4: 48 83 c0 01 add $0x1,%rax
4010a8: 48 83 f8 06 cmp $0x6,%rax
4010ac: 75 dd jne 40108b <phase_5+0x29>
4010ae: c6 44 24 16 00 movb $0x0,0x16(%rsp)
4010b3: be 5e 24 40 00 mov $0x40245e,%esi
4010b8: 48 8d 7c 24 10 lea 0x10(%rsp),%rdi
4010bd: e8 76 02 00 00 callq 401338 <strings_not_equal>
4010c2: 85 c0 test %eax,%eax
4010c4: 74 13 je 4010d9 <phase_5+0x77>
4010c6: e8 6f 03 00 00 callq 40143a <explode_bomb>
4010cb: 0f 1f 44 00 00 nopl 0x0(%rax,%rax,1)
4010d0: eb 07 jmp 4010d9 <phase_5+0x77>
4010d2: b8 00 00 00 00 mov $0x0,%eax
4010d7: eb b2 jmp 40108b <phase_5+0x29>
4010d9: 48 8b 44 24 18 mov 0x18(%rsp),%rax
4010de: 64 48 33 04 25 28 00 xor %fs:0x28,%rax
4010e5: 00 00
4010e7: 74 05 je 4010ee <phase_5+0x8c>
4010e9: e8 42 fa ff ff callq 400b30 <__stack_chk_fail@plt>
4010ee: 48 83 c4 20 add $0x20,%rsp
4010f2: 5b pop %rbx
4010f3: c3 retq
可以看到 phase_5 開啟了金絲雀保護機制，用於防範緩衝區溢位可能造成的安全問題。接著判斷輸入的字串的長度，如果不為 6 就引爆炸彈。接下來的程式碼可以翻譯為：
rbx = rdi; // %rdi 儲存了輸入的字串的起始地址
for (rax = 0; rax < 6; rax++) {
rcx = M[rbx + rax];
M[rsp] = cl; // %rcx 低八位，將值限制在 0~255 之間
rdx = M[rsp];
rdx &= 0xF; // 將 %rdx 的值限制在 0~15 之間
rdx = M[rdx + 0x4024b0];
M[rsp + rax + 0x10] = dl; // %rdx 的低八位
}
M[rsp + 0x16] = 0;
rsi = 0x40245e;
rdi = rsp + 0x10;
if (strings_not_equal(rdi, rsi)) {
explode_bomb()
}
根據第一炸彈的套路，%rsi 中存的應該是正確字串的起始地址，由於字串的長度為 6，所以結果如下圖所示：
可以看到字串是 flyers，當然第五炸彈可能沒有第一炸彈那麼簡單，直接將 flyers 輸到終端就企圖解除炸彈只會無功而返，畢竟在 strings_not_equal 之前還有一段幹了髒活的程式碼。再來認真分析一下 for 迴圈裡面都發生了什麼。
由於 %rdx 儲存了輸入的字串的起始地址，所以 M[rbx + rax] 取出了字串的一個字元，只留下字元的低 8 位並賦值給 %rdx。%rdx 更進一步，只留下了低四位（取值範圍 0~15）。之後 rdx = M[rdx + 0x4024b0] 以 0x4024b0 為基地址，加上 0~15 的偏移量，從記憶體中取出了一個字元並賦給 %rdx。最後把 %rdx 的低 8 位賦值給 M[rsp + rax + 0x10]，由於迴圈進行了 6 次，所以 strings_not_equal 是將 %rsp + 0x10 到 %rsp + 0x15 組成的字串和 flyers 進行比較。
下圖顯示了 0x4024b0 開始的 16 個（ rdx &= 0xF ）字元，裡面出現了 flyers 所需的 6 個字母：
只要讓給 0x4024b0 加上 9 就能取到 f，所以字串的第一個字元應該是 9。而為了取到 l，我們應該給 0x4024b0 加上 15，但是這裡對應的字元就不該是 15 的十六進位制 F，而應該是低四位全為 1 的某個字元，字元 ? 的的二進位制值為 0b11111，滿足低四位全 1 的條件，所以字串的第二位取 ?。根據這個原理可以分別確定出後面幾個字元為 >567，最終結果是 9?>567。
第六炸彈
phase_6 的彙編程式碼如下所示：
00000000004010f4 <phase_6>:
4010f4: 41 56 push %r14
4010f6: 41 55 push %r13
4010f8: 41 54 push %r12
4010fa: 55 push %rbp
4010fb: 53 push %rbx
4010fc: 48 83 ec 50 sub $0x50,%rsp
401100: 49 89 e5 mov %rsp,%r13
401103: 48 89 e6 mov %rsp,%rsi
401106: e8 51 03 00 00 callq 40145c <read_six_numbers>
40110b: 49 89 e6 mov %rsp,%r14
40110e: 41 bc 00 00 00 00 mov $0x0,%r12d
401114: 4c 89 ed mov %r13,%rbp
401117: 41 8b 45 00 mov 0x0(%r13),%eax
40111b: 83 e8 01 sub $0x1,%eax
40111e: 83 f8 05 cmp $0x5,%eax
401121: 76 05 jbe 401128 <phase_6+0x34>
401123: e8 12 03 00 00 callq 40143a <explode_bomb>
401128: 41 83 c4 01 add $0x1,%r12d
40112c: 41 83 fc 06 cmp $0x6,%r12d
401130: 74 21 je 401153 <phase_6+0x5f>
401132: 44 89 e3 mov %r12d,%ebx
401135: 48 63 c3 movslq %ebx,%rax
401138: 8b 04 84 mov (%rsp,%rax,4),%eax
40113b: 39 45 00 cmp %eax,0x0(%rbp)
40113e: 75 05 jne 401145 <phase_6+0x51>
401140: e8 f5 02 00 00 callq 40143a <explode_bomb>
401145: 83 c3 01 add $0x1,%ebx
401148: 83 fb 05 cmp $0x5,%ebx
40114b: 7e e8 jle 401135 <phase_6+0x41>
40114d: 49 83 c5 04 add $0x4,%r13
401151: eb c1 jmp 401114 <phase_6+0x20>
401153: 48 8d 74 24 18 lea 0x18(%rsp),%rsi
401158: 4c 89 f0 mov %r14,%rax
40115b: b9 07 00 00 00 mov $0x7,%ecx
401160: 89 ca mov %ecx,%edx
401162: 2b 10 sub (%rax),%edx
401164: 89 10 mov %edx,(%rax)
401166: 48 83 c0 04 add $0x4,%rax
40116a: 48 39 f0 cmp %rsi,%rax
40116d: 75 f1 jne 401160 <phase_6+0x6c>
40116f: be 00 00 00 00 mov $0x0,%esi
401174: eb 21 jmp 401197 <phase_6+0xa3>
401176: 48 8b 52 08 mov 0x8(%rdx),%rdx
40117a: 83 c0 01 add $0x1,%eax
40117d: 39 c8 cmp %ecx,%eax
40117f: 75 f5 jne 401176 <phase_6+0x82>
401181: eb 05 jmp 401188 <phase_6+0x94>
401183: ba d0 32 60 00 mov $0x6032d0,%edx
401188: 48 89 54 74 20 mov %rdx,0x20(%rsp,%rsi,2)
40118d: 48 83 c6 04 add $0x4,%rsi
401191: 48 83 fe 18 cmp $0x18,%rsi
401195: 74 14 je 4011ab <phase_6+0xb7>
401197: 8b 0c 34 mov (%rsp,%rsi,1),%ecx
40119a: 83 f9 01 cmp $0x1,%ecx
40119d: 7e e4 jle 401183 <phase_6+0x8f>
40119f: b8 01 00 00 00 mov $0x1,%eax
4011a4: ba d0 32 60 00 mov $0x6032d0,%edx
4011a9: eb cb jmp 401176 <phase_6+0x82>
4011ab: 48 8b 5c 24 20 mov 0x20(%rsp),%rbx
4011b0: 48 8d 44 24 28 lea 0x28(%rsp),%rax
4011b5: 48 8d 74 24 50 lea 0x50(%rsp),%rsi
4011ba: 48 89 d9 mov %rbx,%rcx
4011bd: 48 8b 10 mov (%rax),%rdx
4011c0: 48 89 51 08 mov %rdx,0x8(%rcx)
4011c4: 48 83 c0 08 add $0x8,%rax
4011c8: 48 39 f0 cmp %rsi,%rax
4011cb: 74 05 je 4011d2 <phase_6+0xde>
4011cd: 48 89 d1 mov %rdx,%rcx
4011d0: eb eb jmp 4011bd <phase_6+0xc9>
4011d2: 48 c7 42 08 00 00 00 movq $0x0,0x8(%rdx)
4011d9: 00
4011da: bd 05 00 00 00 mov $0x5,%ebp
4011df: 48 8b 43 08 mov 0x8(%rbx),%rax
4011e3: 8b 00 mov (%rax),%eax
4011e5: 39 03 cmp %eax,(%rbx)
4011e7: 7d 05 jge 4011ee <phase_6+0xfa>
4011e9: e8 4c 02 00 00 callq 40143a <explode_bomb>
4011ee: 48 8b 5b 08 mov 0x8(%rbx),%rbx
4011f2: 83 ed 01 sub $0x1,%ebp
4011f5: 75 e8 jne 4011df <phase_6+0xeb>
4011f7: 48 83 c4 50 add $0x50,%rsp
4011fb: 5b pop %rbx
4011fc: 5d pop %rbp
4011fd: 41 5c pop %r12
4011ff: 41 5d pop %r13
401201: 41 5e pop %r14
401203: c3 retq
這段程式碼體積有點大，不過拆彈小分隊還是得忍一下。phase_6 首先讀入了 6 個數字，接著從 0x40110e 到 0x401151 的程式碼可以翻譯為：
r12d = 0;
while (True) {
rbp = r13; // 輸入的數字的地址
rax = M[r13];
rax -= 1;
// M[r13] 的取值範圍在 1~6 之間
if (rax > 5 ) {
explode_bomb();
}
r12d += 1;
if (r12d == 6) break;
for (rbx = r12d; rbx <= 5; rbx++) {
rax = rbx;
if (rax == M[rsp]) {
explode_bomb();
}
}
r13 += 4;
}
上述程式碼中 %r13 儲存的是輸入的數字的地址，如下圖所示：
根據上述程式碼可以確定輸入的數字應該在 1~6 之間，並且不能重複，不然就會引爆第六炸彈。從 0x401153 到 0x40116d 的程式碼可以翻譯為：
rsi = rsp + 18;
rax = r14; // 輸入數字的開始地址
do {
rdx = 7 - M[rax];
M[rax] = rdx;
rax += 4;
} while (rsi != rax)
此處 %r14 和 %r13 一樣存的是輸入數字的開始地址（不貼圖了），而上述程式碼的作用就是用 7 減去每個輸入的數字並作為新值。接下來的程式碼就有點混亂了，反覆橫跳，所以這裡先看下最後一段程式碼 0x4011da 到 0x4011f5 的翻譯：
for (rbp = 5; rbp > 1; rbp--) {
rax = M[rbx + 8];
eax = M[rax]; // 只保留四個位元組，高位填充 0
if (M[rbx] < eax) {
explode_bomb();
}
rbx = M[rbx + 8]; // rbx 滯後 rax
}
由此可見 %rbx 是一個二重指標，需要解引用兩次才能拿到正確的值，這段程式碼用來確定一段記憶體是否已降序排列，如果不滿足降序條件就會引爆第六炸彈。如果輸入的 6 個數字為 6~1，在開始檢查是否滿足倒序條件之前暫停程式，可以看到記憶體中以 %rbx 為起始地址的 12 個 8 位元組數，其中左側一列的低 32 位用來比較大小，右側一列用來作為 %rax 和下次 %rbx 存放的地址：
根據上述資訊，再來審視沒提及的那一部分彙編程式碼，其實就是根據使用者輸入的數字，改變右側一欄的地址和 %rbx 的初始值。如果將 %rbx 的初始值設定為 0x6032f0，沿著左側一欄向下，到底之後回到 0x6032d0，一路得到的序列就是遞減的。由此可以得到輸入的數字為 4 3 2 1 6 5（被 7 減過得到的）。結果如下：
總結
通過這次實驗，可以熟悉 GDB 除錯工具的使用方法，同時也能看懂一些彙編程式碼了（不過有一說一，第六炸彈的程式碼真的就是又臭又長）。拆了這麼久的炸彈，中間還失敗過好多次，希望人質沒事，以上~~