### 簡述
logminer它包括DBMS_LOGMNR和DBMS_LOGMNR_D兩個package，後邊的D是字典的意思。它既能分析redo log file，也能分析歸檔後的archive log file。

在分析日誌的過程中需要使用資料字典，一般先生成資料字典檔案後使用，10g版本還可以使用線上資料字典

> 用於日誌分析是：
Logminer也可以分析其它資料庫的重做日誌檔案，但是必須使用重做日誌所在資料庫的資料字典，否則會出現無法識別的亂碼。另外被分析資料庫的作業系統平臺最好和當前Logminer所在資料庫的執行平臺一樣，且block size相同。

#### LogMiner的功能
- 確定資料庫的邏輯損壞時間

透過LogMiner可以準確定位該誤操作的執行時間和SCN值，然後透過基於時間恢復或者基於SCN恢復可以完全恢復該表資料。

```
select scn_to_timestamp(10135546249879) from dual;
SELECT timestamp_to_scn(to_timestamp('2020-4-15 16:06:06','yyyy-mm-dd hh24:mi:ss')) FROM dual;
```

- 確定事務級要執行的精細邏輯恢復操作

透過LogMiner可以取得任何使用者的DML操作及相應的UNDO操作，透過執行UNDO操作可以取消使用者的錯誤操作。

- 執行後續審計

透過LogMiner可以跟蹤Oracle資料庫的所有DML、DDL和DCL操作，從而取得執行這些操作的時間順序、執行這些操作的使用者等資訊。

### logminer 簡單使用

#### 初始環境

```
--安裝logminer 
@?/rdbms/admin/dbmslm.sql 
 @?/rdbms/admin/dbmslmd.sql 
--設定兩端資料庫
alter database archive;
alter database force logging;
alter database add supplemental  log data;--不開啟的話只能看到以sys使用者登陸下的資料更新
alter database add supplemental log data (primary key,unique,foreign key) columns;
```

#### 分析歸檔/線上日誌

```
--線上日誌可透過v$log,v$logfile 結合查出，通常檢查當前使用的線上日誌
--歸檔日誌可透過v$archived_log查出

--新增歸檔或線上日誌
begin
sys.dbms_logmnr.add_logfile(logfilename=>'+DATAJIXIE/sypm/archvelog/2_29980_1007747066.dbf', options=>sys.dbms_logmnr.new);
end;

--啟動分析
begin
sys.dbms_logmnr.start_logmnr(options=>sys.dbms_logmnr.dict_from_online_catalog);
end;
--or 也可以將字典存為本地，需如下設定,如抽取日誌同步到其他資料庫，建議該方式
alter system set utl_file_dir='/backup/logminer' scope=spfile;
execute dbms_logmnr_d.build ('dict2020.ora','/backup/logminer',dbms_logmnr_d.store_in_flat_file);
execute dbms_logmnr.start_logmnr(dictfilename=>'/backup/logminer/dict2020.ora',options=>dbms_logmnr.ddl_dict_tracking);

--透過檢視分析
select * from  v$logmnr_contents  where sql_redo like '%INSERT%';
```

### 使用logminer 定時同步(dblink)資料到目標端

> 來自網路參考

以下測試指令碼，預設使用使用者mytest，表t2020,dblink:logdblink,每兩秒鐘重新整理一次。透過事務id、scan等方式，捕捉事務id、scn變化，增量同步(主要使用三個檢視:v$log,v$archived_log,v$logmnr_contents)。

本次測試指令碼分為兩部分，初始化環境及相關job和主要使用儲存過程。

#### 初始環境及相關job如下

```
alter session set nls_date_format='yyyy-mm-dd hh24:mi:ss';

--1 日誌目錄
create directory logmnr as '/backup/logmnr';
create directory SYNCDATACONFIG as '/backup/logmnr/config';
--2 DML佇列目錄
create directory SYNCDATA as '/backup/logmnr/syncdata';
--3 SCN標誌位初始化
-- 例項化啟動程式時的SCN到/backup/logmnr/scn.txt, 標誌為全域性 g_scn
declare
 fhandle utl_file.file_type;
 v_scn number(30);
begin
  v_scn:=dbms_flashback.get_system_change_number();
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'scn_ck.txt', 'w');
  utl_file.put_line(fhandle , v_scn);
  utl_file.fclose(fhandle);
end;
/
-- 4 archive log 標誌位初始化
declare
 fhandle utl_file.file_type;
 v_recid v$archived_log.RECID%type;
begin
    select max(recid) into v_recid  from v$archived_log order by 1;
    fhandle := utl_file.fopen ('SYNCDATACONFIG','archivelog_ck.txt', 'W');
    utl_file.put_line(fhandle ,to_char(v_recid));--初始化捕獲程式前存在的歸檔不傳送 
    utl_file.fclose(fhandle);
    exception 
     when others then return;
end;
/
-- 5 DML佇列初始化
declare
 fhandle utl_file.file_type;
begin
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'queue_ck.txt', 'w');
  utl_file.put_line(fhandle , 'q0000000000'); -- 初始化佇列序列標誌
  utl_file.fclose(fhandle);
end;
/

-- 7 傳送佇列檢查點標誌初始化
declare
 fhandle utl_file.file_type;
begin
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'send_ck.txt', 'w');
  utl_file.fclose(fhandle);
end;
/

-- 8 xid事務標識集合初始化 
declare
 fhandle utl_file.file_type;
begin
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'xid_array.txt', 'w');
  utl_file.fclose(fhandle);
end;
/

-- 9 所有佇列序號集合初始化 
declare
 fhandle utl_file.file_type;
begin
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'queue_array.txt', 'w');
  utl_file.fclose(fhandle);
end;
/

-- 10 捕獲日誌初始化
declare
 fhandle utl_file.file_type;
begin
  fhandle := utl_file.fopen('LOGMNR', 'capture_log.txt', 'w');
  utl_file.fclose(fhandle);
end;
/

-- 11 傳送日誌初始化
declare
 fhandle utl_file.file_type;
begin
  fhandle := utl_file.fopen('LOGMNR', 'send_log.txt', 'w');
  utl_file.fclose(fhandle);
end;
/

/*-- 9 資料庫對照字典初始化
BEGIN
 dbms_logmnr_d.build(dictionary_filename=>'rac1emz_dict.ora',
 dictionary_location=>'/backup/logmnr/config');
END;
/*/

--10 初始化自定義型別
create or replace type myTableType as table of varchar2 (255);
/
-- 二、程式
--1 源資料庫捕獲程式
--2 源資料庫傳播程式 --檢查點記錄，支援斷點續傳

--三、建立源資料庫捕獲程式任務排程
/* 建立可執行程式 */
begin
    DBMS_SCHEDULER.CREATE_PROGRAM(
        program_name        => 'sys.proc_DataCapture_Archivelog',
        program_action      => 'sys.DataCapture_Archivelog',
        program_type        => 'STORED_PROCEDURE',
        number_of_arguments => 3,
        comments            => '資料同步程式',
        enabled             => false
    );
end;
/

/* 設定可執行程式的輸入引數 */
begin
    DBMS_SCHEDULER.define_program_argument(
        program_name      => 'sys.proc_DataCapture_Archivelog',
        argument_position => 1,
        argument_type     => 'VARCHAR2',
        default_value     => ''
    );
    DBMS_SCHEDULER.define_program_argument(
        program_name      => 'sys.proc_DataCapture_Archivelog',
        argument_position => 2,
        argument_type     => 'VARCHAR2',
        default_value     => ''
    );
    DBMS_SCHEDULER.define_program_argument(
        program_name      => 'sys.proc_DataCapture_Archivelog',
        argument_position => 3,
        argument_type     => 'VARCHAR2',
        default_value     => ''
    );
END;
/

/* 建立排程表 */
begin
    DBMS_SCHEDULER.create_schedule(
        schedule_name   => 'sys.sch_DataCapture_Archivelog',
        repeat_interval => 'FREQ=SECONDLY;INTERVAL=5',
        start_date      => sysdate,
        comments        => '資料同步排程'
    );
end;
/

/* 建立作業 */
begin
    DBMS_SCHEDULER.create_job( 
        job_name      => 'sys.JOB_DEMOSYNC',     
        program_name  => 'sys.proc_DataCapture_Archivelog',
        schedule_name => 'sys.sch_DataCapture_Archivelog',
        job_class     => 'DEFAULT_JOB_CLASS',            
        comments      => '資料同步作業',
        auto_drop     => false,
        enabled       => false
    );
end;
/

/* 啟動可執行程式 */
exec DBMS_SCHEDULER.enable('proc_DataCapture_Archivelog');

/* 啟動作業 */
exec DBMS_SCHEDULER.enable('JOB_DEMOSYNC');

/* 設定不同的作業引數 */
begin
    DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE(
        job_name          => 'sys.JOB_DEMOSYNC',
        argument_position => 1,
        argument_value    => 'MYTEST'
    );
    DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE(
        job_name          => 'sys.JOB_DEMOSYNC',
        argument_position => 2,
        argument_value    => 'T2020'
    );
    DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE(
        job_name          => 'sys.JOB_DEMOSYNC',
        argument_position => 3,
        argument_value    => 'LOGLINK'
    );
end;
/
----Job管理-----------------------------------------------------------------------

/* 禁用Job */
exec dbms_scheduler.disable('JOB_DEMOSYNC');
/* 執行Job */
exec dbms_scheduler.run_job('JOB_DEMOSYNC'); 
/* 停止Job */
exec dbms_scheduler.stop_job('JOB_DEMOSYNC');
/* 刪除Job */
exec dbms_scheduler.drop_job('JOB_DEMOSYNC');
exec DBMS_SCHEDULER.drop_schedule('sys.sch_DataCapture_Archivelog');
exec DBMS_SCHEDULER.drop_PROGRAM('sys.proc_DataCapture_Archivelog');

------------------------------------------------
--三、建立源資料庫傳送程式任務排程
/* 建立可執行程式 */
begin
    DBMS_SCHEDULER.CREATE_PROGRAM(
        program_name        => 'sys.proc_DataReplicat',
        program_action      => 'sys.DataReplicat',
        program_type        => 'STORED_PROCEDURE',
        number_of_arguments => 0,
        comments            => '資料同步程式-傳送程式',
        enabled             => false
    );
end;
/

/* 建立排程表 */
begin
    DBMS_SCHEDULER.create_schedule(
        schedule_name   => 'sys.sch_DataReplicat',
        repeat_interval => 'FREQ=SECONDLY;INTERVAL=2',
        start_date      => sysdate,
        comments        => '資料同步排程-傳送程式'
    );
end;
/

/* 建立作業 */
begin
    DBMS_SCHEDULER.create_job( 
        job_name      => 'sys.JOB_DEMOSYNC2',     
        program_name  => 'sys.proc_DataReplicat',
        schedule_name => 'sys.sch_DataReplicat',
        job_class     => 'DEFAULT_JOB_CLASS',            
        comments      => '資料同步作業-傳送程式',
        auto_drop     => false,
        enabled       => false
    );
end;
/

/* 啟動可執行程式 */
exec DBMS_SCHEDULER.enable('proc_DataReplicat');

/* 啟動作業 */
exec DBMS_SCHEDULER.enable('JOB_DEMOSYNC2');
----Job管理-----------------------------------------------------------------------

/* 禁用Job */
exec dbms_scheduler.disable('JOB_DEMOSYNC2');
/* 執行Job */
exec dbms_scheduler.run_job('JOB_DEMOSYNC2'); 
/* 停止Job */
exec dbms_scheduler.stop_job('JOB_DEMOSYNC2');
/* 刪除Job */
exec dbms_scheduler.drop_job('JOB_DEMOSYNC2');
exec DBMS_SCHEDULER.drop_schedule('sys.sch_DataReplicat');
exec DBMS_SCHEDULER.drop_PROGRAM('sys.proc_DataReplicat');

--檢視狀態
set lines 200
set pages 99
col job_name for a15
col repeat_interval for a20
col state for a10
col start_date for a15
col last_start_date for a15
col next_run_date for a15
col comments for a15
select t.job_name,t.repeat_interval,t.state,t.start_date,t.last_start_date,t.next_run_date,t.comments
from dba_scheduler_jobs t
where t.job_name in('JOB_DEMOSYNC','JOB_DEMOSYNC2');

```

#### 主要使用儲存過程如下

抓取歸檔日誌程式

```
create or replace procedure DataCapture_Archivelog(tableowner         varchar2,
                                                   tablename          varchar2,
                                                   database_link_name varchar2) is
  v_scn         number(30);
  fhandle       utl_file.file_type; --oracle檔案型別
  fp_buffer     varchar2(4000); --檔案輸出快取
  logfile        utl_file.file_type; --oracle檔案型別
  logfile_buffer varchar2(4000); --檔案輸出快取
  v_recid       number(10); --表archive log 序號
  v_recidck     number(10); --archivelog_ck 序號
  sql_txt       varchar2(4000); --待執行的 sql_redo
  v_dblink_name varchar2(20) := '@' || database_link_name; --目的資料庫聯接
  sqlwhere      varchar2(1000); --待執行的 sql_redo 條件語句
  v_tableowner  varchar2(20); --待同步的使用者
  v_tablename   varchar2(20); --待同步的表
  v_queueck     number(10); --佇列序列SCN
  v_queuename   varchar(20); --dml佇列名稱
  isCheckRedo   number(1) := 0; --是已經否抽取Redo日誌

v_sqlcommitnum number(5) := 10000; --已經提交的事務dml 分批提交給目的資料庫
  v_sqlnum    number := 0; --已經提交的事務dml當前個數

l_string long;
  l_data   myTableType := myTableType();
  n        number;

isDDL      number(1) := 0; --是否是dll操作 0不是 1是
  isCommited number(1) := 0; --是否已經commit操作 0不是 1是

XID_str varchar2(8000); --事務序號陣列
  j       number := 0; --tb_dml_XIDSQN序列下標
  type tb_XID_type is table of v$logmnr_contents.XID%type index by binary_integer; --定義待排除DLL
  tb_ddl_XID   tb_xid_type; --定義待排除DLL表
  tb_dml_XID   tb_xid_type; --定義待排除DLL表
  duplicat_xid number(1) := 0; -- 0  不重複 1 重複

cursor c_ddl is
    select distinct XID
      from v$logmnr_contents
     where seg_name = v_tablename
       and OPERATION = 'DDL';
begin
--開啟捕獲日誌
  logfile := utl_file.fopen('LOGMNR', 'capture_log.txt', 'a');
  --初始化schema
  v_tableowner := tableowner;
  v_tablename  := tablename;
  --捕獲歸檔日誌
  --dbms_output.put_line();
  utl_file.put_line(logfile, '');
  utl_file.put_line(logfile, 'Analyze Archivelog...start:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));

fhandle := utl_file.fopen('SYNCDATACONFIG', 'scn_ck.txt', 'R');
  utl_file.get_line(fhandle, fp_buffer);
  v_scn := fp_buffer;
  utl_file.fclose(fhandle);
  --dbms_output.put_line();
  utl_file.put_line(logfile, '0====v_scn:' || v_scn);

select max(recid) into v_recid from v$archived_log order by 1;
  /*exception
  when no_data_found then
    return;*/
  --dbms_output.put_line();
  utl_file.put_line(logfile, '1====1v_recid:' || v_recid);
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'archivelog_ck.txt', 'R');
  utl_file.get_line(fhandle, fp_buffer);
  v_recidck := fp_buffer;
  utl_file.fclose(fhandle);
  --dbms_output.put_line();
  utl_file.put_line(logfile, '1====2v_recid_ck:' || v_recidck);

if trim(v_recid) != trim(nvl(v_recidck, 0)) then
    --dbms_output.put_line();
    utl_file.put_line(logfile, '2====1存在未分析的Archive log');
  else
    if isCheckRedo = 0 then
      utl_file.put_line(logfile, '2====1 no New Archive log');
      utl_file.put_line(logfile, '2====Analyze Archivelog...End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
      utl_file.fclose(logfile);
      sys.datacapture_redo(tableowner, tablename, database_link_name);
      isCheckRedo := 1;
      return;
    end if;
  end if;

--一次載入從archive_ck歸檔檢查點到最新歸檔,及 當前 Redo
  for rs in (select name, recid from v$archived_log where recid >= v_recidck) loop
    dbms_logmnr.add_logfile(options     => dbms_logmnr.addfile,
                            logfilename => rs.name);
    --dbms_output.put_line();
    utl_file.put_line(logfile, '2====2 Archive logfilename:' || rs.name);
  end loop;

--dbms_output.put_line();
  utl_file.put_line(logfile, '2====3補充Redo log');
  for rs in (select f.MEMBER
               from v$logfile f, v$log l
              where f.group# = l.GROUP#
                and l.STATUS = 'CURRENT') loop
    dbms_logmnr.add_logfile(options     => dbms_logmnr.addfile,
                            logfilename => rs.MEMBER);
    --dbms_output.put_line();
    utl_file.put_line(logfile, '2====3 Redo logfilename:' || rs.MEMBER);
  end loop;
  dbms_logmnr.start_logmnr(options => dbms_logmnr.dict_from_online_catalog);
  --dbms_logmnr.start_logmnr(dictfilename => '/backup/logmnr/rac1emz_testdict.ora');

--待排除DLL
  open c_ddl;
  fetch c_ddl bulk collect
    into tb_ddl_XID;
  close c_ddl;

--待查詢的DML
  for c_tranXID in (select distinct XID
                      from v$logmnr_contents
                     where seg_name = v_tablename) loop
    isDDL        := 0;
    duplicat_xid := 0;
    isCommited   := 0;
    --判斷是否dll操作
    for i in 1 .. tb_ddl_XID.count loop
      if c_tranXID.XID = tb_ddl_XID(i) then
        isDDL := 1;
        --dbms_output.put_line();
        utl_file.put_line(logfile, '3==1 ddl xid:' || c_tranXID.XID);
      end if;
    end loop;
    --不是dll,新增dml xid
    if isDDl = 0 then
      --是否已經commit
      for c_commitXid in (select XID
                            from v$logmnr_contents
                           where xid = c_tranXID.XID
                             and operation = 'COMMIT') loop
        isCommited := 1;
        --dbms_output.put_line();
        utl_file.put_line(logfile, '3==1 COMMITED xid:' || c_commitXid.xid);
      end loop;
      if isCommited = 1 then
        --判斷xid事務標識是否已經存在，如果存在不新增,防止重複分析xid
        fhandle := utl_file.fopen('SYNCDATACONFIG', 'xid_array.txt', 'R');
        LOOP
          BEGIN
            utl_file.get_line(fhandle, fp_buffer);
            if rtrim(ltrim(fp_buffer)) = c_tranXID.XID then
              duplicat_xid := 1;
              --dbms_output.put_line(); --重複xid
              utl_file.put_line(logfile, '3====2 已分析過xid :' || c_tranXID.XID);
            end if;
          exception
            when no_data_found then
              exit;
          END;
        END LOOP;
        --判斷沒有重複的插入表tb_dml_XID
        if duplicat_xid = 0 then
          tb_dml_XID(j) := c_tranXID.XID;
          j := j + 1;
        end if;
        utl_file.fclose(fhandle);
      end if;
    end if;
  end loop;

--沒有dml  tran 退出程式
  --dbms_output.put_line();
  utl_file.put_line(logfile, '3====3 dml  tran count :' || tb_dml_XID.count);
  if tb_dml_XID.count = 0 then
    dbms_logmnr.end_logmnr;
  else
    --開啟xid事務標識集合，準備新增xid事務標識
    fhandle := utl_file.fopen('SYNCDATACONFIG', 'xid_array.txt', 'a');
    --dbms_output.put_line();
    utl_file.put_line(logfile, '5====開啟xid事務標識集合');
    --建立XID_str字串
    --dbms_output.put_line();
    utl_file.put_line(logfile, '5====建立XID_str字串');
    for i in 1 .. tb_dml_XID.count loop
      if tb_dml_XID.count != 1 then
        if i = 1 then
          --新增入一行xid事務標識
          utl_file.put_line(fhandle, tb_dml_XID(i - 1));
          --dbms_output.put_line();
          utl_file.put_line(logfile, 'a1_' || tb_dml_XID(i - 1));
          XID_str := tb_dml_XID(i - 1);
        else
          --新增入一行xid事務標識
          utl_file.put_line(fhandle, tb_dml_XID(i - 1));
          utl_file.put_line(logfile, 'a2_' || tb_dml_XID(i - 1));
          XID_str := XID_str || ',' || tb_dml_XID(i - 1);
        end if;
      else
        --新增入一行xid事務標識
        utl_file.put_line(fhandle, tb_dml_XID(i - 1));
        --dbms_output.put_line('a3_' || tb_dml_XID(i - 1));
        utl_file.put_line(logfile, 'a3_' || tb_dml_XID(i - 1));
        XID_str := tb_dml_XID(i - 1);
      end if;
    end loop;
    utl_file.fclose(fhandle);
    --dbms_output.put_line();
    utl_file.put_line(logfile, '5====關閉xid事務標識集合');
    --dbms_output.put_line();
    utl_file.put_line(logfile, '5====XID_str字串: ' || XID_str);
  
    l_string := XID_str || ',';
    loop
      exit when l_string is null;
      n := instr(l_string, ',');
      l_data.extend;
      l_data(l_data.count) := ltrim(rtrim(substr(l_string, 1, n - 1)));
      l_string := substr(l_string, n + 1);
    end loop;
  
    --佇列
    --讀取佇列開始序列
    fhandle := utl_file.fopen('SYNCDATACONFIG', 'queue_ck.txt', 'R');
    utl_file.get_line(fhandle, fp_buffer);
    utl_file.fclose(fhandle);
    --dbms_output.put_line();
    utl_file.put_line(logfile, '6====讀取佇列開始序列');
  
    --更新佇列
    v_queueck   := to_number(substr(fp_buffer, 2, 10));
    v_queuename := 'q' || lpad((v_queueck + 1), 10, '0');
    fhandle     := utl_file.fopen('SYNCDATACONFIG', 'queue_ck.txt', 'w');
    utl_file.put_line(fhandle, v_queuename);
    utl_file.fclose(fhandle);
    --dbms_output.put_line();
    utl_file.put_line(logfile, '7====更新佇列佇列序列');
  
    ----建立佇列檔案
    fhandle := utl_file.fopen('SYNCDATA', v_queuename || '.txt', 'w');
    utl_file.fclose(fhandle);
    utl_file.put_line(logfile, '8====建立佇列v_queuename:' || v_queuename);
    --新增dml
    fhandle := utl_file.fopen('SYNCDATA', v_queuename || '.txt', 'a');
    for c_sql in (select sql_redo, OPERATION
                    from v$logmnr_contents
                   where XID in (select *
                                   from THE (select cast(l_data as mytableType)
                                               from dual))
                     and operation in
                         ('INSERT', 'DELETE', 'UPDATE', 'COMMIT')
                   order by scn) loop
      if c_sql.sql_redo is not null then
        --判斷如果是insert,不擷取ROWID
        if c_sql.OPERATION = 'INSERT' or c_sql.OPERATION = 'COMMIT' then
          if c_sql.OPERATION = 'INSERT' then
            sql_txt := replace(c_sql.sql_redo,
                               '"' || v_tablename || '"',
                               '"' || v_tablename || '"' || v_dblink_name);
            utl_file.put_line(fhandle, sql_txt);
            utl_file.put_line(logfile, '9====sql_redo1:' || sql_txt);
          else
            utl_file.put_line(fhandle, c_sql.sql_redo);
            utl_file.put_line(logfile, '9====sql_redo2:' || c_sql.sql_redo);
          end if;
        else
          sql_txt := substr(c_sql.sql_redo,
                            0,
                            instr(c_sql.sql_redo, 'ROWID') - 5);
          sql_txt := replace(sql_txt,
                             '"' || v_tablename || '"',
                             '"' || v_tablename || '"' || v_dblink_name);
          utl_file.put_line(fhandle, sql_txt);
          utl_file.put_line(logfile, '9====sql_redo3:' || sql_txt);
        end if;
      end if;
    end loop;
    utl_file.fclose(fhandle);
    utl_file.put_line(logfile, '10====');
  
    --新增一行到 queue_arrary集合
    fhandle := utl_file.fopen('SYNCDATACONFIG', 'queue_array.txt', 'a');
    utl_file.put_line(fhandle, v_queuename);
    utl_file.fclose(fhandle);
    --dbms_output.put_line('11====新增到queue_arrary集合的佇列名稱:' || v_queuename);
    utl_file.put_line(logfile, '11====新增到queue_arrary集合的佇列名稱:' || v_queuename);
  
    dbms_logmnr.end_logmnr;
    --dbms_output.put_line('9====');
    utl_file.put_line(logfile, '9====');
    v_scn   := dbms_flashback.get_system_change_number();
    fhandle := utl_file.fopen('SYNCDATACONFIG', 'scn_ck.txt', 'w');
    utl_file.put_line(fhandle, v_scn);
    utl_file.fclose(fhandle);
    --dbms_output.put_line('10====v_scn:' || v_scn);
    utl_file.put_line(logfile, '10====v_scn:' || v_scn);
  end if;

--結束後變更檢查點
  --歸檔檢查點
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'archivelog_ck.txt', 'W');
  utl_file.put_line(fhandle, v_recid);
  utl_file.fclose(fhandle);
  --dbms_output.put_line('11====v_recid_ck:' || v_recid);
  utl_file.put_line(logfile, '11====v_recid_ck:' || v_recid);
  v_scn   := dbms_flashback.get_system_change_number();
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'scn_ck.txt', 'w');
  utl_file.put_line(fhandle, v_scn);
  utl_file.fclose(fhandle);
  --dbms_output.put_line('12====v_scn:' || v_scn);
  utl_file.put_line(logfile, '12====v_scn:' || v_scn);
  
  utl_file.put_line(logfile, '2====Analyze Archivelog...End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
  utl_file.fclose(logfile);
  
  if isCheckRedo = 0 then
    sys.datacapture_redo(tableowner, tablename, database_link_name);
  end if;
  
exception
  when others then
    dbms_logmnr.end_logmnr;
    utl_file.put_line(logfile, '2====Analyze Archivelog...End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
    --dbms_output.put_line(sqlerrm);
    utl_file.put_line(logfile, '13====2sqlerrm: ' || sqlerrm);
    utl_file.fclose(logfile);
    return;
end DataCapture_Archivelog;
/
```

抓取線上日誌程式

```
create or replace procedure DATACAPTURE_REDO(tableowner varchar2,tablename varchar2,database_link_name varchar2) is
  v_scn         number(30);
  fhandle       utl_file.file_type; --oracle檔案型別
  fp_buffer     varchar2(4000); --檔案輸出快取
  logfile        utl_file.file_type; --oracle檔案型別
  logfile_buffer varchar2(4000); --檔案輸出快取
  v_recid       number(10); --表archive log 序號
  v_recidck     number(10); --archivelog_ck 序號
  sql_txt       varchar2(4000); --待執行的 sql_redo
  v_dblink_name varchar2(20) := '@'||database_link_name; --目的資料庫聯接
  sqlwhere      varchar2(1000); --待執行的 sql_redo 條件語句
  v_tableowner  varchar2(20); --待同步的使用者
  v_tablename   varchar2(20); --待同步的表
  v_queueck     number(10); --佇列序列SCN
  v_queuename   varchar(20); --dml佇列名稱

v_sqlcommitnum number(5) := 10000; --已經提交的事務dml 分批提交給目的資料庫
  v_sqlnum    number:= 0; --已經提交的事務dml當前個數

l_string long;
  l_data   myTableType := myTableType();
  n        number;

isDDL      number(1) := 0; --是否是ddl操作 0不是 1是
  isCommited number(1) := 0; --是否已經commit操作 0不是 1是

XID_str varchar2(8000); --事務序號陣列
  j       number := 0; --tb_dml_XIDSQN序列下標
  type tb_XID_type is table of v$logmnr_contents.XID%type index by binary_integer; --定義待排除DLL
  tb_ddl_XID   tb_xid_type; --定義待排除DLL表
  tb_dml_XID   tb_xid_type; --定義待排除DLL表
  duplicat_xid number(1) := 0; -- 0  不重複 1 重複

cursor c_ddl is
    select distinct XID
      from v$logmnr_contents
     where seg_name = v_tablename
       and OPERATION = 'DDL';
begin
--開啟捕獲日誌
  logfile := utl_file.fopen('LOGMNR', 'capture_log.txt', 'a');
  --初始化schema
  v_tableowner := tableowner;
  v_tablename  := tablename;

--捕獲線上日誌
  --dbms_output.put_line('Analyze Redo...Start');
  utl_file.put_line(logfile, '');
  utl_file.put_line(logfile, 'Analyze Redo...Start :'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));

fhandle := utl_file.fopen('SYNCDATACONFIG', 'scn_ck.txt', 'R');
  utl_file.get_line(fhandle, fp_buffer);
  v_scn := fp_buffer;
  utl_file.fclose(fhandle);
  --dbms_output.put_line('1====v_scn:' || v_scn);
  utl_file.put_line(logfile, '1====v_scn:' || v_scn);
  
  for rs in (select f.MEMBER
               from v$logfile f, v$log l
              where f.group# = l.GROUP#
                and l.STATUS = 'CURRENT') loop
    dbms_logmnr.add_logfile(options     => dbms_logmnr.addfile,
                            logfilename => rs.member);
    dbms_logmnr.start_logmnr(options => dbms_logmnr.dict_from_online_catalog);
    --dbms_logmnr.start_logmnr(dictfilename => '/backup/logmnr/rac1emz_testdict.ora');
    --dbms_output.put_line('2====logfilename:' || rs.member);
    utl_file.put_line(logfile, '2====logfilename:' || rs.member);
  
    --待排除DLL
    open c_ddl;
    fetch c_ddl bulk collect
      into tb_ddl_XID;
    close c_ddl;
  
    --待查詢的DML
    for c_tranXID in (select distinct XID
                        from v$logmnr_contents
                       where seg_name = v_tablename) loop
      isDDL:= 0;
      duplicat_xid := 0;
      isCommited   := 0;
      --判斷是否ddl操作
      for i in 1 .. tb_ddl_XID.count loop
        if c_tranXID.XID = tb_ddl_XID(i) then
          isDDL := 1;
          --dbms_output.put_line('3==1 ddl xid:'||c_tranXID.XID);
          utl_file.put_line(logfile, '3==1 ddl xid:'||c_tranXID.XID);
        end if;
      end loop;
      
      --不是dll,新增dml xid
      if isDDL = 0 then
      --dbms_output.put_line('3==1 dml xid:'||c_tranXID.XID);
      utl_file.put_line(logfile, '3==1 dml xid:'||c_tranXID.XID);
      
        --是否已經commit
        for  c_commit in (select XID from v$logmnr_contents
                             where xid = c_tranXID.XID
                               and operation = 'COMMIT') loop
            isCommited := 1;
            --dbms_output.put_line('3==1 COMMITED xid:'||c_commit.xid);
            utl_file.put_line(logfile, '3==1 COMMITED xid:'||c_commit.xid);
        end loop;
        
        if isCommited = 1 then
          --判斷xid事務標識是否已經存在，如果存在不新增,防止重複分析xid
          fhandle := utl_file.fopen('SYNCDATACONFIG', 'xid_array.txt', 'R');
          LOOP
            BEGIN
              utl_file.get_line(fhandle, fp_buffer);
              if rtrim(ltrim(fp_buffer)) = c_tranXID.XID then
                duplicat_xid := 1;
                --dbms_output.put_line('3====2 已分析過xid :' || c_tranXID.XID); --重複xid
                utl_file.put_line(logfile, '3====2 已分析過xid :' || c_tranXID.XID);
              end if;
            exception
              when no_data_found then
                exit;
            END;
          END LOOP;
          --判斷沒有重複的插入表tb_dml_XID
          if duplicat_xid = 0 then
            tb_dml_XID(j) := c_tranXID.XID;
            j := j + 1;
          end if;
          utl_file.fclose(fhandle);
        end if;
      end if;
    end loop;
  
    --沒有dml tran 退出程式
    --dbms_output.put_line('3====3 dml tran count :' || tb_dml_XID.count);
    utl_file.put_line(logfile, '3====3 dml tran count :' || tb_dml_XID.count);
    
    if tb_dml_XID.count = 0 then
      dbms_logmnr.end_logmnr;
      utl_file.put_line(logfile, 'Analyze Redo...End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
      utl_file.fclose(logfile);
      return;
    end if;
  
    --開啟xid事務標識集合，準備新增xid事務標識
    fhandle := utl_file.fopen('SYNCDATACONFIG', 'xid_array.txt', 'a');
    --dbms_output.put_line('4====開啟xid事務標識集合');
    utl_file.put_line(logfile, '4====開啟xid事務標識集合');
    --建立XID_str字串
    --dbms_output.put_line('4====建立XID_str字串');
    utl_file.put_line(logfile, '4====建立XID_str字串');
    
    for i in 1 .. tb_dml_XID.count loop
      if tb_dml_XID.count != 1 then
        if i = 1 then
          --新增入一行xid事務標識
          utl_file.put_line(fhandle, tb_dml_XID(i - 1));
          --dbms_output.put_line('a1_' || tb_dml_XID(i - 1));
          utl_file.put_line(logfile, 'a1_' || tb_dml_XID(i - 1));
          XID_str := tb_dml_XID(i - 1);
        else
          --新增入一行xid事務標識
          utl_file.put_line(fhandle, tb_dml_XID(i - 1));
          --dbms_output.put_line('a2_' || tb_dml_XID(i - 1));
          utl_file.put_line(logfile, 'a2_' || tb_dml_XID(i - 1));
          XID_str := XID_str || ',' || tb_dml_XID(i - 1);
        end if;
      else
        --新增入一行xid事務標識
        utl_file.put_line(fhandle, tb_dml_XID(i - 1));
        --dbms_output.put_line('a3_' || tb_dml_XID(i - 1));
        utl_file.put_line(logfile, 'a3_' || tb_dml_XID(i - 1));
        XID_str := tb_dml_XID(i - 1);
      end if;
    end loop;
    utl_file.fclose(fhandle);
    --dbms_output.put_line('4====關閉xid事務標識集合');
    utl_file.put_line(logfile, '4====關閉xid事務標識集合');
    --dbms_output.put_line('4====XID_str字串: ' || XID_str);
    utl_file.put_line(logfile, '4====XID_str字串: ' || XID_str);
    l_string := XID_str || ',';
    loop
      exit when l_string is null;
      n := instr(l_string, ',');
      l_data.extend;
      l_data(l_data.count) := ltrim(rtrim(substr(l_string, 1, n - 1)));
      l_string := substr(l_string, n + 1);
    end loop;
  
    --佇列
    --讀取佇列開始序列
    fhandle := utl_file.fopen('SYNCDATACONFIG', 'queue_ck.txt', 'R');
    utl_file.get_line(fhandle, fp_buffer);
    utl_file.fclose(fhandle);
    --dbms_output.put_line('5====讀取佇列開始序列');
    utl_file.put_line(logfile, '5====讀取佇列開始序列');
  
    --更新佇列
    v_queueck   := to_number(substr(fp_buffer, 2, 10));
    v_queuename := 'q' || lpad((v_queueck + 1), 10, '0');
    fhandle     := utl_file.fopen('SYNCDATACONFIG', 'queue_ck.txt', 'w');
    utl_file.put_line(fhandle, v_queuename);
    utl_file.fclose(fhandle);
    --dbms_output.put_line('6====更新佇列佇列序列');
    utl_file.put_line(logfile, '6====更新佇列佇列序列');
  
    ----建立佇列
    fhandle := utl_file.fopen('SYNCDATA', v_queuename || '.txt', 'w');
    utl_file.fclose(fhandle);
    utl_file.put_line(logfile, '7====建立佇列v_queuename:' || v_queuename);
    --新增dml
    fhandle := utl_file.fopen('SYNCDATA', v_queuename || '.txt', 'a');
    for c_sql in (select sql_redo, OPERATION
                    from v$logmnr_contents
                   where XID in (select *
                                   from THE (select cast(l_data as mytableType)
                                               from dual))
                     and operation in
                         ('INSERT', 'DELETE', 'UPDATE', 'COMMIT')
                   order by scn) loop
      if c_sql.sql_redo is not null then
        --判斷如果是insert,不擷取ROWID
        if c_sql.OPERATION = 'INSERT' or c_sql.OPERATION = 'COMMIT' then
          if c_sql.OPERATION = 'INSERT' then
            sql_txt := replace(c_sql.sql_redo,
                               '"' || v_tablename || '"',
                               '"' || v_tablename || '"' || v_dblink_name);
            utl_file.put_line(fhandle, sql_txt);
            --dbms_output.put_line('8====sql_redo1:' || sql_txt);
            utl_file.put_line(logfile, '8====sql_redo1:' || sql_txt);
          else
            utl_file.put_line(fhandle, c_sql.sql_redo);
            --dbms_output.put_line('8====sql_redo2:' || c_sql.sql_redo);
            utl_file.put_line(logfile, '8====sql_redo2:' || c_sql.sql_redo);
          end if;
        else
          sql_txt := substr(c_sql.sql_redo,
                            0,
                            instr(c_sql.sql_redo, 'ROWID') - 5);
          sql_txt := replace(sql_txt,
                             '"' || v_tablename || '"',
                             '"' || v_tablename || '"' || v_dblink_name);
          utl_file.put_line(fhandle, sql_txt);
          --dbms_output.put_line('8====sql_redo3:' || sql_txt);
          utl_file.put_line(logfile, '8====sql_redo3:' || sql_txt);
        end if;
      end if;
    end loop;
    utl_file.fclose(fhandle);
  
    --新增一行到 queue_arrary集合
    fhandle := utl_file.fopen('SYNCDATACONFIG', 'queue_array.txt', 'a');
    utl_file.put_line(fhandle, v_queuename);
    utl_file.fclose(fhandle);
    --dbms_output.put_line('11====新增到queue_arrary集合的佇列名稱:' || v_queuename);
    utl_file.put_line(logfile, '10====新增到queue_arrary集合的佇列名稱:' || v_queuename);
  
    --dbms_output.put_line('9====fclose');
    utl_file.put_line(logfile, '11====fclose');
    dbms_logmnr.end_logmnr;
    --dbms_output.put_line('10====end_logmnr');
    utl_file.put_line(logfile, '10====end_logmnr');
  end loop;

v_scn   := dbms_flashback.get_system_change_number();
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'scn_ck.txt', 'w');
  utl_file.put_line(fhandle, v_scn);
  utl_file.fclose(fhandle);
  --dbms_output.put_line('11====v_scn:' || v_scn);
  utl_file.put_line(logfile, '12====v_scn:' || v_scn);
  
  utl_file.put_line(logfile, 'Analyze Redo...End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
  utl_file.fclose(logfile);
  
exception
  when others then
    dbms_logmnr.end_logmnr;
    --dbms_output.put_line(sqlerrm||': '||sqlcode);
    utl_file.put_line(logfile, 'Analyze Redo...End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
    utl_file.put_line(logfile, sqlerrm||': '||sqlcode);
    utl_file.fclose(logfile);
    return;
  
end DataCapture_Redo;
/
```

資料應用,以dblink方式插入到目標端

```
create or replace procedure DataReplicat is
  fhandle     utl_file.file_type; --oracle檔案型別
  fp_buffer   varchar2(4000); --檔案輸出快取
  v_queuename varchar(20); --queue_arrary.txt中的dml佇列名稱
  v_send_ck   varchar(20); --send_ck.txt的dml佇列名稱
  v_run_sql   varchar(4000); --dml

logfile        utl_file.file_type; --oracle檔案型別
  logfile_buffer varchar2(4000); --檔案輸出快取
begin
  --開啟傳送日誌
  logfile := utl_file.fopen('LOGMNR', 'send_log.txt', 'a');
  utl_file.put_line(logfile, '');
  utl_file.put_line(logfile, 'DataReplicat......Start:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));

--讀取send_ck.txt，獲取檢查點
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'send_ck.txt', 'R');
  BEGIN
    utl_file.get_line(fhandle, fp_buffer);
    v_send_ck := fp_buffer;
    --dbms_output.put_line();
    utl_file.put_line(logfile, '1====1v_send_ck:' || v_send_ck);
  exception
    when no_data_found then
      v_send_ck := null;
      --dbms_output.put_line();
      utl_file.put_line(logfile, '1====1v_send_ck is null');
  END;
  utl_file.fclose(fhandle);

--如果send_ck.txt為空,從queue_array.txt讀取第一個佇列名
  if v_send_ck is null then
    fhandle := utl_file.fopen('SYNCDATACONFIG', 'queue_array.txt', 'R');
    BEGIN
      utl_file.get_line(fhandle, fp_buffer); --讀取第一個佇列名
      v_queuename := fp_buffer;
      --dbms_output.put_line();
      utl_file.put_line(logfile, '2====1queue_array.txt head->v_queuename:' ||v_queuename);
      v_send_ck := v_queuename;
    exception
      when no_data_found then
        --queue_arrary.txt沒有佇列直接退出
        --dbms_output.put_line();
        utl_file.put_line(logfile,'2====2queue_array.txt->no queuename!');
        --dbms_output.put_line();
        utl_file.put_line(logfile,'2====2DataReplicat......End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
        return;
    END;
    utl_file.fclose(fhandle);
  else
    --如果send_ck.txt不為空,讀取下一個佇列
    v_queuename := 'q' ||
                   lpad((to_number(substr(v_send_ck, 2, 10)) + 1), 10, '0');
    --dbms_output.put_line();
    utl_file.put_line(logfile,'2====3next queuename:' || v_queuename);
    begin
      fhandle := utl_file.fopen('SYNCDATA', v_queuename || '.txt', 'R');
      utl_file.get_line(fhandle, fp_buffer);
      utl_file.fclose(fhandle);
      --dbms_output.put_line();
      utl_file.put_line(logfile,'2====4queue_array.txt->' || v_queuename);
      v_send_ck := v_queuename;
    exception
      when others then
        --沒有佇列直接退出
        --dbms_output.put_line();
        utl_file.put_line(logfile,'2====5queue_array.txt->no new queuename or dml in queue file!');
        --dbms_output.put_line();
        utl_file.put_line(logfile,'2====5DataReplicat......End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
        utl_file.fclose(logfile);
        return;
    end;
  end if;

--讀取syncdata佇列 v_queuename,執行佇列q***********.txt命令
  fhandle := utl_file.fopen('SYNCDATA', v_queuename || '.txt', 'R');
  LOOP
    BEGIN
      utl_file.get_line(fhandle, fp_buffer);
      v_run_sql := replace(fp_buffer, ';', null);
      if v_run_sql != 'commit' then
        execute immediate v_run_sql;
        --dbms_output.put_line();
        utl_file.put_line(logfile,'3====1run_sql:' || v_run_sql);
      else
        commit;
        --dbms_output.put_line();
        utl_file.put_line(logfile,'3====2commit');
      end if;
    exception
      when no_data_found then
        exit;
    END;
  END LOOP;
  utl_file.fclose(fhandle);

--執行成功後 send_ck.txt記錄該檢查點
  fhandle := utl_file.fopen('SYNCDATACONFIG', 'send_ck.txt', 'w');
  utl_file.put_line(fhandle, v_send_ck);
  utl_file.fclose(fhandle);
  --dbms_output.put_line();
  utl_file.put_line(logfile,'4====v_send_ck changed:' || v_send_ck);
  --dbms_output.put_line();
  utl_file.put_line(logfile,'4====DataReplicat......End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
exception
  when others then
    --dbms_output.put_line();
    utl_file.put_line(logfile,'DataReplicat......End:'||to_char(sysdate,'yyyy-MM-dd hh24:mi:ss'));
    --dbms_output.put_line();
    utl_file.put_line(logfile,sqlerrm);
    rollback;
    utl_file.put_line(logfile,'rollback');
    utl_file.fclose(logfile);
    return;
end DataReplicat;
/

```

部分內容摘自網路，如有侵權，請聯絡

【Oracle】Oracle logminer功能介紹

相關文章