cmakelist 原始碼生成so 檔案 orthanc mysql

vx_guanchaoguo0發表於2024-10-12
原始碼MySql

cmakelist.txt

# Orthanc - A Lightweight, RESTful DICOM Store
# Copyright (C) 2012-2016 Sebastien Jodogne, Medical Physics
# Department, University Hospital of Liege, Belgium
# Copyright (C) 2017-2023 Osimis S.A., Belgium
# Copyright (C) 2024-2024 Orthanc Team SRL, Belgium
# Copyright (C) 2021-2024 Sebastien Jodogne, ICTEAM UCLouvain, Belgium
#
# This program is free software: you can redistribute it and/or
# modify it under the terms of the GNU Affero General Public License
# as published by the Free Software Foundation, either version 3 of
# the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# Affero General Public License for more details.
# 
# You should have received a copy of the GNU Affero General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.

cmake_minimum_required(VERSION 2.8)
cmake_policy(SET CMP0058 NEW)
project(Orthanc)

set(ORTHANC_PLUGIN_VERSION "5.2")
set(ALLOW_DOWNLOADS ON)
set(CMAKE_BUILD_TYPE "Release")

# This is the preferred version of the Orthanc SDK for this plugin
set(ORTHANC_SDK_DEFAULT_VERSION "1.12.0")

# This is the list of the versions of the Orthanc SDK against which
# this plugin will compile
set(ORTHANC_SDK_COMPATIBLE_VERSIONS "0.9.5" "1.4.0" "1.5.2" "1.5.4" "1.9.2" "1.12.0" "1.12.3" "1.12.4")

# This is the minimal version of the Orthanc runtime that will provide
# best performance. If the version of the Orthanc runtime is below
# this minimal version, a warning message will be printed (but the
# plugin will still start).
set(ORTHANC_OPTIMAL_VERSION_MAJOR    1)
set(ORTHANC_OPTIMAL_VERSION_MINOR    12)
set(ORTHANC_OPTIMAL_VERSION_REVISION 4)
set(USE_SYSTEM_ORTHANC_SDK ON)

if (ORTHANC_PLUGIN_VERSION STREQUAL "mainline")
    set(ORTHANC_FRAMEWORK_VERSION "mainline")
    set(ORTHANC_FRAMEWORK_DEFAULT_SOURCE "hg")
else()
    set(ORTHANC_FRAMEWORK_VERSION "1.12.4")
    set(ORTHANC_FRAMEWORK_DEFAULT_SOURCE "path")
endif()
set(ORTHANC_FRAMEWORK_SOURCE "path")
set(ORTHANC_SDK_DEFAULT_VERSION "1.12.4")
set(ORTHANC_SDK_ROOT ${CMAKE_CURRENT_LIST_DIR}/../OrthancFramework/Resources/Orthanc/Sdk-1.12.4)
set(ORTHANC_FRAMEWORK_ROOT ${CMAKE_CURRENT_LIST_DIR}/../OrthancFramework/Sources)


include(${ORTHANC_FRAMEWORK_ROOT}/../Resources/CMake/DatabasesPluginParameters.cmake)

set(ENABLE_MYSQL_BACKEND ON)
set(OPENSSL_STATIC_VERSION "3.0" CACHE STRING "Force the use of OpenSSL 3.0.x" FORCE)

include(${ORTHANC_FRAMEWORK_ROOT}/../Resources/CMake/DatabasesPluginConfiguration.cmake)


if (${CMAKE_SYSTEM_NAME} STREQUAL "Windows")
    execute_process(
            COMMAND
            ${PYTHON_EXECUTABLE} ${ORTHANC_FRAMEWORK_ROOT}/../Resources/WindowsResources.py
            ${ORTHANC_PLUGIN_VERSION} "MySQL storage area plugin" OrthancMySQLStorage.dll
            "MySQL as a database back-end to Orthanc (storage area)"
            ERROR_VARIABLE Failure
            OUTPUT_FILE ${AUTOGENERATED_DIR}/StorageVersion.rc
    )

    if (Failure)
        message(FATAL_ERROR "Error while computing the version information: ${Failure}")
    endif()

    execute_process(
            COMMAND
            ${PYTHON_EXECUTABLE} ${ORTHANC_FRAMEWORK_ROOT}/../Resources/WindowsResources.py
            ${ORTHANC_PLUGIN_VERSION} "MySQL index plugin" OrthancMySQLIndex.dll
            "MySQL as a database back-end to Orthanc (index)"
            ERROR_VARIABLE Failure
            OUTPUT_FILE ${AUTOGENERATED_DIR}/IndexVersion.rc
    )

    if (Failure)
        message(FATAL_ERROR "Error while computing the version information: ${Failure}")
    endif()

    set(INDEX_RESOURCES ${AUTOGENERATED_DIR}/IndexVersion.rc)
    set(STORAGE_RESOURCES ${AUTOGENERATED_DIR}/StorageVersion.rc)
endif()


EmbedResources(
        MYSQL_PREPARE_INDEX          ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/PrepareIndex.sql
        MYSQL_GET_LAST_CHANGE_INDEX  ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/GetLastChangeIndex.sql
        MYSQL_CREATE_INSTANCE        ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/CreateInstance.sql
        MYSQL_DELETE_RESOURCES       ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/DeleteResources.sql
)

if (EXISTS ${ORTHANC_SDK_ROOT}/orthanc/OrthancDatabasePlugin.proto)
    add_custom_command(
            COMMAND
            ${PROTOC_EXECUTABLE} ${ORTHANC_SDK_ROOT}/orthanc/OrthancDatabasePlugin.proto --cpp_out=${AUTOGENERATED_DIR} -I${ORTHANC_SDK_ROOT}/orthanc/
            DEPENDS
            ProtobufCompiler
            ${ORTHANC_SDK_ROOT}/orthanc/OrthancDatabasePlugin.proto
            OUTPUT
            ${AUTOGENERATED_DIR}/OrthancDatabasePlugin.pb.cc
            ${AUTOGENERATED_DIR}/OrthancDatabasePlugin.pb.h
    )

    list(APPEND AUTOGENERATED_SOURCES
            ${AUTOGENERATED_DIR}/OrthancDatabasePlugin.pb.cc
    )
endif()


add_custom_target(
        AutogeneratedTarget
        DEPENDS
        ${AUTOGENERATED_SOURCES}
)

add_library(FrameworkForPlugins STATIC
        ${AUTOGENERATED_SOURCES}
        ${DATABASES_SOURCES}
        ${ORTHANC_DATABASES_ROOT}/Sources/Plugins/PluginInitialization.cpp
        ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/MySQLIndex.cpp
        ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/MySQLStorageArea.cpp
)

set_target_properties(FrameworkForPlugins PROPERTIES
        POSITION_INDEPENDENT_CODE ON
        COMPILE_FLAGS -DORTHANC_ENABLE_LOGGING_PLUGIN=1
)

add_library(OrthancMySQLIndex SHARED
        ${INDEX_RESOURCES}
        ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/IndexPlugin.cpp
)

add_library(OrthancMySQLStorage SHARED
        ${STORAGE_RESOURCES}
        ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/StoragePlugin.cpp
)

add_dependencies(FrameworkForPlugins AutogeneratedTarget)

target_link_libraries(OrthancMySQLIndex FrameworkForPlugins)
target_link_libraries(OrthancMySQLStorage FrameworkForPlugins)

message("Setting the version of the libraries to ${ORTHANC_PLUGIN_VERSION}")

add_definitions(
        -DORTHANC_PLUGIN_VERSION="${ORTHANC_PLUGIN_VERSION}"
)

set_target_properties(OrthancMySQLStorage PROPERTIES
        VERSION ${ORTHANC_PLUGIN_VERSION}
        SOVERSION ${ORTHANC_PLUGIN_VERSION}
        COMPILE_FLAGS -DORTHANC_ENABLE_LOGGING_PLUGIN=1
)

set_target_properties(OrthancMySQLIndex PROPERTIES
        VERSION ${ORTHANC_PLUGIN_VERSION}
        SOVERSION ${ORTHANC_PLUGIN_VERSION}
        COMPILE_FLAGS -DORTHANC_ENABLE_LOGGING_PLUGIN=1
)

install(
        TARGETS OrthancMySQLIndex OrthancMySQLStorage
        RUNTIME DESTINATION lib    # Destination for Windows
        LIBRARY DESTINATION share/orthanc/plugins    # Destination for Linux
)

message(STATUS "$ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/share/orthanc/plugins")

add_executable(UnitTests
        ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/MySQLIndex.cpp
        ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/Plugins/MySQLStorageArea.cpp
        ${CMAKE_CURRENT_LIST_DIR}/Plugins/MySQL/UnitTests/UnitTestsMain.cpp

        ${DATABASES_SOURCES}
        ${GOOGLE_TEST_SOURCES}
        ${AUTOGENERATED_SOURCES}
)

add_dependencies(UnitTests AutogeneratedTarget)

target_link_libraries(UnitTests ${GOOGLE_TEST_LIBRARIES})
set_target_properties(UnitTests PROPERTIES
        COMPILE_FLAGS -DORTHANC_ENABLE_LOGGING_PLUGIN=0
)

if (COMMAND DefineSourceBasenameForTarget)
    DefineSourceBasenameForTarget(FrameworkForPlugins)
    DefineSourceBasenameForTarget(OrthancMySQLIndex)
    DefineSourceBasenameForTarget(OrthancMySQLStorage)
    DefineSourceBasenameForTarget(UnitTests)
endif()

build

  • 目錄下會有一個 cmake_install.cmake
  • 可以看到有install 命令
  • clion 預設不會執行 make --build
  • make .. 編譯該目錄
  • make --build .. 執行編譯 可以到so檔案再build 目錄下
  • make --install .. 執行 cmakelist 中的 install 移動到 /usr/local/share

執行時載入 so 檔案 可以動態引入模組

  • 比如外掛機制 再配置檔案指定路徑
  • 讀取檔案 透過dlopen 載入動態庫

相關文章