[MQTT](https://www.emqx.com/zh/mqtt) 是輕量級的、靈活的物聯網訊息交換和資料傳遞協議，致力於為 IoT 開發人員實現靈活性與硬體/網路資源的平衡。

[ESP32](https://www.espressif.com/zh-hans/products/socs/esp32)  是 ESP8266 的升級版本，除了Wi-Fi模組，該模組還包含藍芽4.0模組。雙核CPU工作頻率為80至240 MHz，包含兩個Wi-Fi和藍芽模組以及各種輸入和輸出引腳， ESP32 是物聯網專案的理想選擇。

在此專案中我們將實現 ESP32 連線到 EMQ X [MQTT Cloud](https://cloud.emqx.cn) 運營和維護的 [免費公共 MQTT 伺服器](https://www.emqx.com/zh/mqtt/public-mqtt5-broker)，並使用 Arduino IDE 來對 ESP32 進行程式設計。 EMQ X Cloud 是由 [EMQ](https://www.emqx.com/zh) 推出的安全的 MQTT 物聯網雲服務平臺，它提供一站式運維代管、獨有隔離環境的 [MQTT 5.0](https://www.emqx.com/zh/mqtt/mqtt5) 接入服務。

## 所需物聯網元件

* ESP32
* Arduino IDE
* [MQTT 5.0 客戶端工具 - MQTT X](https://mqttx.app/zh)
* 部署在 [EMQ X Cloud](https://cloud.emqx.cn) 上的免費的公共 [MQTT 伺服器](https://www.emqx.io/zh)
  - Broker: **broker-cn.emqx.io**
  - TCP Port: **1883**
  - Websocket Port: **8083**

## Arduino 配置

### 安裝 ESP32 開發板

點選 工具 -> 開發板 -> 開發板管理 -> 搜尋 ESP32 -> 點選安裝

![安裝 ESP32 開發板](https://static.emqx.net/images/082b895a83d44063af2da5161e1916d2.png)

### 安裝 PubSub client

專案 -> 載入庫 -> 管理庫... -> 搜尋 PubSubClient -> 安裝 PubSubClient by Nick O’Leary

![安裝 PubSub client](https://static.emqx.net/images/99a1b042e8e54fb487752cf1f0dff75e.png)

## ESP32 Pub/Sub 示意圖

![ESP32 Pub/Sub 示意圖](https://static.emqx.net/images/d6265585d6257fc02c722fe45888bdac.png)

## ESP32 程式碼編寫

### 分步驟連線 MQTT

1. 首先我們將匯入 **WiFi** 和 **PubSubClient** 庫，ESP8266WiFi  庫能夠將 ESP32 連線到 Wi-Fi 網路，PubSubClient  庫能使 ESP32  連線到 MQTT 伺服器釋出訊息及訂閱主題。

```c
   #include <wifi.h>
   #include <pubsubclient.h>
   ```

2. 設定 Wi-Fi 名稱和密碼，以及 MQTT 伺服器連線地址和埠，並這是 topic 為 "esp32/test"

```c
   // WiFi
   const char *ssid = "mousse"; // Enter your WiFi name
   const char *password = "qweqweqwe";  // Enter WiFi password
   
   // MQTT Broker
   const char *mqtt_broker = "broker.emqx.io";
   const char *topic = "esp32/test";
   const char *mqtt_username = "emqx";
   const char *mqtt_password = "public";
   const int mqtt_port = 1883;
   ```

3. 開啟一個序列連線，以便於輸出程式的結果並且連線到 Wi-Fi 網路

```c
   // Set software serial baud to 115200;
   Serial.begin(115200);
   // connecting to a WiFi network
   WiFi.begin(ssid, password);
   while (WiFi.status() != WL_CONNECTED) {
       delay(500);
       Serial.println("Connecting to WiFi..");
   }
   ```

4. 使用 PubSubClient 連線到公共 MQTT Broker。

```c
   client.setServer(mqtt_broker, mqtt_port);
   client.setCallback(callback);
   while (!client.connected()) {
       String client_id = "esp32-client-";
       client_id += String(WiFi.macAddress());
       Serial.printf("The client %s connects to the public mqtt broker\n", client_id.c_str());
       if (client.connect(client_id.c_str(), mqtt_username, mqtt_password)) {
           Serial.println("Public emqx mqtt broker connected");
       } else {
           Serial.print("failed with state ");
           Serial.print(client.state());
           delay(2000);
       }
   }
   ```

5. MQTT 伺服器連線成功後，ESP32 將向 MQTT 伺服器 `esp/test` 釋出訊息和訂閱 `esp/test` 主題訊息。

```c
   // publish and subscribe
   client.publish(topic, "Hi EMQ X I'm ESP32 ^^");
   client.subscribe(topic);
   ```

6. 設定回撥函式將主題名稱列印到串列埠並列印從 `esp32/test` 主題接收的訊息。

```c
   void callback(char *topic, byte *payload, unsigned int length) {
       Serial.print("Message arrived in topic: ");
       Serial.println(topic);
       Serial.print("Message:");
       for (int i = 0; i < length; i++) {
           Serial.print((char) payload[i]);
       }
       Serial.println();
       Serial.println("-----------------------");
   }
   ```

### 完整程式碼

```c
#include <wifi.h>
#include <pubsubclient.h>

// WiFi
const char *ssid = "mousse"; // Enter your WiFi name
const char *password = "qweqweqwe";  // Enter WiFi password

// MQTT Broker
const char *mqtt_broker = "broker.emqx.io";
const char *topic = "esp32/test";
const char *mqtt_username = "emqx";
const char *mqtt_password = "public";
const int mqtt_port = 1883;

WiFiClient espClient;
PubSubClient client(espClient);

void setup() {
 // Set software serial baud to 115200;
 Serial.begin(115200);
 // connecting to a WiFi network
 WiFi.begin(ssid, password);
 while (WiFi.status() != WL_CONNECTED) {
     delay(500);
     Serial.println("Connecting to WiFi..");
 }
 Serial.println("Connected to the WiFi network");
 //connecting to a mqtt broker
 client.setServer(mqtt_broker, mqtt_port);
 client.setCallback(callback);
 while (!client.connected()) {
     String client_id = "esp32-client-";
     client_id += String(WiFi.macAddress());
     Serial.printf("The client %s connects to the public mqtt broker\n", client_id.c_str());
     if (client.connect(client_id.c_str(), mqtt_username, mqtt_password)) {
         Serial.println("Public emqx mqtt broker connected");
     } else {
         Serial.print("failed with state ");
         Serial.print(client.state());
         delay(2000);
     }
 }
 // publish and subscribe
 client.publish(topic, "Hi EMQ X I'm ESP32 ^^");
 client.subscribe(topic);
}

void callback(char *topic, byte *payload, unsigned int length) {
 Serial.print("Message arrived in topic: ");
 Serial.println(topic);
 Serial.print("Message:");
 for (int i = 0; i < length; i++) {
     Serial.print((char) payload[i]);
 }
 Serial.println();
 Serial.println("-----------------------");
}

void loop() {
 client.loop();
}
```

## 執行和測試

1. 使用 Arduino 上傳完整程式碼，並將 esp32 上電

2. 開啟串列埠監視器，選擇 115200 波特率，檢視 ESP32 連線情況

![檢視 ESP32 連線情況](https://static.emqx.net/images/f8cb5792593d29b5b29b0feacd03a26c.png)

3. 使用 MQTT X 客戶端 連線到公共 MQTT 伺服器, 並向 ESP32 傳送訊息

![使用 MQTT X 客戶端向 ESP32 傳送訊息](https://static.emqx.net/images/2dc50309dbba7bdc8a65ec9b4b082b8c.png)

## 總結

至此，我們已成功使 ESP32 連線到 [EMQ X Cloud](https://cloud.emqx.cn) 提供的公共 MQTT 伺服器。 在本專案中我們簡單的將 ESP32 連線到 MQTT 伺服器，這只是 ESP32 較為基礎的能力之一，ESP32 其實還能與各類物聯網感測器相連，並將感測器資料上報至 MQTT 伺服器。

接下來我們將會陸續釋出更多關於物聯網開發及 ESP32 的相關文章，敬請關注。

>版權宣告： 本文為  [EMQ]( https://www.emqx.io/cn/) 原創，轉載請註明出處。
>
>原文連結：[https://www.emqx.com/zh/blog/esp32-connects-to-the-free-public-mqtt-broker](https://www.emqx.com/zh/blog/esp32-connects-to-the-free-public-mqtt-broker)</pubsubclient.h></wifi.h></pubsubclient.h></wifi.h>

ESP32 連線到免費的公共 MQTT 伺服器

相關文章