![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack01.png)

## 背景
CPack 是 CMake 2.4.2 之後的一個內建工具，用於建立軟體的二進位制包和原始碼包。

CPack 在整個 CMake 工具鏈的位置。

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack02.png)

CPack 支援打包的包格式有以下種類：

- 7Z (7-Zip file format)
- DEB (Debian packages)
- External (CPack External packages)
- IFW (Qt Installer Framework)
- NSIS (Null Soft Installer)
- NSIS64 (Null Soft Installer (64-bit))
- NuGet (NuGet packages)
- RPM (RPM packages)
- STGZ (Self extracting Tar GZip compression
- TBZ2 (Tar GZip compression)
- TXZ (Tar XZ compression)
- TZ (Tar Compress compression)
- ZIP (ZIP file format)

## 為什麼要用打包工具

軟體程式想要在生產環境快速被使用，就需要一個一鍵安裝的安裝包，這樣生產環境就可以很方便的部署和使用。

## 選擇 CPack 的原因

C++ 工程大部分都是用 CMake 配置編譯， 而 CPack 是 CMake 內建的工具，支援打包成多種格式的安裝包。因為是 CMake 的內建工具，所以使用的方式也是透過在 CMakeLists.txt 配置引數，就能達到我們的需求。使用起來很方便，容易上手。

## 如何安裝 CPack

安裝 CMake 的時候會把 CPack 一起安裝了，直接透過 yum 或者 apt-get 安裝即可。

## 一個簡單的例子

### 基礎配置

這裡介紹如何打包 rpm 包，deb 的打包是一樣的，區別在於一些配置。Cpack 打包 rpm 用的是 CPack RPM 生成器，用到的配置變數是以 CPACK_RPM_XXX 為字首。最終透過 **rpm-build** 這個工具去打包，所以需要安裝 **rpm-build** 這個工具，可以透過  `sudo yum install -y rpm-build` 安裝。下面配置是用 3.14.5 的 CMake 進行測試的。

現在有一個工程 example，其目錄結構如下：

只需要在 example/CMakeLists.txt 檔案裡面新增如下配置

```markdown
# 設定生成的安裝包名字
set(CPACK_PACKAGE_NAME "example")
# 設定支援指定安裝目錄的控制為 ON                                   
set(CPACK_SET_DESTDIR ON)
# 設定安裝到的目錄路徑
set(CPACK_INSTALL_PREFIX "/home/vesoft/install")   
# 這是生成的安裝的版本號資訊                       
set(CPACK_PACKAGE_VERSION "1.0.0") 
# 設定 group 名字                                     
set(CPACK_RPM_PACKAGE_GROUP "vesoft")      
# 設定 vendor 名字                             
set(CPACK_PACKAGE_VENDOR "vesoft")    
# 設定 license 資訊                                  
set(CPACK_RPM_PACKAGE_LICENSE "Apache 2.0 + Common Clause 1.0")
include(CPack)
```

執行 cmake 命令後, 你會發現當前目錄下面多了兩個檔案 **CPackConfig.cmake **和** CPackSourceConfig.cmake**。 編譯完成後，執行 `cpack -G RPM` 就可將檔案打包成 rpm 包，當前目錄下會生成一個 **_CPack_Packages** 目錄和一個以 .rpm 為字尾名的檔案 **example-1.0.0-Linux.rpm**，**example-1.0.0-Linux.rpm** 就是我們想要的安裝包檔案。

如果想要檢視打包過程的詳細輸出，可以在命令後面新增 `--verbose`。CPack 是根據使用者的配置生成_CPack_Packages/Linux/RPM/SPECS/example.spec 檔案，然後讓 rpm-build 用。

上面配置生成的安裝包 **example-1.0.0-Linux.rpm**裡面包含的檔案如下：

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack03.png)

⚠️注意：假如安裝時出現 `file /home from install of example-1.0.0-1.x86_64 conflicts with file from package filesystem-3.2-25.el7.x86_64`，那麼需要在配置檔案裡面新增以下配置，讓生成的 rpm 檔案不包含 /home 和 /home/vesoft 。

```markdown
set(CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION "/home")
list(APPEND CPACK_RPM_EXCLUDE_FROM_AUTO_FILELIST_ADDITION "/home/vesoft")
```

### 新增行為

我們要在安裝前後、解除安裝前後做一些事情時，可以透過寫相應的指令碼檔案：

- preinst：安裝前指令碼檔案
- postinst：安裝後指令碼檔案
- prerm：解除安裝前檔案
- postrm：解除安裝後檔案

在上述的 CMakeLists.txt 檔案裡面新增如下配置：

```markdown
# 設定安裝前執行的指令碼檔案 preinst
set(CPACK_RPM_PRE_INSTALL_SCRIPT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/scripts/preinst)
# 設定解除安裝前執行的指令碼檔案 prerm
set(CPACK_RPM_PRE_UNINSTALL_SCRIPT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/scripts/prerm)
# 設定安裝後執行的指令碼檔案 postinst
set(CPACK_RPM_POST_INSTALL_SCRIPT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/scripts/postinst)
# 設定解除安裝後執行的指令碼檔案 postrm
set(CPACK_RPM_POST_UNINSTALL_SCRIPT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/scripts/postrm)
```

CPack 會將上面配置的指令碼里面的內容寫到生成的 SPEC 檔案裡面去。

⚠️注意：上述的四個指令碼檔案需要的許可權是所有使用者和使用者組均能執行，建立完指令碼檔案後，透過 `chmod 755 scripts/*`  修改 scripts 目錄下面的指令碼檔案的許可權。

執行 `sudo rpm -ivh example-1.0.0-Linux.rpm` 命令會有以下輸出

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack04.png)

執行 `sudo rpm -e example-1.0.0` 會有以下輸出

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack05.png)

可以看到圖片裡面綠色和紅色字樣，就是四個指令碼檔案的列印輸出，分別對應安裝前後和解除安裝前後執行列印。所以使用者可以在這四個指令碼里面實現自己想要的功能。

### 分裝多個包

上述配置是將所有需要打包的檔案打包成一個安裝包，但一個專案往往會有多個不同服務，在實施部署時需安裝到不同的機子上，這個時候如果把所有服務一起打包，會導致部署時包太大。這個時候就需要用上 CPack 的 Components 功能。

下面介紹在這個過程需要用到的三個函式：**cpack_add_component** 和 **cpack_add_component_group**，還有 **install**。

以下為新增 **install** 的函式定義

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack06.png)

以下為新增 **component** 的函式定義

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack07.png)

以下為新增 **group** 的函式定義

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack08.png)

以上述為例，假如我們要將 program A 和它的配置檔案 A.conf 打成一個 rpm 包，將 program B 和它的配置檔案 B.conf 打成一個 rpm 包，則需要在 CMakeLists.txt 裡新增以下內容，把上述配置的 include(CPack) 移到下面配置的位置：

```markdown
# 設定每個分組打包成一個 rpm 包
set(CPACK_COMPONENTS_GROUPING ONE_PER_GROUP)
# 設定支援 COMPONENT
set(CPACK_RPM_COMPONENT_INSTALL ON)

include(CPack)

# 新增一個名為 AComponent 的 component
cpack_add_component(AComponent
    DISPLAY_NAME  "A program"
    DESCRIPTION   "The program for test"
    GROUP Aprogram)
# 新增一個名為 BComponent 的 component
cpack_add_component(BComponent
    DISPLAY_NAME  "B program"
    DESCRIPTION   "The program for test"
    GROUP Bprogram)
# 新增一個名為 Aprogram 的 group, 這個名字會作為 rpm 包名字的一部分
cpack_add_component_group(Aprogram)
# 新增一個名為 Bprogram 的 group
cpack_add_component_group(Bprogram)
```

然後修改 src/CMakeLists.txt，看下圖紅框內容，將 program A 二進位制檔案配置為 AComponent，將 program B 二進位制檔案配置為 BComponent。

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack09.png)

修改 etc/CMakeLists.txt，看下圖紅框內容，將配置檔案 A.conf 配置為 AComponent， 將配置檔案 B.conf 配置為 BComponent。

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack10.png)

更新 CMakeLists.txt 的配置之後，重新執行下 cmake 命令生成新的 makefile 檔案，並執行 `cpack -G RPM`，你可以在當前目錄下面看到生成兩個檔案 **example-1.0.0-Linux-Aprogram.rpm** 和 **example-1.0.0-Linux-Bprogram.rpm**, 它們各自包含的檔案如下：

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack11.png)

### 其他常用引數

- 安裝到指定目錄：上述配置，生成的安裝包只能安裝到 **/home/vesoft/install** 目錄，假如使用者希望能夠安裝指定位置，這個時候需要在 **include(CPack)** 之前新增以下配置

```markdown
# 將上述配置設定指定目錄這個選項置為 OFF
set(CPACK_SET_DESTDIR OFF)
# 設定可重定目錄的選擇為 ON
set(CPACK_RPM_PACKAGE_RELOCATABLE ON)
# 設定預設重定的目錄
set(CPACK_PACKAGING_INSTALL_PREFIX "/home/vesoft/install")
```

透過上述配置，重新生成的 rpm 包就可以支援安裝到其他指定目錄，下面是把它安裝到 **/home/test/install**，使用如下：

```markdown
sudo rpm -ivh example-1.0.0-Linux-Aprogram.rpm --prefix=/home/test/install
```

使用者可以透過 **CPACK_RPM_SPEC_MORE_DEFINE** 這個引數在生成的 SEPC 檔案裡面增加相應的宏，來應用 rpmbuild 的一些功能開關。

## 更多…

CPack 有很多引數，不同版本引數有些差異，想要了解更多，可以去 CMake 官網檢視，見 [CPack](https://cmake.org/cmake/help/latest/module/CPack.html)。或直接透過 `CPack --help` 獲取引數描述。

**Nebula Graph** 也是採用 CPack 進行打包成 rpm 和 deb 包，您可以透過 [https://github.com/vesoft-inc/nebula/releases](https://github.com/vesoft-inc/nebula/releases) 獲取到 **Nebula Graph 每次 release 釋出的包**。

![](https://www-cdn.nebula-graph.com.cn/nebula-blog/Cpack12.png)

本文中如有任何錯誤或疏漏歡迎去 GitHub：[https://github.com/vesoft-inc/nebula](https://github.com/vesoft-inc/nebula) issue 區向我們提 issue 或者前往官方論壇：[https://discuss.nebula-graph.com.cn/](https://discuss.nebula-graph.com.cn/) 的 `建議反饋` 分類下提建議 ?；加入 Nebula Graph 交流群，請聯絡 Nebula Graph 官方小助手微訊號：[NebulaGraphbot](https://www-cdn.nebula-graph.com.cn/nebula-blog/nbot.png)

> 作者有話說：Hi，我是 Laura，是圖資料庫 Nebula Graph 研發工程師，希望做的分享能給大家帶來幫助，如有不當之處也希望能幫忙糾正，謝謝~

CPack 入門指南

相關文章