百度 AI 提供了一個計程車發票掃描介面：

https://ai.baidu.com/ai-doc/OCR/Zk3h7xxnn

支援識別全國各大城市計程車票的 16 個關鍵欄位，包括髮票號碼、程式碼、車號、日期、總金額、燃油附加費、叫車服務費、省、市、單價、里程、上車時間、下車時間等。

![](https://img-blog.csdnimg.cn/img_convert/a6fbe49a2bffeb6578c693b2f7378300.png)

我們首先在 postman 裡呼叫該介面。

url：https://aip.baidubce.com/rest/2.0/ocr/v1/taxi_receipt?access_token=[這裡傳入 Access Token]

![](https://img-blog.csdnimg.cn/img_convert/8ea317d709685e945d87233287d822ac.png)

按照介面文件的說明，content-type 設定為 application/x-www-form-urlencoded：

![](https://img-blog.csdnimg.cn/img_convert/d1c9e92e791e61b75a2bf7fa3b4758ee.png)

在 body 裡，型別選擇為 x-www-form-urlencoded:

指定引數的 key 為 image，value 為發票圖片二進位制資料對應的 base 64 編碼的 url encode 值。

下圖是一個例子。點選 Send 按鈕，會收到下圖所示的響應資料，該發票裡的關鍵資訊被 API 成功解析。
![](https://img-blog.csdnimg.cn/img_convert/6a6dfc3ab94ad13cb61614f1c6d92d1c.png)

這裡我們需要注意一點，在 postman 裡，我們指定引數 image 的值，是沒有經過 url encode 的圖片 base64 encode 的值，即下圖圖例 A。

![](https://img-blog.csdnimg.cn/img_convert/01aa5518edc7e4e12ac65753203cfdab.png)

而 postman 在傳送該 HTTP 請求時，會自動把該base 64 的值做一次 url encode 處理，比如 base64 裡的符號 "/", 被處理成了 %2F. 見上圖 B 的圖例。

也就是說，我們在編寫 ABAP 程式碼時，需要手動呼叫 cl_http_utility=>escape_url 執行這個 encode 動作。

下面是 ABAP 程式碼實現，邏輯不難。

```abap
report z.

DATA: http_client TYPE REF TO if_http_client.
DATA: ls_token TYPE string.
DATA: lv_token TYPE string.
DATA: url type string.

url = 'https://aip.baidubce.com/rest/2.0/ocr/v1/taxi_receipt'.
ls_token = '這裡需要填寫你實際獲取的 Access Token'.
CONCATENATE url '?access_token=' ls_token INTO lv_token.

CALL METHOD cl_http_client=>create_by_url
    EXPORTING
      url    = lv_token
    IMPORTING
      client = http_client.

http_client->propertytype_logon_popup = http_client->co_enabled .
http_client->propertytype_redirect = http_client->co_disabled .

CALL METHOD http_client->request->set_header_field
    EXPORTING
      name  = '~request_method'
      value = 'POST'.                 "

CALL METHOD http_client->request->set_header_field
    EXPORTING
      name  = '~request_protocol'
      value = 'HTTPS/1.1'.

CALL METHOD http_client->request->set_header_field
    EXPORTING
      name  = 'Content-Type'
      value = 'application/x-www-form-urlencoded; charset=utf-8'.

*----------上傳圖片並轉換成base64格式 start------------
types: begin of ty_pic,
           pic_data(1024) type x,
         end of ty_pic.
data:       path_string type string.
*parameters: p_file      like rlgrap-filename obligatory.
data:       lv_content  type xstring.
data:       encode_str  type string.
data:       len         type i.
data:       pic_tab     type table of ty_pic."二進位制內表

*  path_string = p_file.
  call function 'GUI_UPLOAD'
    exporting
      "filename   = path_string
      filename   = 'C:\Users\I042416\Documents\1.jpg'
      filetype   = 'BIN'
    importing
      filelength = len
    tables
      data_tab   = pic_tab[].

call function 'SCMS_BINARY_TO_XSTRING'
    exporting
      input_length = len
    importing
      buffer       = lv_content
    tables
      binary_tab   = pic_tab[]
    exceptions
      failed       = 1
      others       = 2.

" xstring轉base64
  CALL FUNCTION 'SCMS_BASE64_ENCODE_STR'
  EXPORTING
    input  = lv_content
  IMPORTING
    output = encode_str.
*----------上傳圖片並轉換成base64格式 end--------------

"set body body內傳base64格式圖片
data: gv_json_send TYPE string.
data: lv_len       TYPE i.

encode_str = cl_http_utility=>escape_url( encode_str ).
CONCATENATE 'image=' encode_str INTO gv_json_send.
  lv_len = strlen( gv_json_send ).

CALL METHOD HTTP_CLIENT->REQUEST->SET_CDATA
    EXPORTING
      DATA   = gv_json_send
      OFFSET = 0
      LENGTH = lv_len.

CALL METHOD http_client->send
    EXCEPTIONS
      http_communication_failure = 1
      http_invalid_state         = 2.

CALL METHOD http_client->receive
    EXCEPTIONS
      http_communication_failure = 1
      http_invalid_state         = 2
      http_processing_failed     = 3.

IF sy-subrc <> 0.
    DATA:l_sysubrc    TYPE sysubrc,
         l_error_text TYPE string.
    l_sysubrc = sy-subrc.
    CALL METHOD http_client->get_last_error
      IMPORTING
        code    = l_sysubrc
        message = l_error_text.
  ENDIF.

"Read HTTP RETURN CODE
DATA:http_status_code TYPE i,
     status_text      TYPE string.
  CALL METHOD http_client->response->get_status
    IMPORTING
      code   = http_status_code
      reason = status_text
      .
  WRITE: / 'HTTP_STATUS_CODE = ',
          http_status_code,
         / 'STATUS_TEXT = ',
         status_text.

"READ RESPONSE DATA
DATA:w_result TYPE string.
  CALL METHOD http_client->response->get_cdata
    RECEIVING data = w_result .

* 獲取返回的資料
  DATA: r_value    TYPE string,
        r_value1   TYPE string,
        r_fields   TYPE tihttpnvp,
        r_h_fields TYPE tihttpnvp.
  http_client->response->get_header_fields( CHANGING fields =  r_h_fields ). "返回表資料
```
最後在 ABAP 端接收到成功解析的結果：
![](https://img-blog.csdnimg.cn/img_convert/1577ce658a7f80361a52516c9e229b1f.png)

用 ABAP 呼叫 OCR 介面實現計程車發票掃描

相關文章