【cmake系列使用教程】
這個系列的文章翻譯自官方cmake教程：cmake tutorial。
示例程式地址：github.com/rangaofei/t…
不會僅僅停留在官方教程。本人作為一個安卓開發者，實在是沒有linux c程式開發經驗，望大佬們海涵。教程是在macos下完成，大部分linux我也測試過，有特殊說明的我會標註出來。本教程基於cmake-3.10.2，同時認為你已經安裝好cmake。
本節將為我們的專案新增安裝規則和測試支援。此處僅講解教程中新增的一些規則，後續有詳細章節講解定製自己的安裝規則。只適用於macos和linux。
設定安裝規則
安裝規則相當簡單。對於mathfunction庫，我們設新增了這個庫，通過將以下兩行新增到mathfunction的CMakeLists.txt中來安裝標頭檔案和靜態庫:
install (TARGETS MathFunctions DESTINATION bin)
install (FILES MathFunctions.h DESTINATION include)
複製程式碼然後根目錄下的CMakeLusts.txt檔案中新增如下行,用來安裝可執行檔案和配置檔案：
# add the install targets
install (TARGETS Tutorial DESTINATION bin)
install (FILES "${PROJECT_BINARY_DIR}/TutorialConfig.h"
DESTINATION include)
複製程式碼注意上邊install的第一個引數和第三個引數。
TARGETS包含六種形式：ARCHIVE, LIBRARY, RUNTIME, OBJECTS, FRAMEWORK, BUNDLE。注意Mathfunction安裝的是LIBRARY，而根目錄下的可執行檔案是RUNTIME型別。
FILE 將給定的檔案複製到指定目錄。如果沒有給定許可權引數，則由該表單安裝的檔案預設為OWNER_WRITE、OWNER_READ、GROUP_READ和WORLD_READ。
TARGETS和FILE可指定為相對目錄和絕對目錄。
DESTINATION在這裡是一個相對路徑，取預設值。在unix系統中指向 /usr/local 在windows上c:/Program Files/${PROJECT_NAME}。
也可以通過設定CMAKE_INSTALL_PREFIX這個變數來設定安裝的路徑，那麼安裝位置不指向/usr/local，而指向你所指定的目錄。
cmake .
make
makeinstall
複製程式碼執行完畢後即安裝了軟體。
示例中指向的安裝地址如下表所示:
| 檔案/庫 | 安裝位置 |
|---|---|
| MathFunctions | /usr/local/bin/ |
| MathFunctions.h | /usr/local/include/ |
| Tutorial | /usr/local/bin/ |
| TutorialConfig.h | /usr/local/include |
新增測試
新增測試也非常簡單，在根目錄下的CMakeLists.txt檔案最後新增如下程式碼來測試輸入引數後產生的結果是否正確。
include(CTest)
# does the application run
add_test (TutorialRuns Tutorial 25)
# does it sqrt of 25
add_test (TutorialComp25 Tutorial 25)
set_tests_properties (TutorialComp25 PROPERTIES PASS_REGULAR_EXPRESSION "25 is 5")
# does it handle negative numbers
add_test (TutorialNegative Tutorial -25)
set_tests_properties (TutorialNegative PROPERTIES PASS_REGULAR_EXPRESSION "-25 is 0")
# does it handle small numbers
add_test (TutorialSmall Tutorial 0.0001)
set_tests_properties (TutorialSmall PROPERTIES PASS_REGULAR_EXPRESSION "0.0001 is 0.01")
# does the usage message work?
add_test (TutorialUsage Tutorial)
set_tests_properties (TutorialUsage PROPERTIES PASS_REGULAR_EXPRESSION "Usage:.*number")
複製程式碼構建專案完成後，可以執行ctest命令列工具來執行測試。第一個測試只是驗證應用程式是否正常執行，沒有發生崩潰，並且返回值是0。這是CTest測試的基本形式。接下來的幾個測試都使用PASS_REGULAR_EXPRESSION測試屬性來驗證測試的輸出是否包含特定的字串。
如果您想要新增許多測試來測試不同的輸入值，您可以考慮建立如下的巨集(相當於函式):
#define a macro to simplify adding tests, then use it
macro (do_test arg result)
add_test (TutorialComp${arg} Tutorial ${arg})
set_tests_properties (TutorialComp${arg}
PROPERTIES PASS_REGULAR_EXPRESSION ${result})
endmacro (do_test)
# do a bunch of result based tests
do_test (25 "25 is 5")
do_test (-25 "-25 is 0")
複製程式碼構建專案後執行ctest可得到如下結果：
~/Desktop/Tutorial/Step3/build/ ctest
Test project /Users/saka/Desktop/Tutorial/Step3/build
Start 1: TutorialRuns
1/5 Test #1: TutorialRuns ..................... Passed 0.00 sec
Start 2: TutorialComp25
2/5 Test #2: TutorialComp25 ................... Passed 0.01 sec
Start 3: TutorialNegative
3/5 Test #3: TutorialNegative ................. Passed 0.00 sec
Start 4: TutorialSmall
4/5 Test #4: TutorialSmall .................... Passed 0.00 sec
Start 5: TutorialUsage
5/5 Test #5: TutorialUsage .................... Passed 0.00 sec
100% tests passed, 0 tests failed out of 5
Total Test time (real) = 0.03 sec
複製程式碼可以看到，測試全部通過。
新增系統自檢
有時候我們可能會為多種平臺開發程式，而有的平臺包含某個庫，有的平臺不包含這個庫，那麼我們就可以通過系統自檢來判斷是使用平臺系統提供的庫還是自己編寫的庫。
下邊我們將新增一些依賴於目標平臺是否具有log和exp函式的程式碼。當然，幾乎每個平臺都有這些功能，但本教程假設它們不太常見。如果平臺有log庫，那麼我們將使用它來計算平方根，而不適用mysqrt中的函式。
首先使用CheckFunctionExists.cmake巨集來測試這些函式的是否存在。在頂級CMakeLists.txt檔案中編寫程式碼如下:
# does this system provide the log and exp functions?
include (CheckFunctionExists)
check_function_exists (log HAVE_LOG)
check_function_exists (exp HAVE_EXP)
複製程式碼然後在TutorialConfig.h.in中新增使用上邊定義的變數的程式碼：
// does the platform provide exp and log functions?
#cmakedefine HAVE_LOG
#cmakedefine HAVE_EXP
複製程式碼有一點需要注意：log和exp的測試程式碼一定要在TutorialConfig.h的configure_file命令之前。configure.file命令會立即使用CMake中的當前設定配置檔案。最後，在mysqrt函式中，我們可以提供一個基於log和exp的替代實現，如果它們在系統上可用以下程式碼可用:
// if we have both log and exp then use them
#if defined (HAVE_LOG) && defined (HAVE_EXP)
result = exp(log(x)*0.5);
#else // otherwise use an iterative approach
...
複製程式碼