我們知道 ABAP 系統裡有一個有用的工具，事物碼 SE10，輸入使用者名稱稱，可以檢視該使用者在本系統上建立的傳輸請求(Transport Request)列表：

![](https://img-blog.csdnimg.cn/img_convert/6c79e0b9493c640d5e703ee2debc78f9.png)

點選 Display 按鈕，能看到使用者名稱 WANGJER 下面的所有傳輸請求：

![](https://img-blog.csdnimg.cn/img_convert/0c6ac2cf5df109764cffdc9d0f1ef4a2.png)

每個傳輸請求可以展開，檢視裡面具體包含的 ABAP 物件。很多 ABAP 物件，比如上圖藍色高亮的 ABAP 類方法，雙擊之後，可以用 ABAP 編輯器開啟這些方法，檢視其實現原始碼。

本教程我們已經用了幾個步驟的篇幅，介紹了 ABAP ALV 的開發步驟：

* [44. 27 行程式碼開發一個最簡單的 SAP ALV 報表](https://jerry.blog.csdn.net/article/details/123010291)
* [45. 48 行程式碼給 ABAP ALV 報表的資料行增添顏色效果](https://jerry.blog.csdn.net/article/details/123017241)
* [46. 77 行程式碼實現ABAP ALV 中的雙擊事件處理](https://jerry.blog.csdn.net/article/details/123020730)
* [47. SAP ABAP ALV 層次順序表如何使用雙表頭(Multiple Headers)進行資料輸出](https://jerry.blog.csdn.net/article/details/126443398)
* [48. 如何在 SAP ABAP ALV 報表裡以交通燈的方式顯示某一列的值](https://jerry.blog.csdn.net/article/details/126676314)
* [49. 在彈出對話方塊視窗裡顯示 SAP ABAP ALV 列表](https://jerry.blog.csdn.net/article/details/126795526)

本文我們來使用以前所學習的知識，動手開發一個類似 SE10 的工具。這個工具也是筆者實際工作中開發的一個工具，這裡分享給各位 ABAP 學習者。

這個工具允許使用者輸入指定的使用者名稱，執行之後，在 ALV 列表裡列出該使用者在該系統建立的所有傳輸請求，並自動把傳輸請求裡包含的 ABAP 物件(包括 ABAP 類，ABAP DDIC 物件等等)也顯示出來，如下圖所示：

![](https://img-blog.csdnimg.cn/img_convert/1a99dd6643de6879597b9f4751ca785a.png)

![](https://img-blog.csdnimg.cn/img_convert/e9c4a3993d20c51e965b8b518bf52e63.png)

單擊上圖的 ALV 行專案，同樣能自動跳轉到 ABAP 編輯器裡，開啟這些 ABAP 物件，效果如下圖所示：

![](https://img-blog.csdnimg.cn/img_convert/c99be252c8a50b6e798ff786571a59c3.png)

下面我們介紹這個工具的詳細設計思路，開發步驟和全部原始碼。

這個工具的主幹程式很精簡，程式碼如下，包含 4 個 ABAP include 程式。每個 ABAP include 程式負責實現一項特定的業務邏輯。透過將業務邏輯拆分到不同的 ABAP include 程式，使我們工具實現的程式碼結構和邏輯更清晰，可讀性更好。

主幹程式和 4 個 ABAP include 程式的 smc，代表 Social Media Cockpit，這是筆者當時參與的 CRM 專案的縮寫。

![](https://img-blog.csdnimg.cn/img_convert/9002ad20a84660f039b599e6459f94f8.png)

# zsmc_data

我們在 SE38 裡建立的 ABAP 程式，預設型別都是可以執行的報表，即 `executable program`，如果要建立 `include program`，從下拉選單裡選擇對應的型別即可。

![](https://img-blog.csdnimg.cn/img_convert/4416fb600a93c73964a78279f83a7aa1.png)

這個 include 的任務是定義所有需要在這個工具裡使用到的 ABAP 變數：

![](https://img-blog.csdnimg.cn/img_convert/b7fa1c44008b7d769822c463028fe950.png)

# ZSMC_TR

這個 include 的任務是從資料庫表 `e070` 裡讀取出指定使用者在當前 ABAP 系統裡建立的所有傳輸請求的 id，儲存到 ABAP 內表 `lt_trlist` 裡。

![](https://img-blog.csdnimg.cn/img_convert/041218edfd936a25ae6c47fcbd931b16.png)

比如在筆者使用的 AG3 系統上，我總共建立了 595 個傳輸請求：

![](https://img-blog.csdnimg.cn/img_convert/cb58c64132b3d46004362d6bdb2345da.png)

`e070` 資料庫表只維護了使用者名稱和傳輸請求 id 之間的關係，如果我們想知道每個傳輸請求裡包含了哪些 ABAP 開發物件，需要採取其他辦法來查詢。

# ZSMC_PREPARE_DATA

這個 ABAP include 負責將 ZSMC_TR include 裡編寫的邏輯，即從 `e070` 資料庫表裡取出的 ABAP 傳輸請求 id 進行解析，取出每一個傳輸請求包含的 ABAP 物件。

解析操作透過 Function Module 完成，解析結果如下圖所示：

![](https://img-blog.csdnimg.cn/img_convert/d04306c864020b79fc54d093679ab3a9.png)

上圖函式的 Tables 引數 `et_e071`，儲存的就是傳輸請求裡包含的不同型別的 ABAP 物件。這些 ABAP 物件的型別，透過欄位 `PGMID` 和 `OBJECT` 進行區分。

- R3TR.CLAS, 代表儲存在傳輸請求裡的是 ABAP 類名稱
- LIMU.METH, 代表儲存在傳輸請求裡的是 ABAP 類的方法實現

![](https://img-blog.csdnimg.cn/img_convert/39e19642e87609db51f6a953348902b4.png)

# ZSMC_ALV

負責 ABAP ALV 的資料顯示和點選事件處理。

如圖所示，我們使用 Function Module `REUSE_ALV_GRID_DISPLAY` 來輸出 ALV 報表。

這個函式有一個輸入引數 `i_callback_user_command`, 可以指定一個使用者自定義的 subroutine，用於處理 ALV 的點選事件。

如下圖所示，當我們單擊 ALV 報表某些可以點選的列時，我們透過程式碼 123 行指定的 subroutine，`ALV_USER_COMMAND` 會自動被觸發，在這個 subroutine 裡我們呼叫自己編寫的另一個 subroutine `display_object`，來實現自動開啟對應的 ABAP 編輯器以檢視的功能。

![](https://img-blog.csdnimg.cn/img_convert/71f5cf133cfa2f9034be05faa4ddac97.png)

比如我們單擊下圖紅色的行專案 `CL_ABAP_GIT_ISSUE_IMAGE_TOOL`，

![](https://img-blog.csdnimg.cn/img_convert/8d563309381a747c5755f733031328ee.png)

從偵錯程式裡的函式上下文呼叫棧能看出，我們編寫的 subroutine `ALV_USER_COMMAND` 被呼叫，輸入引數 `ct_selfield` 包含了被點選的行專案的索引 12，所以我們可以從 ALV 報表的資料來源，lt_dev_object 內表裡，透過 `READ TABLE INDEX XXX` 的 ABAP 語句將該行專案的明細讀取出來：

![](https://img-blog.csdnimg.cn/img_convert/32693bd94bc9dea72b8703d9dc5691ec.png)

行專案 ABAP 物件的型別，透過輸入引數 `ct_selfield` 的欄位 `fieldname` 來區分。如果欄位名稱為 `TRKORR`, 說明這個行專案是一個傳輸請求，此時呼叫第 150 行的工具函式 `TR_PRESENT_REQUEST` 來顯示這個傳輸請求。

否則，說明該行專案是一個普通的 ABAP 物件，此時呼叫能處理絕大多數 ABAP 物件顯示功能的 `RS_TOOL_ACCESS` 來實現 ABAP 物件的顯示操作。

![](https://img-blog.csdnimg.cn/img_convert/964b8163afef4f19893c554fdf226179.png)

ALV 報表裡具體哪些列支援單擊事件處理呢？只需要將傳入函式 `REUSE_ALV_GRID_DISPLAY` 的輸入引數 `it_fieldcat ` 裡包含的每一列對應的 `hotspot` 欄位設定為 `X` 即可。

如下圖所示，程式碼的語義就是，我們期望 `OBJ_NAME` 和 `TRKORR` 這兩列，即物件名稱和傳輸請求號能夠支援單擊操作。
 
![](https://img-blog.csdnimg.cn/img_convert/39333aa92e55a54d85b0418044e4aa79.png)

這兩個支援單擊操作的列如下圖所示，使用者很容易區分，因為其值下有一條下劃線，顯示成超連結的效果。

![](https://img-blog.csdnimg.cn/img_convert/90dfaf2614c470dc6d746f752da510ba.png)

本例完整的原始碼如下：

主程式：

```sql
REPORT ZSMC_OBJECT_LIST.

PARAMETERS: user type usr02-bname DEFAULT sy-uname OBLIGATORY.
INCLUDE zsmc_data.
INCLUDE zsmc_tr.
INCLUDE zsmc_prepare_data.
INCLUDE zsmc_alv.

INITIALIZATION.
  PERFORM init.
START-OF-SELECTION.

PERFORM fill_trlist.
  PERFORM fill_data.
  PERFORM alv_display.
```

ZSMC_DATA：
```sql
*&---------------------------------------------------------------------*
*&  Include           ZSMC_DATA
*&---------------------------------------------------------------------*

TYPES: begin of ty_dev_object,
            obj_name TYPE string,
            pgm_id TYPE char4,
            object TYPE char4,
            trkorr TYPE char20,
            as4user TYPE char12,
            as4date TYPE d,
            as4time TYPE t,
            as4text TYPE char60,
            package TYPE tadir-devclass,
            tech_name TYPE tadir-obj_name,
            color TYPE lvc_t_scol,
       END OF ty_dev_object.

TYPES: tt_dev_object TYPE STANDARD TABLE OF ty_dev_object WITH KEY obj_name pgm_id object trkorr.

DATA: lt_trkorr TYPE TABLE OF scwbtrkorr,
      ls_trkorr LIKE LINE OF lt_trkorr,
      lt_trlist TYPE string_table,
      lt_e070 TYPE STANDARD TABLE OF SCWB_E070,
      lt_e070t TYPE STANDARD TABLE OF SCWB_E07T,
      lt_e070c TYPE STANDARD TABLE OF SCWB_E070C,
      lt_e071  TYPE STANDARD TABLE OF SCWB_E071,
      lt_e071k TYPE STANDARD TABLE OF SCWB_E071K,
      lt_e070a TYPE STANDARD TABLE OF SCWB_E070A,
      lt_dev_object TYPE tt_dev_object,
      ls_dev_object TYPE ty_dev_object.

DATA: lv_col TYPE lvc_s_scol,
      lt_coltab TYPE lvc_t_scol,
      ls_color TYPE lvc_s_colo,
      lt_ic TYPE string_table.

FIELD-SYMBOLS: <e071> LIKE LINE OF lt_e071,
               <e070> LIKE LINE OF lt_e070,
               <e070t> LIKE LINE OF lt_e070t.
```

ZSMC_TR：

```sql
*&---------------------------------------------------------------------*
*&  Include           ZSMC_TR
*&---------------------------------------------------------------------*

FORM fill_trlist.
   PERFORM log USING 10 'Fetching Transport request from DB...'.
   PERFORM add_tr USING user.
ENDFORM.

FORM add_tr USING name TYPE char12.
   DATA: lt_e070 TYPE STANDARD TABLE OF e070.

FIELD-SYMBOLS:<line> TYPE e070.
   SELECT trkorr as4user INTO CORRESPONDING FIELDS OF TABLE lt_e070 FROM e070 WHERE as4user = name.

LOOP AT lt_e070 ASSIGNING <line>.
      APPEND <line>-trkorr TO lt_trlist.
   ENDLOOP.
ENDFORM.

FORM log USING per TYPE i text TYPE string.
   CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
       EXPORTING
           percentage = per
           text = text.
ENDFORM.
```

ZSMC_PREPARE_DATA：

```sql
*&---------------------------------------------------------------------*
*&  Include           ZSMC_PREPARE_DATA
*&---------------------------------------------------------------------*

FORM fill_data.

DATA: lv_tr TYPE string.

LOOP AT lt_trlist INTO lv_tr.
      ls_trkorr-trkorr  = lv_tr.
      ls_trkorr-srcsyst = space.
      APPEND ls_trkorr TO lt_trkorr.
      ls_trkorr-srcsyst = lv_tr(3).
      APPEND ls_trkorr TO lt_trkorr.
ENDLOOP.

CALL FUNCTION 'SCWB_GET_COMPL_REQUESTS_REM_40'
      EXPORTING
        iv_merge_object_lists = ' '
      TABLES
        it_request_numbers    = lt_trkorr
        et_e070               = lt_e070
        et_e07t               = lt_e070t
        et_e070c              = lt_e070c
        et_e071               = lt_e071
        et_e070a              = lt_e070a
      EXCEPTIONS
        error_message         = 0.   "suppres

SORT lt_e070 BY trkorr.
SORT lt_e070t BY trkorr.
PERFORM log USING 50 'Analyzing object information from Transport request...'.
LOOP AT lt_e071 ASSIGNING <e071> WHERE object <> 'CORR' AND object <> 'AVAS' AND object <> 'PDWS' AND object <> 'DLCS' AND object <> 'CDAT'
   AND object <> 'TDAT' AND object <> 'SMIM' AND object <> 'RELE' AND object <> 'MERG' AND object <> 'CLSD' AND object <> 'CPRO'
   AND object <> 'CPUB' AND object <> 'CPRI' AND object <> 'DOCU' AND object <> 'SICF' AND object <> 'MESS' AND object <> 'PIFA'
   AND object <> 'SHI6' AND object <> 'SHI3' AND object <> 'TABU' AND object <> 'VDAT'.
   ls_dev_object-trkorr = <e071>-trkorr.
   ls_dev_object-pgm_id = <e071>-pgmid.
   ls_dev_object-object = <e071>-object.
   ls_dev_object-obj_name = <e071>-obj_name.
   READ TABLE lt_e070t ASSIGNING <e070t> WITH KEY trkorr = <e071>-trkorr BINARY SEARCH.
   IF sy-subrc = 0.
      ls_dev_object-as4text = <e070t>-as4text.
      IF <e070t>-as4text CS 'Generated test transport'.
         CONTINUE.
      ENDIF.
   ENDIF.

READ TABLE lt_e070 ASSIGNING <e070> WITH KEY trkorr = <e071>-trkorr BINARY SEARCH.
   IF sy-subrc = 0.
      ls_dev_object-as4user = <e070>-as4user.
      ls_dev_object-as4date = <e070>-as4date.
      ls_dev_object-as4time = <e070>-as4time.
   ENDIF.
   READ TABLE lt_e070t ASSIGNING <e070t> WITH KEY trkorr = <e071>-trkorr BINARY SEARCH.
   IF sy-subrc = 0.
      ls_dev_object-as4text = <e070t>-as4text.
   ENDIF.

IF <e071>-object <> 'METH'.
       ls_dev_object-tech_name = <e071>-obj_name.
   ELSE.
       PERFORM get_tech_name CHANGING ls_dev_object.
   ENDIF.

APPEND ls_dev_object TO lt_dev_object.
ENDLOOP.

SORT lt_dev_object BY obj_name.
DELETE ADJACENT DUPLICATES FROM lt_dev_object COMPARING obj_name as4user as4text.

ENDFORM.

FORM get_tech_name CHANGING ls_dev_object TYPE ty_dev_object.
   DATA: lt_temp TYPE string_table.
   SPLIT ls_dev_object-obj_name AT space INTO TABLE lt_temp.
   READ TABLE lt_temp INTO ls_dev_object-tech_name INDEX 1.
ENDFORM.

FORM init.
   APPEND 'CRM_IC_APPL_INBOX' TO lt_ic.
   APPEND 'CRM_IC_CMP_INBOX' TO lt_ic.
   APPEND 'CRM_IC_CMP_BTX' TO lt_ic.
   ls_color-col = '6'.
   ls_color-int = '0'.
   ls_color-inv = '0'.
   lv_col-fname = 'OBJECT'.
   lv_col-color = ls_color.
   APPEND lv_col TO lt_coltab.
   lv_col-fname = 'TRKORR'.
   APPEND lv_col TO lt_coltab.
   lv_col-fname = 'AS4USER'.
   APPEND lv_col TO lt_coltab.
   lv_col-fname = 'AS4DATE'.
   APPEND lv_col TO lt_coltab.
   lv_col-fname = 'AS4TIME'.
   APPEND lv_col TO lt_coltab.
   lv_col-fname = 'AS4TEXT'.
   APPEND lv_col TO lt_coltab.
ENDFORM.
```

ZSMC_ALV：
```sql
*&---------------------------------------------------------------------*
*&  Include           ZSMC_ALV
*&---------------------------------------------------------------------*

DATA ls_layout   TYPE slis_layout_alv.
  DATA lt_sort     TYPE slis_t_sortinfo_alv.
  DATA gt_fieldcat TYPE SLIS_T_FIELDCAT_ALV.
  DATA lt_event    TYPE SLIS_T_EVENT.
  data ls_event    type slis_alv_event.

FORM alv_build_fieldcat CHANGING ct_fieldcat TYPE slis_t_fieldcat_alv.

DATA lv_col_pos  TYPE i.
  DATA ls_fieldcat TYPE slis_fieldcat_alv.

CLEAR ct_fieldcat.
  lv_col_pos = 1.

CLEAR ls_fieldcat.
  ls_fieldcat-col_pos      = lv_col_pos.
  ls_fieldcat-fieldname    = 'OBJ_NAME'.
  ls_fieldcat-key          = 'X'.
  ls_fieldcat-hotspot      = 'X'.
  APPEND ls_fieldcat TO ct_fieldcat.
  ADD 1 TO lv_col_pos.

CLEAR ls_fieldcat.
  ls_fieldcat-col_pos      = lv_col_pos.
  ls_fieldcat-fieldname    = 'OBJECT'.
  ls_fieldcat-rollname     = 'CHAR4'.
  ls_fieldcat-reptext_ddic = 'Object TYPE'.
  APPEND ls_fieldcat TO ct_fieldcat.
  ADD 1 TO lv_col_pos.

CLEAR ls_fieldcat.
  ls_fieldcat-col_pos      = lv_col_pos.
  ls_fieldcat-fieldname    = 'TRKORR'.
  ls_fieldcat-rollname     = 'CHAR20'.
  ls_fieldcat-hotspot      = 'X'.
  ls_fieldcat-reptext_ddic = 'TR number'.
  APPEND ls_fieldcat TO ct_fieldcat.
  ADD 1 TO lv_col_pos.

CLEAR ls_fieldcat.
  ls_fieldcat-col_pos      = lv_col_pos.
  ls_fieldcat-fieldname    = 'AS4USER'.
  ls_fieldcat-rollname     = 'CHAR12'.
  ls_fieldcat-reptext_ddic = 'Developer'.
  APPEND ls_fieldcat TO ct_fieldcat.
  ADD 1 TO lv_col_pos.

CLEAR ls_fieldcat.
  ls_fieldcat-col_pos      = lv_col_pos.
  ls_fieldcat-reptext_ddic = 'Date'.
  ls_fieldcat-fieldname    = 'AS4DATE'.
  APPEND ls_fieldcat TO ct_fieldcat.
  ADD 1 TO lv_col_pos.

CLEAR ls_fieldcat.
  ls_fieldcat-col_pos      = lv_col_pos.
  ls_fieldcat-fieldname    = 'AS4TIME'.
  ls_fieldcat-reptext_ddic = 'Time'.
  APPEND ls_fieldcat TO ct_fieldcat.
  ADD 1 TO lv_col_pos.

CLEAR ls_fieldcat.
  ls_fieldcat-col_pos      = lv_col_pos.
  ls_fieldcat-fieldname    = 'AS4TEXT'.
  ls_fieldcat-reptext_ddic = 'Description'.
  APPEND ls_fieldcat TO ct_fieldcat.
  ADD 1 TO lv_col_pos.

ENDFORM.                    "alv_build_fieldcat

FORM alv_build_layout USING es_layout TYPE slis_layout_alv.

es_layout-colwidth_optimize = 'X'.
  es_layout-zebra             = 'X'.
  es_layout-coltab_fieldname = 'COLOR'.

ENDFORM.                    "alv_build_layout

*&---------------------------------------------------------------------*
*&      Form  alv_build_sorting
*&---------------------------------------------------------------------*
FORM alv_build_sorting USING et_sort TYPE slis_t_sortinfo_alv.
  DATA ls_sort LIKE LINE OF et_sort.

CLEAR ls_sort.
  ls_sort-fieldname = 'OBJ_NAME'.
  ls_sort-up = 'X'.
  APPEND ls_sort TO et_sort.

ENDFORM.

FORM html_top_of_page USING document TYPE REF TO cl_dd_document.

DATA: text TYPE sdydo_text_element.
  text =  '使用者傳輸請求檢視小工具'.
  CALL METHOD document->add_text
    EXPORTING
      text      = text
      sap_style = 'HEADING'.

ENDFORM.                    "HTML_TOP_OF_PAGE
FORM alv_display.
  PERFORM alv_build_fieldcat CHANGING gt_fieldcat.
  PERFORM alv_build_layout   USING ls_layout.
  PERFORM alv_build_sorting  USING lt_sort.

ls_event-name = 'DATA_CHANGED'.
  ls_event-form = 'DATA_CHANGED'.
  append ls_event to lt_event.

PERFORM log USING 80 'Determining Package information...'.

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      i_callback_program       = sy-repid
      i_callback_pf_status_set = 'ALV_SET_STATUS'
      i_callback_html_top_of_page = 'HTML_TOP_OF_PAGE'
      i_callback_user_command  = 'ALV_USER_COMMAND'
      is_layout                = ls_layout
      it_fieldcat              = gt_fieldcat
      it_sort                  = lt_sort
      it_events                = lt_event
      i_grid_title             = 'Transport Request Object List'
    TABLES
      t_outtab                 = lt_dev_object
    EXCEPTIONS
      program_error            = 1
      OTHERS                   = 2.
  ASSERT sy-subrc = 0.
ENDFORM.

FORM ALV_USER_COMMAND USING iv_ucomm     LIKE sy-ucomm
                             ct_selfield  TYPE slis_selfield."#EC CALLED .
   PERFORM display_object USING ct_selfield.
ENDFORM.

FORM display_object USING ct_selfield TYPE slis_selfield.
   FIELD-SYMBOLS: <line> TYPE ty_dev_object.

READ TABLE lt_dev_object ASSIGNING <line> INDEX ct_selfield-tabindex.
   CHECK sy-subrc = 0.

IF ct_selfield-fieldname = 'TRKORR'.
     SET PARAMETER ID 'KOR' FIELD <line>-trkorr.
     CALL FUNCTION 'TR_PRESENT_REQUEST'
        EXPORTING
          iv_trkorr    = <line>-trkorr
          iv_highlight = 'X'.
   ELSE.

CALL FUNCTION 'RS_TOOL_ACCESS'
       EXPORTING
         operation   = 'SHOW'
         object_name = <line>-obj_name
         object_type = <line>-object
       EXCEPTIONS
         OTHERS      = 1.
   ENDIF.

ENDFORM.

FORM ALV_SET_STATUS USING it_exclude TYPE table.
   SET PF-STATUS 'ZALV'.
ENDFORM.
```</line></line></line></line></line></line></e071></e071></e070t></e071></e070t></e070></e070></e070></e071></e070></e070t></e070t></e071></e070t></e071></e071></e071></e071></e071></line></line></line></e070t></e070></e071>

動手開發一個有用的 ABAP ALV 工具 - 檢視指定使用者的 ABAP 傳輸請求

相關文章