值語義(Value semantics)和引用語義(reference semantics)描述了動態記憶體物件在多個變數引用它時, 可以表現的兩種方式。

用於特定型別的動態記憶體物件的語義, 對該型別的物件如何消耗記憶體產生了重要影響。

本質上，使用值語義的引用變數總是有它自己的、它所引用的記憶體物件的唯一副本。值語義變數類似於靜態變數；像靜態變數一樣，它直接繫結到它所代表的記憶體物件。儘管變數只是一個引用，但在語義上它是記憶體物件本身。

相比之下，使用引用語義的引用變數被理解為指向記憶體物件的指標。記憶體物件在語義上獨立於引用變數。該物件可以在許多這樣的變數之間共享。

Value Semantics 的典型代表：

- ABAP Internal Tables
- Strings
- Boxed Components

使用值語義解析對 ABAP 內表、字串或 boxed元件的多次引用。 這意味著：

- 內表、字串或 boxed 元件的每個變數都指向它自己的記憶體物件的單獨副本。

- 將內表、字串或 boxed 元件分配給第二個 ABAP 變數會觸發物件的複製操作，以便每個變數都有自己的物件副本。

- 通過特定變數對內表、字串或裝箱元件所做的更改，對於已分配給同一物件的其他變數是不可見的。

由於內部表和字串可能會變得非常大，ABAP 通過採用`惰性複製`(有時也稱為`寫時複製`)策略 (Copy-On-Write) 來節省複製工作量。

我們來看一個具體的例子。

原始碼如下：

```abap
REPORT z.

DATA: lv_size     TYPE abap_msize,
      lv_size1    LIKE lv_size,
      lv_consumed LIKE lv_size.

DATA: lt_table  TYPE TABLE OF tadir,
      lt_table1 LIKE lt_table.

SELECT * INTO TABLE lt_table FROM tadir.

cl_abap_memory_utilities=>get_total_used_size( IMPORTING size = lv_size ).

WRITE:/ 'total consumed: ' , lv_size.

lt_table1 = lt_table.

cl_abap_memory_utilities=>get_total_used_size( IMPORTING size = lv_size1 ).

lv_consumed = lv_size1 - lv_size.

WRITE:/ 'total consumed after = ' , lv_consumed.

APPEND lt_table[ 1 ] TO lt_table.

CLEAR: lv_size.

cl_abap_memory_utilities=>get_total_used_size( IMPORTING size = lv_size ).

lv_consumed = lv_size - lv_size1.
WRITE:/ 'total consumed after copy on write:', lv_consumed.
```

這個測試程式的5個關鍵點：

1. 從資料庫表 `TADIR` 裡讀取其全部資料，儲存到內表 lt_table 內。列印當前應用程式所在的會話總共消耗的記憶體位元組數。
2. 將內表 lt_table 的內容複製給 lt_table1. 這裡並不觸發真實的內表間資料拷貝操作，因為內表 lt_table1 和 lt_table 此刻都指向同一塊記憶體區域。

3. 列印出當前應用程式所在的會話，同第一步執行完畢後的記憶體增量。因為沒有實際的資料拷貝操作，我們可以斷定，這個列印出來的值應該很小。

![](https://img-blog.csdnimg.cn/img_convert/53a7ba1f81d19360e304158a8f4127d7.png)

4. 修改 lt_table 的值，之後，兩個內表指向的記憶體區域不再是同一塊，觸發了 ABAP 的寫時拷貝邏輯，造成了實際的內表拷貝操作，引起了大量的記憶體分配。
5. 列印出第四步執行完後的應用程式記憶體增量。可以斷定，因為 `TADIR` 資料庫的全部內容從一個內表複製到另一個內表，因此這個增量的值和第一個步驟列印的值非常接近。
![](https://img-blog.csdnimg.cn/img_convert/5f58e3db790118c4e49f7077157fc2be.png)

SAP ABAP 寫時拷貝(Copy on Write)策略的一個具體例子

相關文章