Delphi原生JSON框架（二）TJsonArray

_成飞發表於2024-07-18
JSON框架

前面寫了如何快速讀取一個JSON串，但只是針對簡單的型別，如果JSON串中有陣列該怎麼辦呢？

一、例子程式碼

先看下面的程式碼，讀取一個學生的各科成績。

procedure TForm6.Button1Click(Sender: TObject);
var
  jsonstr:string;

  jv:TJSONValue;
  js:TJSONString;
  ja:TJSONArray;
  jo:TJSONObject;

  I: Integer;
begin
  jsonstr:=
            '{' +
            '    "person": {' +
            '        "sex": "男",' +
            '        "name": "王小二",' +
            '        "score": [{' +
            '                "語文": 120' +
            '            },' +
            '            {' +
            '                "數學": 89' +
            '            },' +
            '            {' +
            '                "英語": 100' +
            '            }' +
            '        ]' +
            '    }' +
            '}';

  jv := TJSONValue.ParseJSONValue(jsonstr); //將JSON串轉換為JSON物件，即TJSONValue物件
  if jv <> nil then
  begin

    Log('姓名:' + jv.GetValue<TJSONValue>('person.name').Value); //直接讀取節點值
    Log('性別:' + jv.GetValue<TJSONValue>('person.sex').Value);
    Log('成績');

    if jv.TryGetValue<TJSONArray>('person.score', ja) then  //讀取JSON物件中的陣列物件
    begin
      for I := 0 to ja.Count - 1 do //迴圈陣列物件
      begin
        jo := ja.A[I] as TJSONObject;  //取陣列元素物件
        var pair:= jo.Pairs[0];        //取出Pair物件
        var s1 := pair.JsonString.value; //讀取Pair中鍵名
        var s2 := pair.JsonValue.Value;  //讀取Pair中值
        //var s2:=jo.Values[s1].Value; //也可以根據Pair的鍵名讀取鍵值
        Log(s1 + '=' + s2);
      end;
    end;
    Log(jv.ToString);  //輸出：{"person":{"sex":"男","name":"王小二","score":[{"語文":120},{"數學":89},{"英語":100}]}}
    log(jv.ToJSON);    //輸出：{"person":{"sex":"\u7537","name":"\u738B\u5C0F\u4E8C","score":[{"\u8BED\u6587":120},{"\u6570\u5B66":89},{"\u82F1\u8BED":100}]}}
  end;

end;

執行後輸出的結果：

二、程式碼解讀

透過上面程式碼，重點在於如何解讀JSON中的陣列物件TJSONArray。

TJSONArray都是從TJSONValue繼承而來，所以我們可以象正常一樣，用TryGetValue方法從TJSONValue中讀取一個TJSONArray物件。得到了TJSONArray物件，有兩種方法取到每個元素值：

  • TJSONArray.A[X]
  • TJSONArray.Items[X]

這兩種方式，都返回TJSONValue型別的物件。

迴圈一個TJSONArray，用到了TJSONArray.Count，即資料的長度，也可以用Size，但官方已經明確用Count取代了。從上面的程式碼中摘錄出來：

if jv.TryGetValue<TJSONArray>('person.score', ja) then  //讀取JSON物件中的陣列物件
    begin
      for I := 0 to ja.Count - 1 do //迴圈陣列物件
      begin
        jo := ja.A[I] as TJSONObject;    //取陣列元素物件
        //jo := ja.Items[I] as TJSONObject;//取陣列元素物件的另一種寫法
        //...
      end;
    end;

迴圈一個TJSONArray的另一種寫法，這種寫法更簡潔：

if jv.TryGetValue<TJSONArray>('person.score', ja) then  //讀取JSON物件中的陣列物件
    begin
      var jva:TJSONValue;
      for jva in ja do
      begin
        jo :=jva as TJSONObject;
        //...
      end;
    end;

我們可以快速讀取一個陣列的JSON串了，直接上程式碼：

procedure TForm6.Button2Click(Sender: TObject);
begin
var jsonstr:=
            '{' +
            '    "code": 0,' +
            '    "msg": "Success",' +
            '    "check": true,' +
            '    "datas": [{' +
            '            "id": 1,' +
            '            "name": "測試1",' +
            '            "age": 10' +
            '        },' +
            '        {' +
            '            "id": 2,' +
            '            "name": "測試2",' +
            '            "age": 10' +
            '        },' +
            '        {' +
            '            "id": 3,' +
            '            "name": "測試3",' +
            '            "age": 10' +
            '        },' +
            '        {' +
            '            "id": 4,' +
            '            "name": "測試4",' +
            '            "age": 10' +
            '        },' +
            '        {' +
            '            "id": 5,' +
            '            "name": "測試5",' +
            '            "age": 10' +
            '        }' +
            '    ],' +
            '    "time": "2020-12-03 11:19:08"' +
            '}';

  var jv := TJSONValue.ParseJSONValue(jsonstr);
  Log('code=' + jv.GetValue<TJSONValue>('code').Value);
  Log('msg=' + jv.GetValue<TJSONValue>('msg').Value);
  Log('check=' + jv.GetValue<TJSONBool>('check').Value);
  Log('time=' + jv.GetValue<TJSONValue>('time').Value);
  var ja := jv.GetValue<TJSONArray>('datas');
  var jva: TJSONValue;
  for jva in ja do
  begin
    Log('id=' + jva.GetValue<TJSONValue>('id').Value);
    Log('name=' + jva.GetValue<TJSONValue>('name').Value);
    Log('age=' + jva.GetValue<TJSONValue>('age').Value);
  end;

end;

輸出結果：

透過上面的程式碼，其核心是基於TJSONValue及TJSONArray物件，就解析了這個JSON串！！

如果我們將jva轉換成一個TJSONObject物件，那麼基於TJSONObject物件的GetValue方法，可以改寫這樣：

var ja := jv.GetValue<TJSONArray>('datas');
  var jva: TJSONValue;
  for jva in ja do
  begin
    var jo:=jva as TJSONObject;
    Log('id=' + jo.GetValue('id').Value);
    Log('name=' + jo.GetValue('name').Value);
    Log('age=' + jo.GetValue('age').Value);
  end;

相關文章