批處理安裝綠色版MySQL 5.7.24

1.下載MySQL 5.7.24

https://cdn.mysql.com//Downloads/MySQL-5.7/mysql-5.7.24-winx64.zip

2.進行解壓

解壓後如下

3.建立_mysql.bat，並增加安裝模組

首先加入以下程式碼，以管理員身份啟動，並設定設定mysql路徑

%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
set mysql=C:\Programs\mysql-5.7.24-winx64

增加選擇模組，1:start 2:install 3:uninstall:，預設是1

set option=1
set /p option="1:start 2:install 3:uninstall: "
if %option% equ 1 goto start
if %option% equ 2 goto install
if %option% equ 3 goto uninstall

然後增加install部分，先是建立my.ini配置檔案，接著往裡加入配置，用bat來替代手動建立檔案並輸入

:install
echo [mysql]>>%mysql%\my.ini
echo default-character-set=utf8>>%mysql%\my.ini
echo [mysqld]>>%mysql%\my.ini
echo port = 3307>>%mysql%\my.ini
echo basedir=%mysql:\=\\%>>%mysql%\my.ini
echo datadir=%mysql:\=\\%\\data>>%mysql%\my.ini
echo max_connections=200>>%mysql%\my.ini
echo character-set-server=utf8>>%mysql%\my.ini
echo default-storage-engine=INNODB>>%mysql%\my.ini

建立data資料夾，並初始化以及安裝服務

md %mysql%\data
%mysql%\bin\mysqld.exe --initialize --user=mysql --console
%mysql%\bin\mysqld.exe --install MySQL57

執行_mysql.bat，選擇2.install，等待安裝完畢，如下圖所示

檢視MySQL路徑下，多了my.ini檔案，以及data資料夾

此後，增加啟動以及刪除模組，在此之前，先在指令碼底端增加一個標籤：end，以便所有的模組執行完了都跳轉到末尾，不影響其他的指令碼邏輯。再在%mysql%\bin\mysqld.exe --install MySQL57語句後增加goto end，增加完成以後就可以新增啟動以及刪除模組了

增加啟動以及刪除模組

增加啟動模組

:start
net start MySQL57
goto end

增加刪除模組

:uninstall
net stop MySQL57
del %mysql%\my.ini
rd /s /q %mysql%\data
%mysql%\bin\mysqld.exe --remove MySQL57
goto end

至此，已經完成MySQL自動化構建工具，增加幾個注意的點：
1.在my.ini寫入配置時，如果用的是 ‘’ 而不是 ‘\’ 就會有路徑上的問題，筆者在自身的電腦上對於 ‘’ 沒有問題，但是在公司電腦上，’’ 則是有問題的

2.對於MySQL服務的檢測: 以java -jar啟動專案為例，一般啟動Java專案使用java -jar test.jar，總會有MySQL服務忘記啟動的情況，此時增加如下程式碼，將原有語句包圍，則可以實現執行時檢測：

net start|findstr /I "mysql57">nul && java -jar test.jar || echo MySQL未執行

3.對於編寫的_mysql.bat，切忌不用chcp 65001來改變介面字元，會導致執行時在中文路徑下的找不到路徑問題，但是在筆者自身的電腦上經測試又是沒有問題的，只在公司電腦上出現過