Intellij IDEA 通過資料庫生成 POJO

sisibeloved發表於2019-04-04
IntelliJIdea資料庫POJO

前言

最近寫需求時需要新建許多新表，設計完表結構還要一一寫成對應的 POJO，很麻煩，就 Google 了一下。網上相關資料不多，借鑑了一篇部落格，並在其基礎上進行了完善。

前置步驟

  1. 使用 IDEA 自帶的外掛 Database 連線資料庫
  2. 在資料庫的表上右鍵 Scripted Extensions -> Go to Scripts Directory
  3. 在開啟的目錄下放入指令碼檔案

原始碼

指令碼用的 Groovy 語言，語法類似 Java，並能呼叫 Java 類庫，自己修改也很方便。唯一的麻煩是執行入口在 Intellij 內部，想 debug 很麻煩。

PO 的路徑一般都是統一的，如果要在新的模組中使用需要改一下路徑。另外類註釋需要替換成自己的。

還有一點需要注意的是列舉型別，指令碼中將 tinyint 統一對映成了 Boolean 型別，如果要對映成自定義列舉型別，需要在實體類中自行修改。

用於生成帶 Lombok 註釋的實體類的指令碼

Generate Lombok POJOs.groovy:

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.time.LocalDate

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

// 此處指定包路徑，路徑需要自行維護;
packageName = "com.xxx.xxx.entity;"
// 此處指定對應的型別對映，可按需修改，目前tinyint如果要對映到自定義列舉型別，只能手動修改
typeMapping = [
        (~/(?i)bigint/)                   : "Long",
        (~/(?i)int/)                      : "Integer",
        (~/(?i)tinyint/)                  : "Boolean",
        (~/(?i)float|double|decimal|real/): "BigDecimal",
        (~/(?i)time|datetime|timestamp/)  : "LocalDateTime",
        (~/(?i)date/)                     : "LocalDate",
        (~/(?i)/)                         : "String"
]

// 上面用到類和它的匯入路徑的之間的對映
importMap = [
        "BigDecimal" : "java.math.BigDecimal",
        "LocalDate" : "java.time.LocalDate",
        "LocalDateTime" : "java.time.LocalDateTime",
]

// 匯入路徑列表，下面引用的時候會去重，也可以直接宣告成一個 HashSet
importList = []

// 彈出選擇檔案的對話方塊
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true) + "PO"
    def fields = calcFields(table)
    new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "utf-8")).withPrintWriter { out -> generate(out, className, fields, table) }
}

// 從這裡開始，拼實體類的具體邏輯程式碼
def generate(out, className, fields, table) {
    out.println "package $packageName"
    out.println ""
    out.println ""
    // 引入所需的包
    out.println "import lombok.Data;"
    out.println "import javax.persistence.Id;"
    out.println "import javax.persistence.Table;"
    out.println "import javax.persistence.GeneratedValue;"
    // 去重後匯入列表
    importList.unique().each() { pkg ->
        out.println "import " + pkg + ";"
    }
    out.println ""
    // 新增類註釋
    out.println "/**"
    // 如果新增了表註釋，會加到類註釋上
    if (isNotEmpty(table.getComment())) {
        out.println " * " + table.getComment()
    }
    out.println " *"
    out.println " * @author xxx"
    out.println " * @date " + LocalDate.now()
    out.println " */"
    // 新增類註解
    out.println "@Data"
    out.println "@Table(name = \"${table.getName()}\")"
    out.println "public class $className {"
    out.println ""
    boolean isId = true
    // 遍歷欄位，按下面的規則生成
    fields.each() {
        // 輸出註釋
        if (isNotEmpty(it.comment)) {
            out.println "\t/**"
            out.println "\t * ${it.comment}"
            out.println "\t */"
        }
        // 這邊預設第一個欄位為主鍵，實際情況大多數如此，遇到特殊情況可能需要手動修改
        if (isId) {
            out.println "\t@Id"
            out.println "\t@GeneratedValue(generator = \"JDBC\")"
            isId = false
        }
        out.println "\tprivate ${it.type} ${it.name};"
        out.println ""
    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        if (importMap.containsKey(typeStr)) {
            importList.add(importMap.get(typeStr))
        }
        fields += [[
                           name   : javaName(col.getName(), false),
                           type   : typeStr,
                           comment: col.getComment()
        ]]
    }
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

複製程式碼

用於生成帶 Lombok 註釋並繼承基類的實體類的指令碼

Generate Lombok POJOs extend BaseEntity.groovy:

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.time.LocalDate

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

// 此處指定包路徑，路徑需要自行維護;
packageName = "com.xxx.xxx.entity;"
// 此處指定對應的型別對映，可按需修改，目前tinyint如果要對映到自定義列舉型別，只能手動修改
typeMapping = [
        (~/(?i)bigint/)                   : "Long",
        (~/(?i)int/)                      : "Integer",
        (~/(?i)tinyint/)                  : "Boolean",
        (~/(?i)float|double|decimal|real/): "BigDecimal",
        (~/(?i)time|datetime|timestamp/)  : "LocalDateTime",
        (~/(?i)date/)                     : "LocalDate",
        (~/(?i)/)                         : "String"
]

// 上面用到類和它的匯入路徑的之間的對映
importMap = [
        "BigDecimal" : "java.math.BigDecimal",
        "LocalDate" : "java.time.LocalDate",
        "LocalDateTime" : "java.time.LocalDateTime",
]

// 匯入路徑列表，下面引用的時候會去重，也可以直接宣告成一個 HashSet
importList = []

// 基類中已經有的屬性，就無需在新生成的類中宣告瞭
userTimeList = [
        "create_user_id",
        "update_user_id",
        "create_time",
        "update_time"
]

// 彈出選擇檔案的對話方塊
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true) + "PO"
    def writer = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "utf-8"))
    def fields = calcFields(table)
    writer.withPrintWriter { out -> generate(out, className, fields, table) }
}

// 從這裡開始，拼實體類的具體邏輯程式碼
def generate(out, className, fields, table) {
    out.println "package $packageName"
    out.println ""
    out.println ""
    // 引入所需的包
    out.println "import com.xxx.xxx.entity.BaseEntity;"
    out.println "import lombok.Data;"
    out.println "import lombok.EqualsAndHashCode;"
    out.println "import java.io.Serializable;"
    out.println "import javax.persistence.Id;"
    out.println "import javax.persistence.Table;"
    out.println "import javax.persistence.GeneratedValue;"
    // 去重後匯入列表
    importList.unique().each() { pkg ->
        out.println "import " + pkg + ";"
    }
    out.println ""
    // 新增類註釋
    out.println "/**"
    // 如果新增了表註釋，會加到類註釋上
    if (isNotEmpty(table.getComment())) {
        out.println " * " + table.getComment()
    }
    out.println " *"
    out.println " * @author xxx"
    out.println " * @date " + LocalDate.now()
    out.println " */"
    // 新增類註解
    out.println "@Data"
    out.println "@EqualsAndHashCode(callSuper = false)"
    out.println "@Table(name = \"${table.getName()}\")"
    out.println "public class $className extends BaseEntity implements Serializable {"
    out.println ""
    boolean isId = true
    // 遍歷欄位，按下面的規則生成
    fields.each() {
        // 輸出註釋
        if (isNotEmpty(it.comment)) {
            out.println "\t/**"
            out.println "\t * ${it.comment}"
            out.println "\t */"
        }
        // 這邊預設第一個欄位為主鍵，實際情況大多數如此，遇到特殊情況可能需要手動修改
        if (isId) {
            out.println "\t@Id"
            out.println "\t@GeneratedValue(generator = \"JDBC\")"
            isId = false
        }
        out.println "\tprivate ${it.type} ${it.name};"
        out.println ""
    }
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        // 如果是BaseTimeUserIdPO中已有的欄位，則不再新增
        if (!userTimeList.contains(col.getName())) {
            // 如果是需要匯入的型別，則往list裡面新增
            if (importMap.containsKey(typeStr)) {
                importList.add(importMap.get(typeStr))
            }
            fields += [[
                               name   : javaName(col.getName(), false),
                               type   : typeStr,
                               dbType : col.getDataType(),
                               comment: col.getComment()
                       ]]
        } else {
            fields += []
        }
    }
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

複製程式碼

使用方法

在 Database 中選中需要生成實體類的表（可以多選），右鍵 Scripted Extensions 選擇需要執行的指令碼，在彈出的對話方塊中選擇生成檔案的目標目錄，OK。

參考資料

[1] idea通過資料庫生成java實體類（lombok版）

相關文章