[Neuron](https://www.emqx.com/zh/products/neuron) 是一款開源的輕量級工業協議閘道器軟體，支援數十種工業協議的一站式裝置連線、資料接入、MQTT 協議轉換，為工業裝置賦予工業 4.0 時代關鍵的物聯網連線能力。

開源社群使用者有時會有使用 Neuron 原始碼在當前編譯平臺下編譯能夠執行在體系結構不同的另一種目標平臺上，即進行交叉編譯的需求。在這一過程中可能會遇到由於沒有安裝好依賴庫等原因導致的編譯錯誤。

本文將詳細介紹使用 Neuron 原始碼進行交叉編譯的操作步驟，幫助使用者更好地利用 Neuron 進行進一步的工業物聯網業務開發。

Neuron 原始碼下載：

```shell
$ git clone https://github.com/emqx/neuron
$ cd neuron
$ git submodule update --init
$ mkdir build && cd build
```

## 什麼是交叉編譯

交叉編譯，可以理解為在當前編譯平臺下，編譯出能夠執行在體系結構不同的另一種目標平臺上的可執行程式的過程，經常用於目標平臺無法執行編譯所需的編譯器的情況。

交叉編譯需要用到交叉編譯鏈。交叉編譯鏈是為了編譯跨平臺體系結構的程式程式碼而形成的由多個子工具構成的一套完整的工具集。當指定了原始檔（.c）時，它會自動按照編譯流程呼叫不同的子工具，自動生成可執行檔案。交叉編譯鏈的重點在於交叉編譯器，使用不同平臺的編譯器用來生成可在該平臺執行的可執行程式。所有語句都寫在跨平臺編譯工具 CMake 所依賴的規則檔案 CMakeLists.txt 中，用於構建整個工程。

## Neuron 的交叉編譯流程

下面我們以 X86_64 架構平臺下編譯出可執行於 armv7l 架構的可執行程式為例，介紹對 Neuron 原始碼進行交叉編譯的具體操作。

### 安裝編譯器

執行以下指令安裝適用於 armv7l 架構的編譯器。

```armasm
$ sudo apt-get update
$ sudo apt-get install -y gcc-arm-linux-gnueabihf g++-arm-linux-gnueabihf pkg-config libtool alien unzip
```

### 編寫 .cmake 檔案

.cmake 檔案用於配置 cmake 的變數和屬性。

```routeros
# 目標系統名稱
set(CMAKE_SYSTEM_NAME Linux)
set(COMPILER_PREFIX arm-linux-gnueabihf)
# 目標平臺架構
set(CMAKE_SYSTEM_PROCESSOR armv7l)
# 庫的目錄
set(LIBRARY_DIR /opt/externs/libs)

# 語言編譯器
set(CMAKE_C_COMPILER ${COMPILER_PREFIX}-gcc)
set(CMAKE_CXX_COMPILER ${COMPILER_PREFIX}-g++)

# 靜態庫的歸檔工具名稱
set(CMAKE_AR ${COMPILER_PREFIX}-ar)
set(CMAKE_LINKER ${COMPILER_PREFIX}-ld)
set(CMAKE_NM ${COMPILER_PREFIX}-nm)
set(CMAKE_OBJDUMP ${COMPILER_PREFIX}-objdump)
# 靜態庫隨機化工具名稱
set(CMAKE_RANLIB ${COMPILER_PREFIX}-ranlib)
# CMAKE_STAGING_PREFIX 變數用於指定安裝到主機的路經
set(CMAKE_STAGING_PREFIX ${LIBRARY_DIR}/${COMPILER_PREFIX})
# CMAKE_PREFIX_PATH 變數用於指定要編譯的檔案所在的安裝位置
set(CMAKE_PREFIX_PATH ${CMAKE_STAGING_PREFIX})

include_directories(SYSTEM ${CMAKE_STAGING_PREFIX}/include)
include_directories(SYSTEM ${CMAKE_STAGING_PREFIX}/openssl/include)
# 指定交叉編譯環境
set(CMAKE_FIND_ROOT_PATH ${CMAKE_STAGING_PREFIX})
# 從來不在指定目錄下查詢工具程式
set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
# 只在指定目錄下查詢庫檔案
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
# 只在指定目錄下查標頭檔案
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
link_directories(${CMAKE_STAGING_PREFIX})
```

### 編寫 CMakeLists.txt 檔案

基礎配置及引數配置如下：

```cmake
# 設定 cmake 所需要的最低版本，如果用的 cmake 版本低於該版本，將報錯
cmake_minimum_required(VERSION 3.12)
# 宣告專案名稱
project(neuron)
# 開啟當前及其下級目錄的測試功能
enable_testing()
# 開啟 c 語言的支援
enable_language(C)
set(CMAKE_C_STANDARD 99)
set(CMAKE_CXX_STANDARD 17)

set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

# build 型別，可取值 Debug，Release 等
if(NOT CMAKE_BUILD_TYPE)
  set(CMAKE_BUILD_TYPE "Debug")
endif()

# 要構建的目標平臺的 CMake 識別符號
if(NOT CMAKE_SYSTEM_NAME)
  set(CMAKE_SYSTEM_NAME "Linux")
endif()

if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  add_definitions(-DNEU_PLATFORM_LINUX)
elseif(CMAKE_SYSTEM_NAME MATCHES "Darwin")
  add_definitions(-DNEU_PLATFORM_DARWIN)
elseif(CMAKE_SYSTEM_NAME MATCHES "Windows")
  add_definitions(-DNEU_PLATFORM_WINDOWS)
endif()

# 禁用告警：=ON 表示禁用，=OFF 表示不禁用
if(NOT DISABLE_WERROR)
  set(CMAKE_C_FLAGS "$ENV{CFLAGS} -Werror")
endif()

set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -g")
set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O1")

# 禁用記憶體錯誤檢查：=ON 表示禁用，=OFF 表示不禁用
if(NOT DISABLE_ASAN)
  set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS} -fsanitize=address")
  set(CMAKE_CXX_FLAGS_DEBUG "-Wall -g -fsanitize=address")
endif()
```

依賴庫的查詢：

```reasonml
# 由 CMAKE_STAGING_PREFIX 引數選擇依賴庫檔案查詢的位置，該引數在 .cmake 檔案中配置
if (CMAKE_STAGING_PREFIX)
  # 當進行交叉編譯時，指定標頭檔案的搜尋路徑
  include_directories(${CMAKE_STAGING_PREFIX}/include)
  # 新增需要連結的庫檔案目錄
  link_directories(${CMAKE_STAGING_PREFIX}/lib)
else()
  # 當不進行交叉編譯時，指定標頭檔案的搜尋路徑
  include_directories(/usr/local/include)
  link_directories(/usr/local/lib)
endif()
```

指定 .c 原始檔：

```awk
set(PERSIST_SOURCES
    src/persist/persist.c
    src/persist/json/persist_json_plugin.c)
set(NEURON_SOURCES
    src/main.c
    src/argparse.c
    src/daemon.c
    src/core/manager_internal.c
    src/core/manager.c
    src/core/subscribe.c
    src/core/sub_msg.c
    src/core/plugin_manager.c
    src/core/node_manager.c
    src/core/storage.c
    src/adapter/storage.c
    src/adapter/adapter.c
    src/adapter/driver/cache.c
    src/adapter/driver/driver.c
    plugins/restful/handle.c
    plugins/restful/license.c
    plugins/restful/license_handle.c
    plugins/restful/log_handle.c
    plugins/restful/normal_handle.c
    plugins/restful/rw_handle.c
    plugins/restful/adapter_handle.c
    plugins/restful/datatag_handle.c
    plugins/restful/group_config_handle.c
    plugins/restful/plugin_handle.c
    plugins/restful/version_handle.c
    plugins/restful/rest.c
    plugins/restful/http.c
    plugins/restful/proxy.c
    plugins/restful/websocket.c
    ${PERSIST_SOURCES})

# 設定 build 路徑變數為當前路徑
set(CMAKE_BUILD_RPATH ./)
# 定義可執行檔案的名稱為 neuron，編譯可執行程式
add_executable(neuron)
# 指定原始檔, 與 add_executable 合用，用於將原始檔 NEURON_SOURCES 生成動態連結檔案到 neuron 中。
target_sources(neuron PRIVATE ${NEURON_SOURCES}) 
# 將標頭檔案庫路徑新增到 neuron 中
target_include_directories(neuron PRIVATE include/neuron src plugins)
# 將目標檔案 neuron 與庫檔案進行連結
target_link_libraries(neuron dl neuron-base sqlite3 -lm)
```

### 依賴庫的交叉編譯

在原始碼交叉編譯前，使用者需要先對在交叉編譯中使用的依賴庫進行交叉編譯，使得依賴庫與交叉編譯的平臺保持一致。新建一個目錄檔案用於存放安裝檔案，例如 install。執行指令時所使用的編譯工具，即上述中安裝的相應的編譯器。

cmake 通用引數說明

- -D 配置 cmake 的引數，功能類似於 set；
- CMAKE_C_COMPILER ，交叉編譯宏變數，指定 c 的編譯工具；
- CMAKE_CXX_COMPILER ，交叉編譯宏變數，指定 c++ 的編譯工具 ；
- CMAKE_STAGING_PREFIX ，交叉編譯變數，指定安裝到主機上的路徑 ；
- CMAKE_PREFIX_PATH，交叉編譯變數，指定要編譯的檔案所在的安裝位置；

#### [zlog](https://github.com/HardySimpson/zlog.git)

在 install 目錄下，執行以下指令安裝 zlog 依賴庫。

```shell
$ git clone -b 1.2.15 https://github.com/HardySimpson/zlog.git
$ cd zlog     
$ make CC=arm-linux-gnueabihf-gcc
$ sudo make PREFIX=/opt/externs/libs/arm-linux-gnueabihf install
```

#### [jansson](https://github.com/neugates/jansson.git)

在 install 目錄下，執行以下指令安裝 jansson 依賴庫。

```awk
$ git clone https://github.com/neugates/jansson.git
$ mkdir build && cd build
$ cmake .. -DCMAKE_C_COMPILER=arm-linux-gnueabihf-gcc -DCMAKE_CXX_COMPILER=arm-linux-gnueabihf-g++ -DCMAKE_STAGING_PREFIX=/opt/externs/libs/arm-linux-gnueabihf -DCMAKE_PREFIX_PATH=/opt/externs/libs/arm-linux-gnueabihf -DJANSSON_BUILD_DOCS=OFF -DJANSSON_EXAMPLES=OFF
$ make
$ sudo make install
```

#### [mbedtls](https://github.com/Mbed-TLS/mbedtls.git)

在 install 目錄下，執行以下指令安裝 mbedtls 依賴庫。

```shell
$ git clone -b v2.16.12 https://github.com/Mbed-TLS/mbedtls.git
$ cd mbedtls && mkdir build && cd build
$ cmake -DCMAKE_C_COMPILER=arm-linux-gnueabihf-gcc -DCMAKE_CXX_COMPILER=arm-linux-gnueabihf-g++ -DUSE_SHARED_MBEDTLS_LIBRARY=OFF -DENABLE_TESTING=OFF -DCMAKE_POSITION_INDEPENDENT_CODE=ON .. && make && sudo make install
```

#### [jwt](https://github.com/benmcollins/libjwt.git)

在 install 目錄下，執行以下指令安裝 jwt 依賴庫。

```shell
$ git clone https://github.com/benmcollins/libjwt.git
$ cd libjwt
$ mkdir build && cd build
$ cmake .. -DCMAKE_C_COMPILER=arm-linux-gnueabihf-gcc -DCMAKE_CXX_COMPILER=arm-linux-gnueabihf-g++ -DCMAKE_STAGING_PREFIX=/opt/externs/libs/arm-linux-gnueabihf -DCMAKE_PREFIX_PATH=/opt/externs/libs/arm-linux-gnueabihf -DENABLE_PIC=ON -DBUILD_SHARED_LIBS=OFF
$ make
$ sudo make install
```

#### [NanoSDK](https://github.com/neugates/NanoSDK.git)

```shell
$ git clone -b neuron https://github.com/neugates/NanoSDK.git
$ cd NanoSDK && mkdir build && cd build
$ cmake -DBUILD_SHARED_LIBS=OFF -DNNG_TESTS=OFF -DNNG_ENABLE_SQLITE=ON -DNNG_ENABLE_TLS=ON .. && make && sudo make install
```

#### [sqlite3](https://github.com/sqlite/sqlite)

在 install 目錄下，執行以下指令安裝 sqlite3 依賴庫。

```shell
$ curl https://www.sqlite.org/2022/sqlite-autoconf-3390000.tar.gz --output sqlite3.tar.gz
$ mkdir -p sqlite3
$ tar xzf sqlite3.tar.gz --strip-components=1 -C sqlite3
$ cd sqlite3
$ ./configure --prefix=/opt/externs/libs/arm-linux-gnueabihf --disable-shared --disable-readline --host armv4 CC=arm-linux-gnueabihf-gcc
$ make
$ sudo make install
```

依賴庫編譯可參考：[Install-dependencies](https://github.com/emqx/neuron/blob/main/Install-dependencies.md)

### Neuron 原始碼交叉編譯

完成以上步驟後，執行以下指令下編譯 Neuron 原始碼，生成目標平臺可執行檔案。

```routeros
$ cmake .. -DCMAKE_TOOLCHAIN_FILE=../cmake/arm-linux-gnueabihf.cmake -DCMAKE_BUILD_TYPE=Release -DDISABLE_UT=ON
$ make
```

DISABLE_UT 引數，禁用單元測試，=ON 禁用，=OFF 不禁用。

CMAKE_TOOLCHAIN_FILE 引數用於指定 .cmake 檔案的路徑。

## 結語

至此，我們就完成了使用 Neuron 原始碼進行交叉編譯的全部操作。使用者可以根據本文，自行編譯出所需架構的可執行檔案，從而更好地將 Neuron 執行在不同架構平臺上，實現相應的業務目標。

有關 Neuron 開源版使用中的任何建議或問題，歡迎在 [GitHub 倉庫](https://github.com/emqx/neuron)提交 PR 和 Issues。

>版權宣告： 本文為 EMQ 原創，轉載請註明出處。
>
>原文連結：[https://www.emqx.com/zh/blog/how-to-cross-compile-neuron-source-code](https://www.emqx.com/zh/blog/how-to-cross-compile-neuron-source-code)

如何對 Neuron 原始碼進行交叉編譯

相關文章