Win10系統怎麼為批處理檔案自動新增管理員許可權

　　在win10系統中，我們可能經常會需要執行一些批處理檔案，一般都要先手動獲取管理員許可權才可以，顯得有點麻煩，那麼要其實可以為批處理檔案自動新增管理員許可權，該怎麼操作呢，本文就給大家講解一下Win10系統為批處理檔案自動新增管理員許可權的具體步驟。

1、把如下程式碼（分割線之間）複製到記事本中，並儲存為 .bat 格式即可（檔名可自擬）；

————————— 分割線 —————————

@echo off

CLS

ECHO.

ECHO ================================

ECHO 獲取批處理檔案管理員許可權

ECHO ================================

:init

setlocal DisableDelayedExpansion

set "batchPath=%~0"

for %%k in (%0) do set batchName=%%~nk

set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"

setlocal EnableDelayedExpansion

:checkPrivileges

NET FILE 1>NUL 2>NUL

if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )

:getPrivileges

if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)

ECHO.

ECHO ********************************

ECHO 請求 UAC 許可權批准……

ECHO ********************************

ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"

ECHO args = "ELEV " >> "%vbsGetPrivileges%"

ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"

ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"

ECHO Next >> "%vbsGetPrivileges%"

ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"

"%SystemRoot%\System32\WScript.exe" "%vbsGetPrivileges%" %*

exit /B

:gotPrivileges

setlocal & pushd .

cd /d %~dp0

if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

::     以下為需要執行的批處理檔案程式碼     ::

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

rem 本行以下可修改為你需要的bat命令（從上面三行冒號開始到下面都可刪改）

ECHO 歡迎使用！

ECHO.

pause

————————— 分割線 —————————

以上程式碼就是為你的bat內容獲取管理員許可權用的，加在你的程式碼之前就可以用了。執行效果如下：

▲圖片說明：如果你的系統開啟了UAC，那麼就需要執行後批准一下（別嫌麻煩，最好開啟UAC，比較安全）

▲圖片說明：執行示例（有小夥伴嫌CMD醜，所以你可以在屬性→顏色中調下背景透明度，再換個喜歡的桌布……）

這個程式碼也支援Win7/Win8.1系統，效果如下（Windows7為例）：

▲圖片說明：Win7的CMD還沒法設定透明背景

　　上述給大家介紹的就是Win10系統怎麼為批處理檔案自動新增管理員許可權的詳細操作步驟，有需要的使用者們可以按照上面的方法步驟來進行操作吧。