環境
- Time 2022-11-12
- WSL-Ubuntu 22.04
- QEMU 6.2.0
- NASM 2.15.05
前言
說明
參考：https://os.phil-opp.com/entering-longmode
目標
在之前的真實模式切換到保護模式時，已經建立過全域性描述符表（GDT），這裡需要轉為 64 位。
在長模式下，主要應用分頁技術，分段被大大削弱，我們只建立一個程式碼段。
對應位解釋
| Bit(s) | Name | Meaning |
|---|---|---|
| 0-41 | ignored | ignored in 64-bit mode |
| 42 | conforming | the current privilege level can be higher than the specified level for code segments (else it must match exactly) |
| 43 | executable | if set, it’s a code segment, else it’s a data segment |
| 44 | descriptor type | should be 1 for code and data segments |
| 45-46 | privilege | the ring level 0 for kernel, 3 for user |
| 47 | present | must be 1 for valid selectors |
| 48-52 | ignored | ignored in 64-bit mode |
| 53 | 64-bit | should be set for 64-bit code segments |
| 54 | 32-bit | must be 0 for 64-bit segments |
| 55-63 | ignored | ignored in 64-bit mode |
只讀資料段
section .rodata
gdt64:
dq 0 ; 和之前一樣，第一段為 0
; 43 表示程式碼段，44 同樣為 1，47 表示可用，53 表示 64 位
dq (1<<43) | (1<<44) | (1<<47) | (1<<53) ; 程式碼段
GDT 偏移地址
第一個為長度，第二個為地址。
.pointer:
dw $ - gdt64 - 1
dq gdt64
載入 GDT
lgdt [gdt64.pointer]
總結
在保護模式下，載入全域性描述符表。
附錄
原始碼
section .multiboot_header
header_start:
dd 0x1BADB002 ; 魔法數字，固定值
dd 0
dd -0x1BADB002 ; 定義的這三個數字相加需要等於0
header_end:
global start
section .text
bits 32
start:
; 棧是否高地址往低地址增長
mov esp, stack_top
call check_cpuid
call check_long_mode
call set_up_page_tables
call enable_paging
lgdt [gdt64.pointer]
; print `OK` to screen
mov dword [0xb8000], 0x2f4b2f4f
hlt
check_cpuid:
; 檢查 CPUID 是否支援可以透過翻轉 ID 位，即第 21 位。
; 如果在 FLAGS 標誌暫存器中，我們能夠翻轉它，CPUID 就是可用的。
; 透過棧複製 FLAGS 暫存器的值到 EAX 暫存器
pushfd
pop eax
; 將 EAX 的值複製到 ECX，後面要用
mov ecx, eax
; 翻轉第 21 位
xor eax, 1 << 21
; 把 EAX 的值複製回 FLAGS 暫存器
push eax
popfd
; 複製 FLAGS 暫存器的值回 EAX 暫存器，檢查是否翻轉成功，成功翻轉則支援 CPUID
pushfd
pop eax
; 透過 ECX 還原 EFLAGS 中的值
push ecx
popfd
; 比較，如果兩個一樣，則翻轉不成功，不支援CPUID；如果翻轉成功，則支援CPUID
cmp eax, ecx
je .no_cpuid
ret
.no_cpuid:
mov al, "1"
jmp error
check_long_mode:
; 檢查是否有擴充套件的處理器資訊可用
mov eax, 0x80000000 ; CPUID 的隱式引數
cpuid ; 獲取最高支援的引數
cmp eax, 0x80000001 ; 如果支援長模式，至少是 0x80000001
jb .no_long_mode ; 如果小於，則不支援長模式
; 使用擴充套件資訊驗證是否支援長模式
mov eax, 0x80000001 ; 擴充套件處理器引數資訊
cpuid ; 將各種特徵標記位返回到 ECX 和 EDX
test edx, 1 << 29 ; 第 29 位是 long mode 長模式標記位，檢查是否支援
jz .no_long_mode ; 如果為 0，表示不支援長模式
ret
.no_long_mode:
mov al, "2"
jmp error
set_up_page_tables:
; 將 P4 的第一個地址設定成 P3 的起始地址
mov eax, p3_table
or eax, 0b11 ; 二進位制數，表示當前頁存在，並且可寫
mov [p4_table], eax
; 將 P3 的第一個地址設定成 P2 的起始地址
mov eax, p2_table
or eax, 0b11 ; 二進位制數，表示當前頁存在，並且可寫
mov [p3_table], eax
; 將 P2 設定成 2M 的巨型頁
mov ecx, 0 ; 迴圈的計數器
.map_p2_table:
; 使用 EAX 初始化 P2 的每一項，並且對映到實體地址最低的 1G 空間
mov eax, 0x200000 ; 2MiB
mul ecx ; 每一項對應的實體地址 EAX * counter
or eax, 0b10000011 ; 存在，可寫，巨型頁
mov [p2_table + ecx * 8], eax ; 將地址記錄到 P2 的每一項
inc ecx ; 計數器加 1
cmp ecx, 512 ; 是否存滿，最大 512 項
jne .map_p2_table ; 不相等繼續下次迴圈
ret
enable_paging:
; 將 CR3 暫存器指向 P4 的起始地址
mov eax, p4_table
mov cr3, eax
; 在 CR4 中啟用實體地址擴充套件(Physical Address Extension)，第五位
mov eax, cr4
or eax, 1 << 5
mov cr4, eax
; 將 EFER MSR（model specific register）暫存器中的第八位設定成長模式
mov ecx, 0xC0000080
rdmsr
or eax, 1 << 8
wrmsr
; 將 CR0 的最高位分頁開啟位設定成 1
mov eax, cr0
or eax, 1 << 31
mov cr0, eax
ret
; 列印 `ERR: ` 和一個錯誤程式碼並停住。
; 錯誤程式碼在 al 暫存器中
error:
mov dword [0xb8000], 0x4f524f45
mov dword [0xb8004], 0x4f3a4f52
mov dword [0xb8008], 0x4f204f20
mov byte [0xb800a], al
hlt
section .rodata
gdt64:
dq 0 ; 和之前一樣，第一段為 0
; 43 表示程式碼段，44 同樣為 1，47 表示可用，53 表示 64 位
dq (1<<43) | (1<<44) | (1<<47) | (1<<53) ; 程式碼段
.pointer:
dw $ - gdt64 - 1
dq gdt64
section .bss
align 4096
p4_table:
resb 4096
p3_table:
resb 4096
p2_table:
resb 4096
stack_bottom:
resb 64
stack_top: