30331定址方式

Zander_Zhao發表於2019-06-19

8086的定址方式

1.與資料有關的定址方式

以 MOV 指令為例

                        立即定址 MOV AX , 3069H
  暫存器定址 MOV AL , BH

儲存器定址

 直接定址 MOV AX , [ 2000H ]
暫存器間接定址 MOV AX , [ BX ] 
暫存器相對定址 MOV AX , COUNT [ SI ] 
基址變址定址 MOV AX , [ BP ] [ DI ]
相對基址變址定址 MOV AX , MASK [ BX ] [ SI ]

1.1立即定址方式*

—— 運算元在指令中給出

指令格式：

MOV AL, 5
MOV AX, 3064H
MOV AL, ‘A’

* 只能用於 SRC 欄位      MOV 40H, AL    //F

* SRC 和 DST 的字長一致    MOV AH, 3064H    //F

 

1.2暫存器定址方式*

— 運算元在指定的暫存器中

MOV AX, BX
MOV AL, BH
MOV AX, 3064H

* 位元組暫存器只有 AH AL BH BL CH CL DH DL
* SRC 和 DST 的字長一致 MOV AH, BX    //F
* CS 不能用 MOV 指令改變 MOV CS, AX   //F

 

 

 運算元的偏移地址：有效地址EA（effective address）

*有效地址計算

　　EA = 基址 + （變址*比例因子）＋ 位移量

  16位定址 32位定址
位移量 0,8,16位 0,8,32位
基址暫存器 BX，BP 任何32位通用暫存器包括ESP
變址暫存器 SI，DI 任何32位通用暫存器除ESP
比例因子 無 1,2,4,8

不允許跨段字首：

串處理指令的目的串必須用ES段

PUSH和POP指令的源必須用SS段

指令必須放在CS段

實體地址：PA

 

1.3直接定址方式*

— 有效地址EA由指令直接給出

例：MOV AX, [ 2000H ]
EA=2000H, 假設(DS)=3000H, 那麼PA=32000H

* 隱含的段為資料段 DS
* 可使用段跨越字首 MOV AX, ES: [2000H]

* 運算元地址可由變數（符號地址）表示, 但要注意變數的屬性

VALUE DB 10
MOV AH, VALUE
MOV AX, VALUE //F
MOV AX, WORD PTR VALUE //T

 

1.4暫存器間接定址*

— EA 在基址暫存器(BX/BP)或變址暫存器(SI/DI) 中

MOV AX, [BX] PA = 16d × (DS) + (BX)
MOV AX, ES:[BX] PA = 16d × (ES) + (BX)
MOV AX, [BP] PA = 16d × (SS) + (BP)

* 不允許使用AX、CX、DX 存放 EA
MOV AX, [CX]   //F
* SRC 和 DST 的字長一致
MOV DL, [ BX ] ; [BX]指示一個位元組單元
MOV DX, [ BX ] ; [BX]指示一個字單元
* 適於陣列、字串、表格的處理

 

1.5暫存器相對定址方式*

 

指令格式： MOV AX, COUNT[SI] 或 MOV AX, [COUNT+SI]
假設 (DS)=3000H, (SI)=2000H, COUNT=3000H,
則: PA = 35000H
假設(35000H)=1234H, 那麼 (AX)=1234H
* 適於陣列、字串、表格的處理

 

1.6基址變址定址方式*

 

指令格式：

MOV AX, [BX] [DI]
MOV AX, [BX+DI]
MOV AX, ES:[BX] [SI]

* 適於陣列、字串、表格的處理
* 必須是一個基址暫存器和一個變址暫存器的組合
MOV AX, [BX] [BP]  //F
MOV AX, [SI] [DI] //F

 

1.7相對基址變址定址方式

 

MOV AX, MASK [BX] [SI]
或 MOV AX, MASK [BX+SI]
或 MOV AX, [MASK+BX+SI]

 

1.8段暫存器的使用規定

 

例：編寫一段顯示字串STRING的程式
DATA SEGMENT
STRING DB ‘ HAPPY NEW YEAR! ’, 0DH , 0AH , ‘ $ ’
COUNT DW 17
DATA ENDS

( 1 ) 直接定址

          mov   dl,  string                
          mov   ah, 2              
          int      21h                       ; 顯示字元‘H’

          mov   dl, string+1                    
          mov   ah, 2
          int      21h                       ; 顯示字元‘A’
           :
           :

 

( 2 ) 暫存器間接定址

            mov    cx,  count                   ; mov  cx, 17         
            mov    bx,  offset  string        ; string的偏址 給 bx
Next :      mov   dl,   [bx]                     
            mov    ah,   2
            int       21h                             ; 顯示一個字元
            inc      bx
            loop   next                             ; 迴圈指令

 

( 3 ) 暫存器相對定址

            mov  cx,  count                  ; mov  cx, 17      
            mov  si,   0                         
Next :      mov  dl,   string[si]             ; mov  dl,  [string+si] 
            mov  ah,  2
            int     21h                           ; 顯示一個字元
            inc     si
            loop   next                         ; 迴圈指令

( 4 ) 基址變址定址

            mov     cx,  count                   ; mov  cx, 17  
            mov     bx,  offset  string        ; string的偏址  bx
            mov     si,   0
Next :      mov    dl,  [bx] [si]                  ; mov  dl, [bx+si] 
            mov     ah, 2
            int       21h                              ; 顯示一個字元
            inc       si
            loop     next                            ; 迴圈指令

 

( 5 ) DOS 顯示字串功能

            mov     dx, offset  string        ; string的偏址  dx
                                             ; lea  dx, string
            mov     ah, 9
            int     21h                    ; 顯示一串字元

 1.9 80x86 新增的定址方式

EA= (基址暫存器) + (變址暫存器) × 比例因子 + 位移量

( 1 ) 比例變址定址方式
例：MOV EAX, COUNT [ ESI * 4 ]

 

(2) 基址比例變址定址方式
例：MOV ECX, [ EAX ][ EDI * 4 ]
(3) 相對基址比例變址定址方式
例：MOV EAX, TABLE [ EBP ][ EDI * 4 ]

 

 

 2.與轉移地址有關的定址方式

用來確定轉移指令及轉子指令的轉向地址

段內定址

 段內直接定址     JMP    NEAR PTR  NEXT 
段內間接定址

JMP TABLE [ BX ]

段間定址

 段間直接定址     JMP    FAR PTR  NEXT 
段間間接定址    

JMP DWORD PTR [ BX ]

2.1段內直接定址

 

例：

JMP NEAR PTR NEXT 近轉移 -32768 ~ +32767
JMP SHORT NEXT 短轉移 -128 ~ +127

 

 2.2段內間接定址

轉向的有效地址是一個暫存器或儲存單元的內容。
（可用除立即數以外的任何一種資料定址方式得到）

例： TABLE = 20A2H     (BX) = 1256H              (SI) = 528EH
        (DS) = 2000H         (232F8H) = 3280H      (264E4H) = 2450H

              JMP  BX                                ; (IP)=1256H
              
              JMP  TABLE[BX]
              JMP  WORD PTR  TABLE[BX]               ; (IP)=3280H
              
              JMP  [BX][SI]
              JMP  WORD PTR  [BX][SI]                 ; (IP)=2450H

 

 2.3段間直接定址

用指令中提供的轉向段地址和偏移地址取代CS 和 IP

 例：

 

2.4段間間接定址

用儲存器中的兩個相繼字的內容取代CS 和 IP
（儲存單元的地址可用儲存器定址方式得到）

例：

 

 

相關文章