拋棄以往分頁方式，改用ROW_NUMBER()加BETWEEN方式的分頁儲存過程，特此分享

/**********************************************************************************************
********************通過指定的條件分頁查詢資料表【TableName or ViewName】記錄******************
**********************************************************************************************/
IF EXISTS (SELECT * FROM dbo.sysobjects WHERE id = object_id (N'[dbo].[SjjPagination]') AND OBJECTPROPERTY(id, N'IsProcedure') = 1)
DROP PROCEDURE [dbo].[SjjPagination]
GO

SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

--引數說明
-------------------------------------------------------------
/*
* @tblName   ----要顯示的表或多個表的連線
* @fldName   ----要查詢出的欄位列表,*表示全部欄位
* @pageSize   ----每頁顯示的記錄個數
* @pageIndex  ----要顯示那一頁的記錄
* @fldSort   ----排序欄位列表或條件，如：id desc (多個id desc,dt asc)
* @strCondition  ----查詢條件,不需where
* @pageCount  ----查詢結果分頁後的總頁數
* @RecordCount  ----查詢到的總記錄數
* @UsedTime   ----耗時測試時間差
* @strSql   ----最後返回的SQL語句
*/
CREATE PROCEDURE [dbo].[SjjPagination]
(
 @tblName NVARCHAR(MAX),
 @fldName NVARCHAR(MAX),
 @pageSize INT,
 @pageIndex INT,
 @fldSort NVARCHAR(MAX),
 @strCondition NVARCHAR(MAX),
 @pageCount INT OUTPUT,
 @RecordCount INT OUTPUT,
 @UsedTime INT OUTPUT,
 @strSql nvarchar(max) = '' OUTPUT
)
AS
 SET NOCOUNT ON
 DECLARE @startRow int, @endRow INT     ----用於存放起始值與結束值
 DECLARE @timediff DATETIME       ----用於存放時間差值
 DECLARE @SqlCounts NVARCHAR(MAX)     ----用於存放總記錄數查詢語句
 DECLARE @strTmp NVARCHAR(MAX)      ----用於存放查詢語句
 DECLARE @strWhere NVARCHAR(MAX)      ----用於存放查詢條件 
 SELECT @timediff = getdate()      ----設定開始時間
 SET @startRow = (@pageIndex - 1) * @pageSize + 1 ----設定起始值
 SET @endRow = @startRow + @pageSize - 1    ----設定結束值
 ----設定總記錄數查詢語句----
 IF @strCondition is null or @strCondition='' ----沒有設定查詢條件
  BEGIN
   SET @SqlCounts = 'SELECT @RecordCount = COUNT(*) FROM ' + @tblName
  END
 ELSE ----有設定查詢條件
  BEGIN
   SET @strWhere = ' WHERE ' + @strCondition
   SET @SqlCounts = 'SELECT @RecordCount = COUNT(*) FROM ' + @tblName + @strWhere
  END  
 ----取得查詢結果總數量-----
 exec sp_executesql @SqlCounts,N'@RecordCount int out ',@RecordCount out
 declare @tmpCounts int
 if @RecordCount = 0
  set @tmpCounts = 1
 else
  set @tmpCounts = @RecordCount
    ----取得分頁總數 ----
    set @pageCount=(@tmpCounts+@pageSize-1)/@pageSize
 ----開始分頁計算並取出相應資料----
 ----SELECT * FROM (SELECT *,ROW_NUMBER() OVER (ORDER BY contnet_keyword_addDate DESC) AS RowNumber FROM Public_content_keyword ) T WHERE T.RowNumber BETWEEN @startRow AND @endRow
 IF @pageIndex = 1
  BEGIN
   IF @strCondition is null or @strCondition='' ----沒有設定顯示條件
    BEGIN
     SET @strTmp = 'SELECT TOP ' + CAST(@pageSize as VARCHAR(max)) + ' ' + @fldName + ' FROM ' + @tblName
    END
   ELSE ----有設定查詢條件
    BEGIN
     SET @strTmp = 'SELECT TOP ' + CAST(@pageSize as VARCHAR(max)) + ' ' + @fldName + ' FROM ' + @tblName + @strWhere
    END
  END
 ELSE
  BEGIN
   IF @strCondition is null or @strCondition='' ----沒有設定顯示條件
    BEGIN
     SET @strTmp = 'SELECT ' + @fldName + ' FROM (SELECT ' + @fldName + ',ROW_NUMBER() OVER (ORDER BY ' + @fldSort + ') AS RowNumber FROM '+ @tblName +') T WHERE T.RowNumber BETWEEN ' + CAST(@startRow as VARCHAR(max)) + ' AND ' + CAST(@endRow as VARCHAR(max))
    END
   ELSE ----有設定查詢條件
    BEGIN
     SET @strTmp = 'SELECT ' + @fldName + ' FROM (SELECT ' + @fldName + ',ROW_NUMBER() OVER (ORDER BY ' + @fldSort + ') AS RowNumber FROM '+ @tblName + @strWhere +') T WHERE T.RowNumber BETWEEN ' + CAST(@startRow as VARCHAR(max)) + ' AND ' + CAST(@endRow as VARCHAR(max))
    END
  END 
------返回查詢結果-----
SET @strSql = @strTmp
EXEC(@strTmp)
SET @UsedTime = DATEDIFF(ms,@timediff,GETDATE())
SET NOCOUNT OFF
GO

原文地址：http://www.cnblogs.com/roach888/archive/2009/10/15/1584014.html

來自 “ ITPUB部落格 ” ，連結：http://blog.itpub.net/16436858/viewspace-616724/，如需轉載，請註明出處，否則將追究法律責任。