SQL Server中行列轉換 Pivot UnPivot

PIVOT用於將列值旋轉為列名（即行轉列），在SQL Server 2000可以用聚合函式配合CASE語句實現

PIVOT 的一般語法是：PIVOT (聚合函式(列) FOR 列 in (…) )AS P

完整語法：

table_source

PIVOT(

聚合函式（value_column）

FOR pivot_column

IN()

)

 

UNPIVOT用於將列明轉為列值（即列轉行），在SQL Server 2000可以用UNION來實現

完整語法：

table_source

UNPIVOT(

value_column

FOR pivot_column

IN()

)

 

注意：PIVOT、UNPIVOT是SQL Server 2005的語法，使用需修改資料庫相容級別
 在資料庫屬性->選項->相容級別改為   90

 

典型例項

一、行轉列

1、建立表格

if object_id('tb') is not null drop table tb

go

create table tb(姓名 varchar(10) , 課程 varchar(10) , 分數 int)

insert into tb values('張三' , '語文' , 74)

insert into tb values('張三' , '數學' , 83)

insert into tb values('張三' , '物理' , 93)

insert into tb values('李四' , '語文' , 74)

insert into tb values('李四' , '數學' , 84)

insert into tb values('李四' , '物理' , 94)

go

select * from tb

go

姓名        課程        分數

---------- ---------- -----------

張三        語文        74

張三        數學        83

張三        物理        93

李四        語文        74

李四        數學        84

李四        物理        94

 

2、使用SQL Server 2000靜態SQL

--c

select 姓名,

 max(case 課程 when '語文' then 分數 else 0 end) 語文,

 max(case 課程 when '數學' then 分數 else 0 end) 數學,

 max(case 課程 when '物理' then 分數 else 0 end) 物理

from tb

group by 姓名

姓名        語文         數學         物理

---------- ----------- ----------- -----------

李四        74          84          94

張三        74          83          93

 

3、使用SQL Server 2000動態SQL

--SQL SERVER 2000 動態SQL,指課程不止語文、數學、物理這三門課程。(以下同)

--變數按sql語言順序賦值

declare @sql varchar(500)

set @sql='select 姓名'

select @sql=@sql+',max(case 課程when '''+課程+''' then 分數 else 0 end)['+課程+']'

from (select distinct 課程 from tb)a --同from tb group by 課程，預設按課程名排序

set @sql=@sql+' from tb group by 姓名'

exec (@sql)

 

--使用isnull(),變數先確定動態部分

declare @sql varchar(8000)

select @sql =isnull(@sql + ',' , '') + ' max(case 課程 when ''' + 課程+ ''' then 分數 else 0 end) [' + 課程+ ']'

from (select distinct 課程 from tb) as a      

set @sql = 'select 姓名,'+@sql + ' from tb group by 姓名'

exec(@sql)

姓名        數學         物理         語文

---------- ----------- ----------- -----------

李四        84          94          74

張三        83          93          74

 

4、使用SQL Server 2005靜態SQL

select * from tb pivot (max(分數) for 課程in (語文,數學,物理)) a

 

5、使用SQL Server 2005動態SQL

--使用stuff()

declare @sql varchar(8000)

set @sql=''   --初始化變數@sql

select @sql = @sql + ','+ 課程 from tb group by 課程--變數多值賦值

set @sql=stuff(@sql,1,1,'') --去掉首個','

set @sql='select * from tb pivot (max(分數) for 課程 in (' + @sql + '))a'

exec (@sql)

 

--或使用isnull()

declare @sql varchar(8000)

–-獲得課程集合

select @sql = isnull(@sql + ',' , '') + 課程 from tb group by 課程           

set @sql='select * from tb pivot (max(分數) for 課程in (' + @sql + '))a'

exec (@sql)

 

二、行轉列結果加上總分、平均分

1、使用SQL Server 2000靜態SQL

--SQL SERVER 2000 靜態SQL

select 姓名,

max(case 課程when '語文' then 分數else 0 end)語文,

max(case 課程when '數學' then 分數else 0 end)數學,

max(case 課程when '物理' then 分數else 0 end)物理,

sum(分數) 總分,

cast(avg(分數*1.0) as decimal(18,2)) 平均分

from tb

group by 姓名

姓名        語文         數學         物理         總分         平均分

---------- ----------- ----------- ----------- -----------

李四        74          84          94          252         84.00

張三        74          83          93          250         83.33

 

2、使用SQL Server 2000動態SQL

--SQL SERVER 2000 動態SQL

declare @sql varchar(500)

set @sql='select 姓名'

select @sql=@sql+',max(case 課程 when '''+課程+''' then 分數 else 0 end)['+課程+']'

from (select distinct 課程from tb)a

set @sql=@sql+',sum(分數) 總分,cast(avg(分數*1.0) as decimal(18,2))      平均分 from tb group by 姓名'

exec (@sql)

 

3、使用SQL Server 2005靜態SQL

select m.*,n.總分,n.平均分

from

(select * from tb pivot(max(分數) for 課程in(語文,數學,物理))a)m,

(select 姓名,sum(分數)總分,cast(avg(分數*1.0) as decimal(18,2)) 平均分

from tb

group by 姓名)n

where m.姓名=n.姓名

 

4、使用SQL Server 2005動態SQL

--使用stuff()

--

declare @sql varchar(8000)

set @sql=''   --初始化變數@sql

select @sql = @sql + ','+ 課程 from tb group by 課程--變數多值賦值

--同select @sql = @sql + ','+ 課程 from (select distinct 課程 from tb)a

set @sql=stuff(@sql,1,1,'') --去掉首個','

set @sql='select m.* , n.總分,n.平均分 from

(select * from (select * from tb) a pivot (max(分數) for 課程 in (' +@sql + ')) b) m ,

(select 姓名,sum(分數) 總分, cast(avg(分數*1.0) as decimal(18,2)) 平均分from tb group by 姓名) n

where m.姓名= n.姓名'

exec (@sql)

 

--或使用isnull()

declare @sql varchar(8000)

select @sql = isnull(@sql + ',' , '') + 課程from tb group by 課程

set @sql='select m.* , n.總分,n.平均分 from

(select * from (select * from tb) a pivot (max(分數) for 課程 in (' +

 @sql + ')) b) m ,

(select 姓名,sum(分數) 總分, cast(avg(分數*1.0) as decimal(18,2)) 平均分from tb group by 姓名) n

where m.姓名= n.姓名'

exec (@sql)

 

二、列轉行

1、建立表格

if object_id('tb') is not null drop table tb

go

create table tb(姓名 varchar(10) , 語文 int , 數學 int , 物理 int)

insert into tb values('張三',74,83,93)

insert into tb values('李四',74,84,94)

go

select * from tb

go

姓名        語文         數學         物理

---------- ----------- ----------- -----------

張三        74          83          93

李四        74          84          94

 

2、使用SQL Server 2000靜態SQL

--SQL SERVER 2000 靜態SQL。

select * from

(

 select 姓名 , 課程 = '語文' , 分數 = 語文 from tb

 union all

 select 姓名 , 課程 = '數學' , 分數 = 數學 from tb

 union all

 select 姓名 , 課程 = '物理' , 分數 = 物理 from tb

) t

order by 姓名 , case 課程 when '語文' then 1 when '數學' then 2 when '物理' then 3 end

姓名        課程 分數

---------- ---- -----------

李四        語文 74

李四        數學 84

李四        物理 94

張三        語文 74

張三        數學 83

張三        物理 93

  

2、使用SQL Server 2000動態SQL

--SQL SERVER 2000 動態SQL。

--呼叫系統表動態生態。

declare @sql varchar(8000)

select @sql = isnull(@sql + ' union all ' , '' ) + ' select 姓名, [課程]='

+ quotename(Name , '''') + ' , [分數] = ' + quotename(Name) + ' from tb'

from syscolumns

where Name !='姓名' and ID = object_id('tb') --表名tb，不包含列名為姓名的其他列

order by colid

exec(@sql + ' order by 姓名')

go

 

3、使用SQL Server 2005靜態SQL

--SQL SERVER 2005 動態SQL

select 姓名 , 課程 , 分數 from tb unpivot (分數 for 課程 in([語文] , [數學] , [物理])) t

 

4、使用SQL Server 2005動態SQL

--SQL SERVER 2005 動態SQL

declare @sql nvarchar(4000)

select @sql=isnull(@sql+',','')+quotename(Name)

from syscolumns

where ID=object_id('tb') and Name not in('姓名')

order by Colid

set @sql='select 姓名,[課程],[分數] from tb unpivot ([分數] for [課程] in('+@sql+'))b'

exec(@sql)

來自 “ ITPUB部落格 ” ，連結：http://blog.itpub.net/16436858/viewspace-622492/，如需轉載，請註明出處，否則將追究法律責任。