什麼是 NGAP(Next Generation ABAP Platform)？

SAP NetWeaver 7.40 釋出，並附帶其 ABAP 應用伺服器 AS ABAP 7.40。

在 AS ABAP 7.40 中，ABAP 語言具有一些不錯的新特性。

AS ABAP 7.40 是 AS ABAP 7.31（又名 AS ABAP 7.03）的繼承者，後者是基於 AS ABAP 7.0 構建的 AS ABAP 7.02 的繼承者。

請注意，關於 ABAP 語言和 ABAP 語言環境 AS ABAP 7.31 及其 AS ABAP 7.40 不是 AS ABAP 7.30 的繼承者。相反，AS ABAP 7.03 已重新命名為 AS ABAP 7.31，因此 AS ABAP 7.40 是 AS ABAP 7.02 的後續版本。

AS ABAP 7.0 釋出後，ABAP 語言的進一步開發主要在 7.10、7.20、7.30 程式碼行中完成，而大多數使用者仍然使用 7.0x 程式碼行。為了讓更大的開發者社群能夠使用所有好的開發，幾年前從 7.2 到 7.02 進行了一項主要功能的反向移植。 7.2 的所有功能（除了為 RFC 啟用的基於類的異常和來自包違規的語法錯誤）在 7.02 中可用。

在 7.2 和 7.3 或 7.02 和 7.03（又名 7.31）之間沒有增強 ABAP 語言。同時關閉 7.10、7.20、7.30 程式碼行。由於該程式碼行的大多數開發（尤其是那些與 ABAP 語言本身無關的增強功能）無論如何都向後移植到 7.03，因此 7.03 被重新命名為 7.31，兩個程式碼行合二為一：7.0x -> 7.31 行。
在這期間，為 SAP 內部使用開啟了另一個 ABAP 程式碼行：基於 7.2 的 ABAP 8.0 到 8.04。這是有史以來第一個 ABAP 程式碼行，其中 ABAP 以非向下相容的方式進一步開發。事實上，許多被認為已過時的功能已從該程式碼行中刪除（甚至包括邏輯資料庫）。新的 AS ABAP 是為 NGAP（下一代 ABAP 平臺）製作的，並在內部用於 SAP 用於新產品（例如 Business by Design）的現代物件導向和基於框架的開發。當然，遺留 ABAP 程式很難在 NGAP 上執行。

隨著 HANA 的出現，需要在 7.0x -> 7.31 系列中進一步開發 ABAP。第一個結果是 7.40。再次，發生了一個大的反向移植。這次從 8.0x 到 7.40。為 NGAP 開發的許多有用的 ABAP 功能回到了 7.0x 線——這一次是透過保持完全的向下相容性（由於此限制，仍有一些功能尚未向後移植）。
從 7.40 開始，ABAP 在與核心版本捆綁的支援包中得到進一步開發。第一個可供客戶使用的捆綁支援包是帶有核心 7.40 的 SP02。緊隨其後的是帶有核心 741 的 SP05。更多捆綁的 SP 即將推出，每個都有自己的核心，因此具有新的 ABAP 功能。

![](https://img-blog.csdnimg.cn/img_convert/558262f7e5e30ee3a9e7f88fbb1d6fb0.png)

# COND

```sql
*&---------------------------------------------------------------------*
*& Report ZCAST2
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT zcast2.

CLASS c1 DEFINITION.
ENDCLASS.

CLASS c2 DEFINITION INHERITING FROM c1.
ENDCLASS.

DATA: ref1 TYPE REF TO c1,
      ref2 TYPE REF TO c2.

ref1 = NEW c2( ).

IF ref1 IS INSTANCE OF c2.
  ref2 ?= ref1.
ENDIF.

TRY.
    ref2 ?= ref1.
  CATCH cx_sy_move_cast_error.
ENDTRY.

DATA: jerry1 TYPE REF TO c1,
      jerry2 TYPE REF TO c2.
DATA(lv) = COND boolean( WHEN jerry1 IS INSTANCE OF c2 THEN abap_true ELSE abap_false ).

WRITE: lv.
ASSERT lv = abap_false.
```
上面程式碼裡，變數 lv 是一個 boolean 型別，其值透過 `WHEN ... THEN ... ELSE ...` 程式碼塊計算出來。

另一個例子：

```sql
DATA: lv_string TYPE string,
      lv_count TYPE int4 value 1.

lv_string = 'Jerry' &&  COND #( WHEN lv_count = 1 THEN ' Hello' ELSE 'default'  ).

WRITE: / lv_string.
```

# FILTERS

直接對一個內表根據某些條件進行過濾操作，返回過濾後的新內表：

```sql
*&---------------------------------------------------------------------*
*& Report ZFILTER
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ZFILTER.

CLASS demo DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS main.
ENDCLASS.

CLASS demo IMPLEMENTATION.
  METHOD main.
    DATA carrid TYPE spfli-carrid VALUE 'LH'.
    cl_demo_input=>add_field( CHANGING field = carrid ).
    DATA cityfrom TYPE spfli-cityfrom VALUE 'Frankfurt'.
    cl_demo_input=>request( CHANGING field = cityfrom ).

DATA spfli_tab TYPE STANDARD TABLE OF spfli
                   WITH EMPTY KEY
                   WITH NON-UNIQUE SORTED KEY carr_city
                        COMPONENTS carrid cityfrom.

SELECT *
           FROM spfli
           INTO TABLE @spfli_tab.

DATA(extract) =
      FILTER #( spfli_tab USING KEY carr_city
                  WHERE carrid   = CONV #( to_upper( carrid ) ) AND
                        cityfrom = CONV #( to_upper( cityfrom ) ) ).

cl_demo_output=>display( extract ).

DATA(rest) =
      FILTER #( spfli_tab EXCEPT USING KEY carr_city
                  WHERE carrid   = CONV #( to_upper( carrid ) ) AND
                        cityfrom = CONV #( to_upper( cityfrom ) ) ).

ASSERT lines( extract ) + lines( rest ) = lines( spfli_tab ).

ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  demo=>main( ).
```

另一個例子：

```sql
*&---------------------------------------------------------------------*
*& Report ZFILTER_TEST
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ZFILTER_TEST.

*Here, the internal table itab must have at least one sorted key or one hash key used for access.
*This can be either the primary table key used without specifying USING KEY or
* by specifying its name primary_key after USING KEY,
*or a secondary table key used by specifying its name after USING KEY.

TYPES: BEGIN OF ty_language,
         name TYPE string,
         year TYPE i,
       END OF ty_language.

TYPES: tt_language TYPE STANDARD TABLE OF ty_language with key PRIMARY_KEY COMPONENTS name with UNIQUE SORTED KEY
        aa COMPONENTS year.

"types: tt_language TYPE STANDARD TABLE OF ty_language.

TYPES: BEGIN OF ty_employee,
         empl_name TYPE string,
         lang_name TYPE string,
         year TYPE i,
       END OF ty_employee.

TYPES: tt_employee TYPE STANDARD TABLE OF ty_employee WITH KEY empl_name.

data:lt_language type tt_language.

lt_language = value #( ( name = 'ABAP' year = 10 )
                       (  name = 'Java' year = 7  ) ).

DATA: lt_employee1 TYPE tt_employee,
      lt_employee2 TYPE tt_language.

* way1
LOOP AT lt_language ASSIGNING FIELD-SYMBOL(<line>) WHERE year >= 10.
   DATA(ls_employee) = value ty_employee( empl_name = 'Jerry' lang_name = <line>-name
   year = <line>-year ).
   APPEND ls_employee TO lt_employee1.
ENDLOOP.

lt_employee2 = FILTER tt_language( lt_language using key aa where year >= 10  ).

BREAK-POINT.
```

# 利用 LET 關鍵字定義的臨時變數

```sql
*&---------------------------------------------------------------------*
*& Report ZLET
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ZLET.

data: lv_string type string value '1'.

CLASS cx_cant_be DEFINITION INHERITING FROM cx_no_check.
ENDCLASS.

cl_demo_output=>display(
  COND #( LET t = '120000' IN
          WHEN sy-timlo < t THEN
            |{ sy-timlo TIME = ISO } AM|
          WHEN sy-timlo > t AND sy-timlo < '240000' THEN
            |{ CONV t( sy-timlo - 12 * 3600 ) TIME = ISO } PM|
          WHEN sy-timlo = t THEN
            |High Noon|
          ELSE
            THROW cx_cant_be( ) ) ).

BREAK-POINT.
```

# Table 表示式

```sql
*&---------------------------------------------------------------------*
*& Report ZTABLE_EXPRESSION
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ZTABLE_EXPRESSION.

data: lt_table type string_table,
      lv_jerry type string value 'Jerry',
      lv_scala type string value 'Scala'.

lt_table = value #( ( lv_jerry ) ( lv_scala ) ).

* Jerry and the line of LT_TABLE are incompatible
" lt_table = value #( ( 'Jerry' ) ).
TYPES:
   BEGIN OF struc,
      col1 TYPE c LENGTH 2,
      col2 TYPE i,
      col3 TYPE i,
   END OF struc.

DATA itab TYPE SORTED TABLE OF struc WITH UNIQUE KEY col1
          WITH UNIQUE SORTED KEY sec_key COMPONENTS col2.

itab = VALUE #( ( col1 = 'AA' col2 = 5 col3 = 100 )
                ( col1 = 'BB' col2 = 4 col3 = 100 )
                ( col1 = 'CC' col2 = 3 col3 = 100 )
                ( col1 = 'DD' col2 = 2 col3 = 100 )
                ( col1 = 'EE' col2 = 1 col3 = 100 ) ).

DATA(wa) = itab[ 1 ].

ASSIGN itab[ col1 = 'BB' ] TO FIELD-SYMBOL(<fs>).

cl_demo_output=>display( itab[ 3 ] ).

IF line_exists( itab[ KEY sec_key col2 = 2 ] ).
ENDIF.

DATA(line) = itab[ KEY sec_key col2 = 4 ].

TRY.
DATA(not) = itab[ KEY sec_key col2 = 333 ].
CATCH cx_root.
ENDTRY.

itab[ col1 = 'EE' ]-col3 = 555.
```</fs></line></line></line>

一些 Next Generation ABAP Platform 的新語法用例

相關文章