PLSQL Language Reference-PL/SQL語言基礎-詞彙單元-識別符號的作用域和可見性

-- 外部塊

DECLARE

    a CHAR;         -- a(CHAR)的scope開始

    b REAL;     -- b的scope開始

BEGIN

    -- a(CHAR), b可見

    -- 第1個子塊

    DECLARE

        a INTEGER;      -- a(INTEGER)scope開始

        c REAL;         -- c的scope開始

    BEGIN

        -- a(INTEGER), b, c可見

        NULL;

    END;                -- a(INTEGER)和c的scope結束

    -- 第2個子塊

    DECLARE

        d REAL;     -- d的scope開始

    BEGIN

        -- a(CHAR), b, d可見

        NULL;

    END;            -- d的scope結束

    -- a(CHAR), b可見

END; 

<<outer>>  -- 標籤

DECLARE

    birthdate DATE := to_date('09-08-70', 'DD-MM-YYYY');

BEGIN

    DECLARE

        birthdate DATE := to_date('29-09-70', 'DD-MM-YY');

    BEGIN

        --前者是本地的，後者是限定的全域性的

        IF birthdate = outer.birthdate THEN

            DBMS_OUTPUT.PUT_LINE ('相同的生日');

        ELSE

            DBMS_OUTPUT.PUT_LINE ('不同的生日');

        END IF;

    END;

END;

CREATE OR REPLACE PROCEDURE check_credit (credit_limit NUMBER) AS

    rating NUMBER := 3;                             --全域性變數

    --子程式

    FUNCTION check_rating RETURN BOOLEAN IS

        rating  NUMBER := 1;                        --本地變數

        over_limit  BOOLEAN;

    BEGIN

        IF check_credit.rating <= credit_limit THEN  -- 引用全域性變數（使用過程名來限定）

            over_limit := FALSE;

        ELSE

            over_limit := TRUE;

            rating := credit_limit;                  -- 引用本地量

        END IF;

        RETURN over_limit;

    END check_rating;

BEGIN

    IF check_rating THEN

        DBMS_OUTPUT.PUT_LINE

        ('信用等級超出限制 (' || TO_CHAR(credit_limit) || ').  '

        || '等級: ' || TO_CHAR(rating));

    ELSE

        DBMS_OUTPUT.PUT_LINE('信用等級OK.  ' || '等級: ' || TO_CHAR(rating));

    END IF;

END;

BEGIN

    check_credit(1);

END;

DECLARE

    id  BOOLEAN;

    id  VARCHAR2(5);  -- 重複宣告

BEGIN

    id := FALSE;

END;

--在不同的PL/SQL單元中宣告同名變數

DECLARE

    PROCEDURE p

    IS

        x VARCHAR2(1);

    BEGIN

        x := 'a';

        DBMS_OUTPUT.PUT_LINE('在過程P中, x = ' || x);

    END;

    PROCEDURE q

    IS

        x VARCHAR2(1);

    BEGIN

        x := 'b';

        DBMS_OUTPUT.PUT_LINE('在過程q中, x = ' || x);

    END;

BEGIN

    p;

    q;

END;

-- 子程式和塊具有相同的名稱echo

<<echo>>

DECLARE

    x  NUMBER := 5;

    PROCEDURE echo AS

        x  NUMBER := 0;

    BEGIN

        --都是指本地的x

        DBMS_OUTPUT.PUT_LINE('x = ' || x);

        DBMS_OUTPUT.PUT_LINE('echo.x = ' || echo.x);

    END;

BEGIN

    echo;

END;