在VBScript中使用類（三） (轉)

在VBScript中使用類（三） (轉)[@more@]

我們來分析一下（2）中的：

Class TVProgram:namespace prefix = o ns = "urn:schemas--com::office" />

  Public StartTime

  Public internal_Prograte

  Public Property Get ProgramDate

  ProgramDate = Day(internal_ProgramDate) & _

  " " & MonthName(Month(internal_ProgramDate)) & _

  " " & Year(internal_ProgramDate)

  End Property

  Public ProgramTitle

  End Class

  Dim objTVShow

  Set objTVShow = New TVProgram

  objTVShow.StartTime = CDate("17:30")

  objTVShow.internal_ProgramDate = DateSerial(1999,9,17)

  objTVShow.ProgramTitle = "The Jerry er Show"

  Response.Write objTVShow.ProgramTitle & " is on at " & _

  objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

當的屬性ProgramDate時，實際上了ProgramDate，即如上定義的函式，而很快你也將習慣這種在宣告部分使用Public或Private關鍵字的方式。關鍵字“Property”，告知了如同呼叫屬性一樣在外部呼叫函式。接著的“Get”，表明該函式是輸出還是獲得一個值。

Get的意思是“允許外部程式碼去‘獲取’一個值”，與其類似的關鍵字還有“Let”和“Set”，但這兩個比較複雜，因而我們以後再討論。

接下去的程式碼看來有點難度的，給name.internal_ProgramDate賦值並透過objectname.ProgramDate來呼叫它。如果可以使用相同關鍵字同時為其賦值並獲得它的值不是更好嗎？當然，那也可以。

如果定義Get和Let屬性的名稱相同，可以將它們當作物件相同的屬性，但這隻限於它們定義了相同數量的成員。（以下程式碼看來不太相同，僅作為例項參考）

Class TVProgram

  Public StartTime

  Public internal_ProgramDate

  Public Property Get ProgramDate

  ProgramDate = Day(internal_ProgramDate) & " " _

  & MonthName(Month(internal_ProgramDate)) & _

  " " & Year(internal_ProgramDate)

  End Property

  Public Property Let ProgramDate(ByVal varDateIn)

  internal_ProgramDate = CDate(varDateIn)

  End Property

  Public ProgramTitle

  End Class

  Dim objTVShow

  Set objTVShow = New TVProgram

  objTVShow.StartTime = CDate("17:30")

  objTVShow.ProgramDate = "17 Sept 99"

  objTVShow.ProgramTitle = "The Jerry Springer Show"

  Response.Write objTVShow.ProgramTitle & " is on at " & _

  objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

以上程式碼中Let的宣告部分看來似乎是一個多餘的元素，當我第一次看到時研究了很長時間。每次我使用“0”作為變數用在每個屬性上，我總是得到這個錯誤資訊，“元素數量必須相等”。“它們確實相等！”抓狂之後，我回過頭去看程式才覺得自己的愚蠢！：）

原因是，當你試圖為ProgramDate賦值時，你會使用這樣一行程式：

objTVShow.ProgramDate = dtmMyDate

為了方便，等號右邊的值（這裡指dtmMyDate）作為了一個程元賦給了函式。因此編譯器可能會認為在Get ProgramDate行有0程元，而Let ProgramDate卻多一個！分配的值總是被略過而作為屬性的最後一個程元，所以即使你使用其他程元，所賦的值總是作為最後一個程元。

現在看程式。無論透過ProgramDate設定日期為文字形式，還是用internal_ProgramDate譯成日期變數，程式都沒有問題。但能不能只使用一個入口呢？

如果internal_ProgramDate只能在內部有效，而使用Let ProgramDate檢查傳輸的資料型別，我們就可以作出選擇。例如：

Class TVProgram

  Public StartTime

  Private internal_ProgramDate

  Public Property Get ProgramDate

  ProgramDate = Day(internal_ProgramDate) & " " & _

  MonthName(Month(internal_ProgramDate)) & _

  " " & Year(internal_ProgramDate)

  End Property

  Public Property Let ProgramDate(ByVal varDateIn)

  If IsDate(varDateIn) Then

  internal_ProgramDate = varDateIn

  Else

  'Place some error handling code in here.

  End If

  End Property

  Public ProgramTitle

  End Class

並同樣宣告StartTime屬性：

Class TVProgram

  Private internal_StartTime

  Public Property Get StartTime

  StartTime = Hour(internal_StartTime) & ":" _

  & Minute(internal_StartTime)

  End Property

  Public Property Let StartTime(ByVal varTimeIn)

  If IsDate(varTimeIn) Then

  internal_StartTime = varTimeIn

  End If

  End Property

  Private internal_ProgramDate

  Public Property Get ProgramDate

  ProgramDate = Day(internal_ProgramDate) & " " _

  & MonthName(Month(internal_ProgramDate)) & _

  " " & Year(internal_ProgramDate)

  End Property

  Public Property Let ProgramDate(ByVal varDateIn)

  If IsDate(varDateIn) Then

  internal_ProgramDate = varDateIn

  End If

  End Property

  Public ProgramTitle

  End Class

  ...

 

  現在的程式碼離我們想要的還是有些不太實用，我們將在其他頁使用類TVProgram，因此最好將其獨立定義，以便所有也面都可以呼叫。我們將在第四部分討論這點。