智慧合約語言 Solidity 教程系列3 - 函式型別

Tiny熊發表於2017-12-14
Solid函式型別

最新內容會更新在主站深入淺出區塊鏈社群
原文連結:智慧合約語言 Solidity 教程系列3 - 函式型別

Solidity 教程系列第三篇 - Solidity 函式型別介紹。

寫在前面

Solidity 是以太坊智慧合約程式語言，閱讀本文前，你應該對以太坊、智慧合約有所瞭解，如果你還不瞭解，建議你先看以太坊是什麼

本文前半部分是參考Solidity 官方文件（當前最新版本：0.4.20）進行翻譯，後半部分函式可見性（ public, external, internal, privite ）深度分析（僅針對專欄訂閱使用者）。

函式型別（Function Types）

函式也是一種型別，且屬於值型別。
可以將一個函式賦值給一個函式型別的變數。還可以將一個函式作為引數進行傳遞。也可以在函式呼叫中返回一個函式。
函式型別有兩類:內部(internal)和外部(external)函式

內部(internal)函式只能在當前合約內被呼叫（在當前的程式碼塊內，包括內部庫函式，和繼承的函式中）。
外部(external)函式由地址和函式方法簽名兩部分組成，可作為外部函式呼叫的引數，或返回值。

函式型別定義如下：

function (<parameter types>) {internal|external} [pure|constant|view|payable] [returns (<return types>)]

如果函式不需要返回，則省去returns ()
函式型別預設是internal， 因此internal可以省去。但以此相反，合約中函式本身預設是public的， 僅僅是當作型別名使用時預設是internal的。

有兩個方式訪問函式，一種是直接用函式名f, 一種是this.f， 前者用於內部函式，後者用於外部函式。

如果一個函式變數沒有初始化，直接呼叫它將會產生異常。如果delete了一個函式後呼叫，也會發生同樣的異常。

如果外部函式型別在Solidity的上下文環境以外的地方使用，他們會被視為function型別。它會編碼為20位元組的函式所在地址，和在它之前的4位元組的函式方法簽名一起作為bytes24型別。
合約中的public的函式，可以使用internal和external兩種方式來呼叫。
internal訪問形式為f, external訪問形式為this.f

成員: 屬性 selector

public (或 external) 函式有一個特殊的成員selector, 它對應一個ABI 函式選擇器。
```js
pragma solidity ^0.4.16;

contract Selector {
function f() public view returns (bytes4) {
    return this.f.selector;
}
}
```

下面的程式碼顯示內部（internal）函式型別的使用：

pragma solidity ^0.4.16;

library ArrayUtils {
  // internal functions can be used in internal library functions because
  // they will be part of the same code context
  function map(uint[] memory self, function (uint) pure returns (uint) f)
    internal
    pure
    returns (uint[] memory r)
  {
    r = new uint[](self.length);
    for (uint i = 0; i < self.length; i++) {
      r[i] = f(self[i]);
    }
  }
  function reduce(
    uint[] memory self,
    function (uint, uint) pure returns (uint) f
  )
    internal
    pure
    returns (uint r)
  {
    r = self[0];
    for (uint i = 1; i < self.length; i++) {
      r = f(r, self[i]);
    }
  }
  function range(uint length) internal pure returns (uint[] memory r) {
    r = new uint[](length);
    for (uint i = 0; i < r.length; i++) {
      r[i] = i;
    }
  }
}

contract Pyramid {
  using ArrayUtils for *;
  function pyramid(uint l) public pure returns (uint) {
    return ArrayUtils.range(l).map(square).reduce(sum);
  }
  function square(uint x) internal pure returns (uint) {
    return x * x;
  }
  function sum(uint x, uint y) internal pure returns (uint) {
    return x + y;
  }
}

下面的程式碼顯示外部（external）函式型別的使用：

pragma solidity ^0.4.11;

contract Oracle {
  struct Request {
    bytes data;
    function(bytes memory) external callback;
  }
  Request[] requests;
  event NewRequest(uint);
  function query(bytes data, function(bytes memory) external callback) public {
    requests.push(Request(data, callback));
    NewRequest(requests.length - 1);
  }
  function reply(uint requestID, bytes response) public {
    // Here goes the check that the reply comes from a trusted source
    requests[requestID].callback(response);
  }
}

contract OracleUser {
  Oracle constant oracle = Oracle(0x1234567); // known contract
  function buySomething() {
    oracle.query("USD", this.oracleResponse);
  }
  function oracleResponse(bytes response) public {
    require(msg.sender == address(oracle));
    // Use the data
  }
}

函式可見性分析

  • public - 任意訪問
  • private - 僅當前合約內
  • internal - 僅當前合約及所繼承的合約
  • external - 僅外部訪問（在內部也只能用外部訪問方式訪問）

public 還是 external 最佳實踐

請訂閱區塊鏈技術檢視。

參考視訊

我們也推出了目前市面上最全的視訊教程：深入詳解以太坊智慧合約語言Solidity
目前我們也在招募體驗師，可以點選連結瞭解。

參考文件

Solidity官方文件-型別

深入淺出區塊鏈 - 系統學習區塊鏈，打造最好的區塊鏈技術部落格

相關文章