SAP Netweaver 裡有很多名字比較長的事務碼，比如 SAP CRM UI開發工具BSP_WD_CMPWB，直到今天我也記不住它。幸好SAP貼心地在SAP GUI裡提供了收藏夾功能，我們可以在SAP GUI裡建立樹狀結構的收藏夾事務碼列表，可以把若干業務上相關的事務碼放在同一個資料夾內，資料夾支援巢狀，如下圖：

![](https://img-blog.csdnimg.cn/img_convert/167558ddadc14b572a2d059094332317.png)

SAP選單是一個由使用者主記錄中的一個條目集中定義或覆蓋的區域選單。SAP選單或SAP區域選單顯示SAP選單樹中所有可用的SAP t-code，如下圖所示：

![](https://img-blog.csdnimg.cn/img_convert/7946bb47eaa91d1af85eeeab6361533d.png)

下面是 SAP Area menu 的建立步驟：

1. 使用事物碼 SE43：

![](https://img-blog.csdnimg.cn/img_convert/b91c0b7c0c9a019b6a5401fbdb92224d.png)

點選 Create Area Menu 按鈕：

![](https://img-blog.csdnimg.cn/img_convert/589f260707934c0660cf1b42735dabeb.png)

輸入選單的名稱和描述資訊：
![](https://img-blog.csdnimg.cn/img_convert/41e4ef88147299cc3b005e34f659388b.png)

2. 新增選單可供點選的子節點：

![](https://img-blog.csdnimg.cn/img_convert/8575c092855f1edbb5455cb98a78e762.png)

依次新增選單項和點選後執行的事物碼即可：
![](https://img-blog.csdnimg.cn/img_convert/786aece5fa448d9b2da5f18feb89b0d4.png)

但是SAP GUI的收藏夾事務碼管理功能有個侷限，收藏夾樹狀結構上的事務碼節點不支援剪下貼上操作。
比如我要想把下圖收藏夾尾部的BSP_WD_COMWB移動到收藏夾最頂端的Design Layer資料夾裡，只能滑鼠左鍵單擊BSP_WD_COMWB, 按住不放，然後將其拖拽到頂部的目的資料夾裡。

![](https://img-blog.csdnimg.cn/img_convert/2bf63ade3007c5c8754644a3151ce1fc.png)

因為我的收藏夾內容很多，所以我得按住滑鼠不放，同時用滑鼠中鍵把捲軸往上滑好幾下，直至收藏夾頂部的目標資料夾出現，再鬆開滑鼠左鍵，將其放到目標資料夾裡。

![](https://img-blog.csdnimg.cn/img_convert/821be9ead846d91a6b87524494342c64.png)

這種收藏夾的管理方式低效而且容易出錯，需要按住滑鼠左鍵不放同時滑動滑鼠中鍵，萬一此時左鍵鬆開，就會誤操作。
於是我自己開發了一個工具。本地新建一個記事本檔案，在其內把自己想要匯入SAP GUI收藏夾的事務碼按照自己喜歡的層級結構維護好，然後直接把這個記事本檔案上傳到ABAP系統即可。

![](https://img-blog.csdnimg.cn/img_convert/fb9de62bd5c7dcc37bdc96bb5dcf8980.png)

上圖的01. 02. 03開頭的內容代表的是SAP GUI裡生成收藏夾的資料夾名稱，方括號內即事務碼本身的值。操作記事本，比用滑鼠在SAP GUI裡做拖拽操作輕鬆多了，不是嗎？
下圖右邊是我在本地記事本里維護的內容，左邊是將這個記事本匯入到SAP GUI裡生成的收藏夾。

![](https://img-blog.csdnimg.cn/img_convert/1cf6b8d35830e820b75c840c2cf42256.png)

我開發的這個報表，會解析記事本里維護的事務碼和層級結構，然後把解析出的記錄插入到Netweaver存放收藏夾事務碼的資料庫表裡。

原始碼如下：

```abap
REPORT zfavorite.

TYPES: tt_tcode  TYPE STANDARD TABLE OF tstct-tcode,
       tt_wd_app TYPE STANDARD TABLE OF wdy_applicationt-application_name.
TYPES: BEGIN OF ty_file,
         text  LIKE smen_buffc-text,
         tcode LIKE smen_buffc-report,
       END   OF ty_file.

CLASS lcl_counter DEFINITION.

PUBLIC SECTION.
    METHODS: get_new_obj_id RETURNING VALUE(rv_id) TYPE int4,
      get_folder_sort RETURNING VALUE(rv_id) TYPE int4,
      get_tcode_sort RETURNING VALUE(rv_id) TYPE int4,
      reset_tcode_sort.

CONSTANTS: cv_root TYPE smen_buffc-parent_id VALUE '00001'.
    CONSTANTS: cv_level1 TYPE smen_buffc-menu_level VALUE '01',
               cv_level2 LIKE cv_level1 VALUE '02'.
  PRIVATE SECTION.
    DATA: mv_object_id   TYPE int4 VALUE 1,
          mv_folder_sort TYPE int4 VALUE 0,
          mv_tcode_sort  TYPE int4 VALUE 0.
ENDCLASS.

CLASS lcl_counter IMPLEMENTATION.
  METHOD: get_new_obj_id.
    ADD 1 TO mv_object_id.
    rv_id = mv_object_id.
  ENDMETHOD.

METHOD: get_folder_sort.
    ADD 10 TO mv_folder_sort.
    rv_id = mv_folder_sort.
  ENDMETHOD.

METHOD: get_tcode_sort.
    ADD 10 TO mv_tcode_sort.
    rv_id = mv_tcode_sort.
  ENDMETHOD.

METHOD reset_tcode_sort.
    CLEAR: mv_tcode_sort.
  ENDMETHOD.
ENDCLASS.

CLASS lcl_tool DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS: is_tcode  IMPORTING iv_text TYPE string RETURNING VALUE(result) TYPE abap_bool.
    CLASS-METHODS: is_wd_app  IMPORTING iv_text TYPE string RETURNING VALUE(result) TYPE abap_bool.
    CLASS-METHODS: get_tcode IMPORTING iv_text TYPE smen_buffc-text RETURNING VALUE(result) TYPE smen_buffc-report.
    CLASS-METHODS: get_wd_app IMPORTING iv_text TYPE smen_buffc-text RETURNING VALUE(result) TYPE smen_buffc-report.
    CLASS-METHODS: set_tcode_list IMPORTING it_tcode TYPE tt_tcode.
    CLASS-METHODS: set_wd_app_list IMPORTING it_app TYPE tt_wd_app.

CLASS-METHODS: get_tcode_description IMPORTING iv_tcode TYPE smen_buffc-report RETURNING VALUE(result) TYPE smen_buffc-text.
    CLASS-METHODS: get_app_description IMPORTING iv_app TYPE smen_buffc-text RETURNING VALUE(result) TYPE smen_buffc-text.
    CLASS-METHODS: get_menu_type IMPORTING is_menu TYPE ty_file RETURNING VALUE(result) TYPE int4.

CONSTANTS: cv_wd_app_type   TYPE smen_buffc-reporttype VALUE 'OT',
               cv_wd_app_report TYPE smen_buffc-report VALUE 'WDY_APPLICATION',
               BEGIN OF cs_entry_type,
                 top_tcode    TYPE int4 VALUE 1,
                 folder       TYPE int4 VALUE 2,
                 child_tcode  TYPE int4 VALUE 3,
                 top_wd_app   TYPE int4 VALUE 4,
                 child_wd_app TYPE int4 VALUE 5,
                 invalid      TYPE int4 VALUE 6,
               END OF cs_entry_type.

PRIVATE SECTION.
    CLASS-DATA: st_tcode  TYPE STANDARD TABLE OF tstct,
                st_wd_app TYPE STANDARD TABLE OF wdy_applicationt.
ENDCLASS.

CLASS lcl_tool IMPLEMENTATION.
  METHOD: is_tcode.
    IF iv_text CP '[*]'.
      result = abap_true.
    ELSE.
      result = abap_false.
    ENDIF.
  ENDMETHOD.

METHOD: is_wd_app.
    IF iv_text CP '(*)'.
      result = abap_true.
    ELSE.
      result = abap_false.
    ENDIF.
  ENDMETHOD.

METHOD: get_tcode.

result = iv_text.
    REPLACE ALL OCCURRENCES OF REGEX `[\[\]]` IN result WITH space.

CONDENSE result NO-GAPS.
  ENDMETHOD.

METHOD: get_wd_app.

result = iv_text.
    REPLACE ALL OCCURRENCES OF REGEX `[\(\)]` IN result WITH space.

CONDENSE result NO-GAPS.
  ENDMETHOD.

METHOD: set_tcode_list.
    SELECT * INTO CORRESPONDING FIELDS OF TABLE st_tcode FROM tstct
      FOR ALL ENTRIES IN it_tcode WHERE sprsl = sy-langu AND tcode = it_tcode-table_line.

ENDMETHOD.

METHOD: set_wd_app_list.
    SELECT * INTO CORRESPONDING FIELDS OF TABLE st_wd_app FROM wdy_applicationt
       FOR ALL ENTRIES IN it_app WHERE application_name = it_app-table_line AND langu = sy-langu.
  ENDMETHOD.

METHOD: get_tcode_description.
    FIELD-SYMBOLS: <line> TYPE tstct.
    READ TABLE st_tcode ASSIGNING <line> WITH KEY tcode = iv_tcode.
    IF sy-subrc = 0.
      result = <line>-ttext.
    ENDIF.
  ENDMETHOD.

METHOD: get_app_description.

FIELD-SYMBOLS: <line> LIKE LINE OF st_wd_app.
    READ TABLE st_wd_app ASSIGNING <line> WITH KEY application_name = iv_app.
    IF sy-subrc = 0.
      result = <line>-description.
    ENDIF.
  ENDMETHOD.

METHOD: get_menu_type.
    DATA: lv_is_tcode  TYPE abap_bool,
          lv_is_wd_app TYPE abap_bool.

lv_is_tcode = is_tcode( CONV #( is_menu-text ) ).
    lv_is_wd_app = is_wd_app( CONV #( is_menu-text ) ).

IF is_menu-text IS NOT INITIAL AND is_menu-tcode IS INITIAL.
      IF is_tcode( CONV #( is_menu-text ) ) = abap_true.
        result = cs_entry_type-top_tcode.
      ELSEIF is_wd_app( CONV #( is_menu-text ) ) = abap_true.
        result = cs_entry_type-top_wd_app.
      ELSE.
        result = cs_entry_type-folder.
      ENDIF.
    ELSEIF is_menu-tcode IS NOT INITIAL.
      IF is_tcode( CONV #( is_menu-tcode ) ) = abap_true.
        result = cs_entry_type-child_tcode.
      ELSEIF is_wd_app( CONV #( is_menu-tcode ) ) = abap_true.
        result = cs_entry_type-child_wd_app.
      ELSE.
        result = cs_entry_type-invalid.
      ENDIF.
    ELSE.
      result = cs_entry_type-invalid.
    ENDIF.
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.

DATA: gt_file     TYPE STANDARD TABLE OF ty_file,
        gt_tcodes   TYPE tt_tcode,
        gt_wd_app   TYPE tt_wd_app,
        lo_counter  TYPE REF TO lcl_counter,
        lv_filename TYPE localfile,
        lv_name_string type string.

CALL FUNCTION 'NAVIGATION_FILENAME_HELP'
    EXPORTING
      default_path_long      = '*.*'
      mode                   = 'O'
    IMPORTING
      selected_filename = lv_filename.

CHECK lv_filename IS NOT INITIAL.
  lv_name_string = lv_filename.
  CREATE OBJECT lo_counter.

CALL FUNCTION 'GUI_UPLOAD'
    EXPORTING
      filename                = lv_name_string
      filetype                = 'ASC'
      has_field_separator     = 'X'
    TABLES
      data_tab                = gt_file
    EXCEPTIONS
      file_open_error         = 1
      file_read_error         = 2
      no_batch                = 3
      gui_refuse_filetransfer = 4
      invalid_type            = 5
      no_authority            = 6                           "as of 4.6C
      OTHERS                  = 7.

DELETE gt_file WHERE tcode IS INITIAL AND text IS INITIAL.

DATA: ls_menu_entry     TYPE smen_buffc,
        lt_menu_entry     TYPE STANDARD TABLE OF smen_buffc,
        ls_web_link       TYPE smen_buffi,
        lt_web_link       TYPE STANDARD TABLE OF smen_buffi,
        lv_current_par_id TYPE smen_buffc-parent_id.

FIELD-SYMBOLS: <entry> LIKE LINE OF gt_file,
                 <menu>  LIKE LINE OF lt_menu_entry,
                 <link>  TYPE smen_buffi.

LOOP AT gt_file ASSIGNING <entry>.
    CLEAR: ls_menu_entry.
    ls_menu_entry-object_id = lo_counter->get_new_obj_id( ).
    ls_menu_entry-uname = sy-uname.
    ls_menu_entry-mandt = sy-mandt.

CASE lcl_tool=>get_menu_type( <entry> ).
      WHEN lcl_tool=>cs_entry_type-top_tcode.
        ls_menu_entry-reporttype = 'TR'.
        ls_menu_entry-parent_id = lcl_counter=>cv_root.
        ls_menu_entry-report = lcl_tool=>get_tcode( <entry>-text ).
        ls_menu_entry-menu_level = lcl_counter=>cv_level1.
        ls_menu_entry-sort_order = lo_counter->get_folder_sort( ).
        APPEND ls_menu_entry-report TO gt_tcodes.
      WHEN lcl_tool=>cs_entry_type-top_wd_app.
        ls_menu_entry-reporttype = 'OT'.
        ls_menu_entry-parent_id = lcl_counter=>cv_root.
        ls_menu_entry-report = lcl_tool=>cv_wd_app_report.
        ls_menu_entry-menu_level = lcl_counter=>cv_level1.
        ls_menu_entry-sort_order = lo_counter->get_folder_sort( ).
        ls_web_link-object_id = ls_menu_entry-object_id.
        APPEND ls_web_link TO lt_web_link.
        ls_menu_entry-text  = lcl_tool=>get_wd_app( <entry>-text ).
        APPEND ls_menu_entry-text  TO gt_wd_app.
      WHEN lcl_tool=>cs_entry_type-folder.
        ls_menu_entry-text = <entry>-text.
        ls_menu_entry-parent_id = lcl_counter=>cv_root.

ls_menu_entry-sort_order = lo_counter->get_folder_sort( ).
        ls_menu_entry-menu_level = lcl_counter=>cv_level1.
        lv_current_par_id = ls_menu_entry-object_id.
        lo_counter->reset_tcode_sort( ).
      WHEN lcl_tool=>cs_entry_type-child_tcode.
        ls_menu_entry-reporttype = 'TR'.
        ls_menu_entry-report = lcl_tool=>get_tcode( CONV #( <entry>-tcode ) ).
        ls_menu_entry-parent_id = lv_current_par_id.
        ls_menu_entry-sort_order = lo_counter->get_tcode_sort( ).
        ls_menu_entry-menu_level = lcl_counter=>cv_level2.
        APPEND ls_menu_entry-report TO gt_tcodes.
      WHEN lcl_tool=>cs_entry_type-child_wd_app.
        ls_menu_entry-reporttype = 'OT'.
        ls_menu_entry-report = lcl_tool=>cv_wd_app_report.
        ls_menu_entry-parent_id = lv_current_par_id.
        ls_menu_entry-sort_order = lo_counter->get_tcode_sort( ).
        ls_menu_entry-menu_level = lcl_counter=>cv_level2.
        ls_menu_entry-text  = lcl_tool=>get_wd_app( CONV #( <entry>-tcode ) ).
        APPEND ls_menu_entry-text TO gt_wd_app.
        ls_web_link-object_id = ls_menu_entry-object_id.
        APPEND ls_web_link TO lt_web_link.
      WHEN OTHERS.
        WRITE: / 'Invalid record: ', <entry>-text, <entry>-tcode COLOR COL_NEGATIVE.
        RETURN.
    ENDCASE.
    APPEND ls_menu_entry TO lt_menu_entry.
  ENDLOOP.

lcl_tool=>set_tcode_list( gt_tcodes ).
  lcl_tool=>set_wd_app_list( gt_wd_app ).

LOOP AT lt_menu_entry ASSIGNING <menu> WHERE reporttype = 'TR'.
    <menu>-text = lcl_tool=>get_tcode_description( <menu>-report ).
  ENDLOOP.

LOOP AT lt_web_link ASSIGNING <link>.
    <link>-mandt = sy-mandt.
    <link>-link_type = 'W'.
    <link>-uname = sy-uname.
    READ TABLE lt_menu_entry INTO ls_menu_entry WITH KEY object_id = <link>-object_id.
    CHECK sy-subrc = 0.
    TRANSLATE ls_menu_entry-text TO LOWER CASE.
    <link>-url = '0E' && ls_menu_entry-text.
  ENDLOOP.

LOOP AT lt_menu_entry ASSIGNING <menu> WHERE reporttype = 'OT'.
    <menu>-text = lcl_tool=>get_app_description( <menu>-text ).
  ENDLOOP.

DELETE FROM smen_buffc WHERE uname = sy-uname.
  DELETE FROM smen_buffi WHERE uname = sy-uname.

INSERT smen_buffc FROM TABLE lt_menu_entry.
  INSERT smen_buffi FROM TABLE lt_web_link.

COMMIT WORK AND WAIT.

WRITE: / 'Favorite list uploaded successfully, total entries: ', lines( lt_menu_entry ) COLOR COL_POSITIVE.
```
# 總結

本文首先介紹了 SAP Area Menu 的建立方式，以及標準的收藏夾管理功能和侷限性，接著分享了筆者自開發的收藏夾工具增強的功能以及全部的原始碼，希望對想提高 SAPGUI 工作效率的使用者有所幫助。</menu></menu></menu></menu></menu></menu></entry></entry></entry></entry></entry></entry></entry></entry></entry></menu></entry></line></line></line></line></line></line>

介紹一種對 SAP GUI 裡的收藏夾事務碼管理工具增強的實現方案

相關文章