iOS底層原理總結 - 探尋Class的本質

iOS底層原理總結 - 探尋Class的本質

對小碼哥底層班視訊學習的總結與記錄。面試題部分，通過對面試題的分析探索問題的本質內容。 上接 iOS底層原理總結 - 探尋OC物件的本質

Class的本質

我們知道不管是類物件還是元類物件，型別都是Class，class和mete-class的底層都是objc_class結構體的指標，記憶體中就是結構體，本章來探尋Class的本質。

Class objectClass = [NSObject class];        
Class objectMetaClass = object_getClass([NSObject class]);
複製程式碼

點選Class來到內部，我們可以發現

typedef struct objc_class *Class;
複製程式碼

Class物件其實是一個指向objc_class結構體的指標。因此我們可以說類物件或元類物件在記憶體中其實就是objc_class結構體。

我們來到objc_class內部，可以看到這段在底層原理中經常出現的程式碼。

struct objc_class {
    Class _Nonnull isa  OBJC_ISA_AVAILABILITY;

#if !__OBJC2__
    Class _Nullable super_class                              OBJC2_UNAVAILABLE;
    const char * _Nonnull name                               OBJC2_UNAVAILABLE;
    long version                                             OBJC2_UNAVAILABLE;
    long info                                                OBJC2_UNAVAILABLE;
    long instance_size                                       OBJC2_UNAVAILABLE;
    struct objc_ivar_list * _Nullable ivars                  OBJC2_UNAVAILABLE;
    struct objc_method_list * _Nullable * _Nullable methodLists                    OBJC2_UNAVAILABLE;
    struct objc_cache * _Nonnull cache                       OBJC2_UNAVAILABLE;
    struct objc_protocol_list * _Nullable protocols          OBJC2_UNAVAILABLE;
#endif

} OBJC2_UNAVAILABLE;
/* Use `Class` instead of `struct objc_class *` */
複製程式碼

這部分程式碼相信在文章中很常見，但是OBJC2_UNAVAILABLE;說明這些程式碼已經不在使用了。那麼目前objc_class的結構是什麼樣的呢？我們通過objc原始碼中去查詢objc_class結構體的內容。

我們發現這個結構體繼承 objc_object 並且結構體內有一些函式，因為這是c++結構體，在c上做了擴充套件，因此結構體中可以包含函式。我們來到objc_object內，擷取部分程式碼

我們發現objc_object中有一個isa指標，那麼objc_class繼承objc_object，也就同樣擁有一個isa指標

那麼我們之前瞭解到的，類中儲存的類的成員變數資訊，例項方法，屬性名等這些資訊在哪裡呢。我們來到class_rw_t中，擷取部分程式碼，我們發現class_rw_t中儲存著方法列表，屬性列表，協議列表等內容。

而class_rw_t是通過bits呼叫data方法得來的，我們來到data方法內部實現。我們可以看到，data函式內部僅僅對bits進行&FAST_DATA_MASK操作

而成員變數資訊則是儲存在class_ro_t內部中的，我們來到class_ro_t內檢視。

最後總結通過一張圖進行總結

如何證明上述內容是正確的。

我們可以自定義一個結構體，如果我們自己寫的結構和objc_class真實結構是一樣的，那麼當我們強制轉化的時候，就會一一對應的賦值。此時我們就可以拿到結構體內部的資訊。

下列程式碼是我們仿照objc_class結構體，提取其中需要使用到的資訊，自定義的一個結構體。

#import <Foundation/Foundation.h>

#ifndef XXClassInfo_h
#define XXClassInfo_h

# if __arm64__
#   define ISA_MASK        0x0000000ffffffff8ULL
# elif __x86_64__
#   define ISA_MASK        0x00007ffffffffff8ULL
# endif

#if __LP64__
typedef uint32_t mask_t;
#else
typedef uint16_t mask_t;
#endif
typedef uintptr_t cache_key_t;

struct bucket_t {
    cache_key_t _key;
    IMP _imp;
};

struct cache_t {
    bucket_t *_buckets;
    mask_t _mask;
    mask_t _occupied;
};

struct entsize_list_tt {
    uint32_t entsizeAndFlags;
    uint32_t count;
};

struct method_t {
    SEL name;
    const char *types;
    IMP imp;
};

struct method_list_t : entsize_list_tt {
    method_t first;
};

struct ivar_t {
    int32_t *offset;
    const char *name;
    const char *type;
    uint32_t alignment_raw;
    uint32_t size;
};

struct ivar_list_t : entsize_list_tt {
    ivar_t first;
};

struct property_t {
    const char *name;
    const char *attributes;
};

struct property_list_t : entsize_list_tt {
    property_t first;
};

struct chained_property_list {
    chained_property_list *next;
    uint32_t count;
    property_t list[0];
};

typedef uintptr_t protocol_ref_t;
struct protocol_list_t {
    uintptr_t count;
    protocol_ref_t list[0];
};

struct class_ro_t {
    uint32_t flags;
    uint32_t instanceStart;
    uint32_t instanceSize;  // instance物件佔用的記憶體空間
#ifdef __LP64__
    uint32_t reserved;
#endif
    const uint8_t * ivarLayout;
    const char * name;  // 類名
    method_list_t * baseMethodList;
    protocol_list_t * baseProtocols;
    const ivar_list_t * ivars;  // 成員變數列表
    const uint8_t * weakIvarLayout;
    property_list_t *baseProperties;
};

struct class_rw_t {
    uint32_t flags;
    uint32_t version;
    const class_ro_t *ro;
    method_list_t * methods;    // 方法列表
    property_list_t *properties;    // 屬性列表
    const protocol_list_t * protocols;  // 協議列表
    Class firstSubclass;
    Class nextSiblingClass;
    char *demangledName;
};

#define FAST_DATA_MASK          0x00007ffffffffff8UL
struct class_data_bits_t {
    uintptr_t bits;
public:
    class_rw_t* data() { // 提供data()方法進行 & FAST_DATA_MASK 操作
        return (class_rw_t *)(bits & FAST_DATA_MASK);
    }
};

/* OC物件 */
struct xx_objc_object {
    void *isa;
};

/* 類物件 */
struct xx_objc_class : xx_objc_object {
    Class superclass;
    cache_t cache;
    class_data_bits_t bits;
public:
    class_rw_t* data() {
        return bits.data();
    }
    
    xx_objc_class* metaClass() { // 提供metaClass函式，獲取元類物件
// 上一篇我們講解過，isa指標需要經過一次 & ISA_MASK操作之後才得到真正的地址
        return (xx_objc_class *)((long long)isa & ISA_MASK);
    }
};

#endif /* XXClassInfo_h */

複製程式碼

接下來我們將自己定義的類強制轉化為我們自定義的精簡的class結構體型別。

#import <Foundation/Foundation.h>
#import <objc/runtime.h>
#import "XXClassInfo.h"

/* Person */
@interface Person : NSObject <NSCopying>
{
    @public
    int _age;
}
@property (nonatomic, assign) int height;
- (void)personMethod;
+ (void)personClassMethod;
@end

@implementation Person
- (void)personMethod {}
+ (void)personClassMethod {}
@end

/* Student */
@interface Student : Person <NSCoding>
{
    @public
    int _no;
}

@property (nonatomic, assign) int score;
- (void)studentMethod;
+ (void)studentClassMethod;
@end

@implementation Student
- (void)studentMethod {}
+ (void)studentClassMethod {}
@end

int main(int argc, const char * argv[]) {
    @autoreleasepool {
        NSObject *object = [[NSObject alloc] init];
        Person *person = [[Person alloc] init];
        Student *student = [[Student alloc] init];
        
        xx_objc_class *objectClass = (__bridge xx_objc_class *)[object class];
        xx_objc_class *personClass = (__bridge xx_objc_class *)[person class];
        xx_objc_class *studentClass = (__bridge xx_objc_class *)[student class];
        
        xx_objc_class *objectMetaClass = objectClass->metaClass();
        xx_objc_class *personMetaClass = personClass->metaClass();
        xx_objc_class *studentMetaClass = studentClass->metaClass();
        
        class_rw_t *objectClassData = objectClass->data();
        class_rw_t *personClassData = personClass->data();
        class_rw_t *studentClassData = studentClass->data();
        
        class_rw_t *objectMetaClassData = objectMetaClass->data();
        class_rw_t *personMetaClassData = personMetaClass->data();
        class_rw_t *studentMetaClassData = studentMetaClass->data();

        // 0x00007ffffffffff8
        NSLog(@"%p %p %p %p %p %p",  objectClassData, personClassData, studentClassData,
              objectMetaClassData, personMetaClassData, studentMetaClassData);

    return 0;
}
複製程式碼

通過打斷點，我們可以看到class內部資訊。

至此，我們再次拿出那張經典的圖，挨個分析圖中isa指標和superclass指標的指向

instance物件

首先我們來看instance物件，我們通過上一篇文章知道，instance物件中儲存著isa指標和其他成員變數，並且instance物件的isa指標是指向其類物件地址的。我們首先分析上述程式碼中我們建立的object，person，student三個instance物件與其相對應的類物件objectClass，personClass，studentClass。

從上圖中我們可以發現instance物件中確實儲存了isa指標和其成員變數，同時將instance物件的isa指標經過&運算之後計算出的地址確實是其相應類物件的記憶體地址。由此我們證明isa，superclass指向圖中的1，2，3號線。

class物件

接著我們來看class物件，同樣通過上一篇文章，我們明確class物件中儲存著isa指標，superclass指標，以及類的屬性資訊，類的成員變數資訊，類的物件方法，和類的協議資訊，而通過上面對object原始碼的分析，我們知道這些資訊儲存在class物件的class_rw_t中，我們通過強制轉化來窺探其中的內容。如下圖

上圖中我們通過模擬對person類物件呼叫.data函式，即對bits進行&FAST_DATA_MASK(0x00007ffffffffff8UL)運算，並轉化為class_rw_t。即上圖中的personClassData。其中我們發現成員變數資訊，物件方法，屬性等資訊只顯示first第一個，如果想要拿到更多的需要通過程式碼將指標後移獲取。而上圖中的instaceSize = 16也同person物件中isa指標8個位元組+_age4個位元組+_height4個位元組相對應起來。這裡不在展開對objectClassData及studentClassData進行分析，基本內容同personClassData相同。

那麼類物件中的isa指標和superclass指標的指向是否如那張經典的圖示呢？我們來驗證一下。

通過上圖中的記憶體地址的分析，由此我們證明isa，superclass指向圖中，isa指標的4，5，6號線，以及superclass指標的10，11，12號線。

meta-class物件

最後我們來看meta-class元類物件，上文提到meta-class中儲存著isa指標，superclass指標，以及類的類方法資訊。同時我們知道meta-class元類物件與class類物件，具有相同的結構，只不過儲存的資訊不同，並且元類物件的isa指標指向基類的元類物件，基類的元類物件的isa指標指向自己。元類物件的superclass指標指向其父類的元類物件，基類的元類物件的superclass指標指向其類物件。

與class物件相同，我們同樣通過模擬對person元類物件呼叫.data函式，即對bits進行&FAST_DATA_MASK(0x00007ffffffffff8UL)運算，並轉化為class_rw_t。

首先我們可以看到結構同personClassData相同，並且成員變數及屬性列表等資訊為空，而methods中儲存著類方法personClassMethod。

接著來驗證isa及superclass指標的指向是否同上圖序號標註一樣。

上圖中通過地址證明meta-class的isa指向基類的meta-class，基類的isa指標也指向自己。

上圖中通過地址證明meta-class的superclass指向父類的meta-class，基類的meta-class的superclass指向基類的class類。

---

最近看到一句話，在這裡與大家共勉。當承認自己與別人的差距的時候，會變得很輕鬆。因為我們終於不用計較為什麼他行我不行，終於不用默默努力較勁心裡告訴自己一定要超過別人。而同時也失去了鬥志，失去了戰勝別人得唯一籌碼。最怕一生碌碌無為，還安慰自己平凡可貴。

文中如果有不對的地方歡迎指出。我是xx_cc，一隻長大很久但還沒有二夠的傢伙。需要視訊一起探討學習的coder可以加我Q：2336684744

---