查詢出系統中沒有使用繫結變數的SQL

查詢出系統中沒有使用繫結變數的SQL

 

 

ASKTOM網站提供了一個函式remove_constants，來檢查共享池中的SQL執行情況

1、首先建立一個表，用於存放整理過的資料：
create table t1 as select sql_text from v$sqlarea;
2、給表增加一個欄位：
alter table t1 add sql_text_wo_constants varchar2(1000);
3、建立函式remove_constants:
create or replace function
remove_constants( p_query in varchar2 ) return varchar2
as
    l_query long;
    l_char  varchar2(1);
    l_in_quotes boolean default FALSE;
begin
    for i in 1 .. length( p_query )
    loop
        l_char := substr(p_query,i,1);
        if ( l_char = '''' and l_in_quotes )
        then
            l_in_quotes := FALSE;
        elsif ( l_char = '''' and NOT l_in_quotes )
        then
            l_in_quotes := TRUE;
            l_query := l_query || '''#';
        end if;
        if ( NOT l_in_quotes ) then
            l_query := l_query || l_char;
        end if;
    end loop;
    l_query := translate( l_query, '0123456789', '@@@@@@@@@@' );
    for i in 0 .. 8 loop
        l_query := replace( l_query, lpad('@',10-i,'@'), '@' );
        l_query := replace( l_query, lpad(' ',10-i,' '), ' ' );
    end loop;
    return upper(l_query);
end;
/
4、將v$sql檢視中的欄位：sql_text的資料用remove_constants處理後，來更新t1表
update t1 set sql_text_wo_constants = remove_constants(sql_text);
5、查出除了謂詞條件不同的SQL語句和它們的執行次數，這裡是查詢SQL沒有重用超過100次的SQL語句:
select sql_text_wo_constants, count(*)
  from t1
 group by sql_text_wo_constants
having count(*) > 100
 order by 2
/

測試：
使用一個迴圈執行1000次某條SQL，每次執行只有謂詞不同：
begin
for i in 1..1000 loop
execute immediate 'select * from t where OBJECT_ID = '||i;
end loop;
end;
/

select sql_text_wo_constants, count(*)
  from t1
 group by sql_text_wo_constants
having count(*) > 100
 order by 2;

SQL_TEXT_WO_CONSTANTS  COUNT(*)
---------------------  ------------
SELECT * FROM T WHERE OBJECT_ID = @
      1000

可以看到輸出結果中，這條語句被執行了1000次，其中謂詞條件被“@”代替，這樣通過這個函式，可以很容易找到共享池中哪些SQL沒有使用繫結變數。