PLSQL Language Referenc-PL/SQL集合和記錄-關聯陣列

變數名(索引)

-- 使用字串索引的關聯陣列

DECLARE 

    TYPE population IS TABLE OF NUMBER  -- 關聯陣列元素型別

    INDEX BY VARCHAR2(64);                -- 索引是字串

    city_population  population;        -- 關聯陣列變數

    i  VARCHAR2(64);                   

BEGIN

    --新增元素

    city_population('Smallville')  := 2000;

    city_population('Midland')     := 750000;

    city_population('Megalopolis') := 1000000;

    -- 改變值

    city_population('Smallville') := 2001;

    -- 輸出關聯陣列

    i := city_population.FIRST;  -- 獲取第1個元素

    WHILE i IS NOT NULL LOOP

        DBMS_Output.PUT_LINE

            (i || ' = ' || city_population(i));

        i := city_population.NEXT(i);  -- 獲取下一下元素

    END LOOP;

END;

--求1-n的和再乘以一個數，只適用於1-10

DECLARE

    TYPE sum_multiples IS TABLE OF PLS_INTEGER INDEX BY PLS_INTEGER;

    n  PLS_INTEGER := 5;  

    sn PLS_INTEGER := 10; 

    m  PLS_INTEGER := 3;  

    --函式的返回值為一個關聯陣列

    FUNCTION get_sum_multiples (

        multiple IN PLS_INTEGER,

        num      IN PLS_INTEGER

    ) RETURN sum_multiples

    IS

        s sum_multiples;

    BEGIN

        FOR i IN 1..num LOOP

            s(i) := multiple * ((i * (i + 1)) / 2);

        END LOOP;

        RETURN s;

    END get_sum_multiples;

BEGIN

    DBMS_OUTPUT.PUT_LINE (

        '1到 ' || TO_CHAR(n) || '的和'|| ' 乘以 ' ||

        TO_CHAR(m) || ' = ' || TO_CHAR(get_sum_multiples (m, sn)(n))

    );

END;