Oracle 傳送郵件的儲存過程
從網上down的一個用Oracle 傳送郵件的儲存過程，測試可以正常使用。 傳送郵件直接呼叫這個儲存過程就可以了，引數的意義裡面都有說明。
程式碼如下：
CREATE OR REPLACE PROCEDURE PROCSENDEMAIL(P_TXT VARCHAR2,
P_SUB VARCHAR2,
P_SENDOR VARCHAR2,
P_RECEIVER VARCHAR2,
P_SERVER VARCHAR2,
P_PORT NUMBER DEFAULT 25,
P_NEED_SMTP INT DEFAULT 0,
P_USER VARCHAR2 DEFAULT NULL,
P_PASS VARCHAR2 DEFAULT NULL,
P_FILENAME VARCHAR2 DEFAULT NULL,
P_ENCODE VARCHAR2 DEFAULT 'bit 7')
AUTHID CURRENT_USER IS
/*
作用：用oracle傳送郵件
主要功能：1、支援多收件人。
2、支援中文
3、支援抄送人
4、支援大於32K的附件
5、支援多行正文
6、支援多附件
7、支援文字附件和二進位制附件
8、支援HTML格式
8、支援
作者：suk
引數說明：
p_txt :郵件正文
p_sub: 郵件標題
p_SendorAddress : 傳送人郵件地址
p_ReceiverAddress : 接收地址，可以同時傳送到多個地址上，地址之間用","或者";"隔開
p_EmailServer : 郵件伺服器地址，可以是域名或者IP
p_Port ：郵件伺服器埠
p_need_smtp：是否需要smtp認證，0表示不需要，1表示需要
p_user：smtp驗證需要的使用者名稱
p_pass：smtp驗證需要的密碼
p_filename：附件名稱，必須包含完整的路徑，如"d:\temp\a.txt"。
可以有多個附件，附件名稱只見用逗號或者分號分隔
p_encode：附件編碼轉換格式，其中 p_encode='bit 7' 表示文字型別附件
p_encode='base64' 表示二進位制型別附件
注意：
1、對於文字型別的附件，不能用base64的方式傳送，否則出錯
2、對於多個附件只能用同一種格式傳送
*/
L_CRLF VARCHAR2(2) := UTL_TCP.CRLF;
L_SENDORADDRESS VARCHAR2(4000);
L_SPLITE VARCHAR2(10) := '++';
BOUNDARY CONSTANT VARCHAR2(256) := '-----BYSUK';
FIRST_BOUNDARY CONSTANT VARCHAR2(256) := '--' || BOUNDARY || L_CRLF;
LAST_BOUNDARY CONSTANT VARCHAR2(256) := '--' || BOUNDARY || '--' ||
L_CRLF;
MULTIPART_MIME_TYPE CONSTANT VARCHAR2(256) := 'multipart/mixed; boundary="' ||
BOUNDARY || '"';
/* 以下部分是傳送大二進位制附件時用到的變數 */
L_FIL BFILE;
L_FILE_LEN NUMBER;
L_MODULO NUMBER;
L_PIECES NUMBER;
L_FILE_HANDLE UTL_FILE.FILE_TYPE;
L_AMT BINARY_INTEGER := 672 * 3; /* ensures proper format; 2016 */
L_FILEPOS PLS_INTEGER := 1; /* pointer for the file */
L_CHUNKS NUMBER;
L_BUF RAW(2100);
L_DATA RAW(2100);
L_MAX_LINE_WIDTH NUMBER := 54;
L_DIRECTORY_BASE_NAME VARCHAR2(100) := 'DIR_FOR_SEND_MAIL';
L_LINE VARCHAR2(1000);
L_MESG VARCHAR2(32767);
/* 以上部分是傳送大二進位制附件時用到的變數 */
TYPE ADDRESS_LIST IS TABLE OF VARCHAR2(100) INDEX BY BINARY_INTEGER;
MY_ADDRESS_LIST ADDRESS_LIST;
TYPE ACCT_LIST IS TABLE OF VARCHAR2(100) INDEX BY BINARY_INTEGER;
MY_ACCT_LIST ACCT_LIST;
-------------------------------------返回附件原始檔所在目錄或者名稱--------------------------------------
FUNCTION GET_FILE(P_FILE VARCHAR2,
P_GET INT) RETURN VARCHAR2 IS
--p_get=1 表示返回目錄
--p_get=2 表示返回檔名
L_FILE VARCHAR2(1000);
BEGIN
IF INSTR(P_FILE, '\') > 0 THEN
--windows
IF P_GET = 1 THEN
L_FILE := SUBSTR(P_FILE, 1, INSTR(P_FILE, '\', -1) - 1);
ELSIF P_GET = 2 THEN
L_FILE := SUBSTR(P_FILE, - (LENGTH(P_FILE) - INSTR(P_FILE, '\', -1)));
END IF;
ELSIF INSTR(P_FILE, '/') > 0 THEN
--linux/unix
IF P_GET = 1 THEN
L_FILE := SUBSTR(P_FILE, 1, INSTR(P_FILE, '/', -1) - 1);
ELSIF P_GET = 2 THEN
L_FILE := SUBSTR(P_FILE, - (LENGTH(P_FILE) - INSTR(P_FILE, '/', -1)));
END IF;
END IF;
RETURN L_FILE;
END;
---------------------------------------------刪除directory------------------------------------
PROCEDURE DROP_DIRECTORY(P_DIRECTORY_NAME VARCHAR2) IS
BEGIN
EXECUTE IMMEDIATE 'drop directory ' || P_DIRECTORY_NAME;
EXCEPTION
WHEN OTHERS THEN
NULL;
END;
--------------------------------------------------建立directory-----------------------------------------
PROCEDURE CREATE_DIRECTORY(P_DIRECTORY_NAME VARCHAR2,
P_DIR VARCHAR2) IS
BEGIN
EXECUTE IMMEDIATE 'create directory ' || P_DIRECTORY_NAME || ' as ''' ||
P_DIR || '''';
EXECUTE IMMEDIATE 'grant read,write on directory ' || P_DIRECTORY_NAME ||
' to public';
EXCEPTION
WHEN OTHERS THEN
RAISE;
END;
--------------------------------------------分割郵件地址或者附件地址-----------------------------------
PROCEDURE P_SPLITE_STR(P_STR VARCHAR2,
P_SPLITE_FLAG INT DEFAULT 1) IS
L_ADDR VARCHAR2(254) := '';
L_LEN INT;
L_STR VARCHAR2(4000);
J INT := 0; --表示郵件地址或者附件的個數
BEGIN
/*處理接收郵件地址列表，包括去空格、將;轉換為,等*/
L_STR := TRIM(RTRIM(REPLACE(REPLACE(P_STR, ';', ','), ' ', ''), ','));
L_LEN := LENGTH(L_STR);
FOR I IN 1 .. L_LEN LOOP
IF SUBSTR(L_STR, I, 1) <> ',' THEN
L_ADDR := L_ADDR || SUBSTR(L_STR, I, 1);
ELSE
J := J + 1;
IF P_SPLITE_FLAG = 1 THEN --表示處理郵件地址
--前後需要加上'<>'，否則很多郵箱將不能傳送郵件
L_ADDR := '';
--呼叫郵件傳送過程
MY_ADDRESS_LIST(J) := L_ADDR;
ELSIF P_SPLITE_FLAG = 2 THEN --表示處理附件名稱
MY_ACCT_LIST(J) := L_ADDR;
END IF;
L_ADDR := '';
END IF;
IF I = L_LEN THEN
J := J + 1;
IF P_SPLITE_FLAG = 1 THEN
--呼叫郵件傳送過程
L_ADDR := '';
MY_ADDRESS_LIST(J) := L_ADDR;
ELSIF P_SPLITE_FLAG = 2 THEN
MY_ACCT_LIST(J) := L_ADDR;
END IF;
END IF;
END LOOP;
END;
------------------------------------------------寫郵件頭和郵件內容------------------------------------------
PROCEDURE WRITE_DATA(P_CONN IN OUT NOCOPY UTL_SMTP.CONNECTION,
P_NAME IN VARCHAR2,
P_VALUE IN VARCHAR2,
P_SPLITE VARCHAR2 DEFAULT ':',
P_CRLF VARCHAR2 DEFAULT L_CRLF) IS
BEGIN
/* utl_raw.cast_to_raw 對解決中文亂碼問題很重要*/
UTL_SMTP.WRITE_RAW_DATA(P_CONN, UTL_RAW.CAST_TO_RAW(CONVERT(P_NAME ||
P_SPLITE ||
P_VALUE ||
P_CRLF, 'ZHS16GBK')));
END;
----------------------------------------寫MIME郵件尾部-----------------------------------------------------
PROCEDURE END_BOUNDARY(CONN IN OUT NOCOPY UTL_SMTP.CONNECTION,
LAST IN BOOLEAN DEFAULT FALSE) IS
BEGIN
UTL_SMTP.WRITE_DATA(CONN, UTL_TCP.CRLF);
IF (LAST) THEN
UTL_SMTP.WRITE_DATA(CONN, LAST_BOUNDARY);
END IF;
END;
----------------------------------------------傳送附件----------------------------------------------------
PROCEDURE ATTACHMENT(CONN IN OUT NOCOPY UTL_SMTP.CONNECTION,
MIME_TYPE IN VARCHAR2 DEFAULT 'text/plain',
INLINE IN BOOLEAN DEFAULT TRUE,
FILENAME IN VARCHAR2 DEFAULT 't.txt',
TRANSFER_ENC IN VARCHAR2 DEFAULT '7 bit',
DT_NAME IN VARCHAR2 DEFAULT '0') IS
L_FILENAME VARCHAR2(1000);
BEGIN
--寫附件頭
UTL_SMTP.WRITE_DATA(CONN, FIRST_BOUNDARY);
--設定附件格式
WRITE_DATA(CONN, 'Content-Type', MIME_TYPE);
--如果檔名稱非空，表示有附件
DROP_DIRECTORY(DT_NAME);
--建立directory
CREATE_DIRECTORY(DT_NAME, GET_FILE(FILENAME, 1));
--得到附件檔名稱
L_FILENAME := GET_FILE(FILENAME, 2);
IF (INLINE) THEN
WRITE_DATA(CONN, 'Content-Disposition', 'inline; filename="' ||
L_FILENAME || '"');
ELSE
WRITE_DATA(CONN, 'Content-Disposition', 'attachment; filename="' ||
L_FILENAME || '"');
END IF;
--設定附件的轉換格式
IF (TRANSFER_ENC IS NOT NULL) THEN
WRITE_DATA(CONN, 'Content-Transfer-Encoding', TRANSFER_ENC);
END IF;
UTL_SMTP.WRITE_DATA(CONN, UTL_TCP.CRLF);
--begin 貼附件內容
IF TRANSFER_ENC = 'bit 7' THEN
--如果是文字型別的附件
BEGIN
L_FILE_HANDLE := UTL_FILE.FOPEN(DT_NAME, L_FILENAME, 'r'); --開啟檔案
--把附件分成多份，這樣可以傳送超過32K的附件
LOOP
UTL_FILE.GET_LINE(L_FILE_HANDLE, L_LINE);
L_MESG := L_LINE || L_CRLF;
WRITE_DATA(CONN, '', L_MESG, '', '');
END LOOP;
UTL_FILE.FCLOSE(L_FILE_HANDLE);
END_BOUNDARY(CONN);
EXCEPTION
WHEN OTHERS THEN
UTL_FILE.FCLOSE(L_FILE_HANDLE);
END_BOUNDARY(CONN);
NULL;
END; --結束文字型別附件的處理
ELSIF TRANSFER_ENC = 'base64' THEN
--如果是二進位制型別的附件
BEGIN
--把附件分成多份，這樣可以傳送超過32K的附件
L_FILEPOS := 1;--重置offset，在傳送多個附件時，必須重置
L_FIL := BFILENAME(DT_NAME, L_FILENAME);
L_FILE_LEN := DBMS_LOB.GETLENGTH(L_FIL);
L_MODULO := MOD(L_FILE_LEN, L_AMT);
L_PIECES := TRUNC(L_FILE_LEN / L_AMT);
IF (L_MODULO <> 0) THEN
L_PIECES := L_PIECES + 1;
END IF;
DBMS_LOB.FILEOPEN(L_FIL, DBMS_LOB.FILE_READONLY);
DBMS_LOB.READ(L_FIL, L_AMT, L_FILEPOS, L_BUF);
L_DATA := NULL;
FOR I IN 1 .. L_PIECES LOOP
L_FILEPOS := I * L_AMT + 1;
L_FILE_LEN := L_FILE_LEN - L_AMT;
L_DATA := UTL_RAW.CONCAT(L_DATA, L_BUF);
L_CHUNKS := TRUNC(UTL_RAW.LENGTH(L_DATA) / L_MAX_LINE_WIDTH);
IF (I <> L_PIECES) THEN
L_CHUNKS := L_CHUNKS - 1;
END IF;
UTL_SMTP.WRITE_RAW_DATA(CONN, UTL_ENCODE.BASE64_ENCODE(L_DATA));
L_DATA := NULL;
IF (L_FILE_LEN < L_AMT AND L_FILE_LEN > 0) THEN
L_AMT := L_FILE_LEN;
END IF;
DBMS_LOB.READ(L_FIL, L_AMT, L_FILEPOS, L_BUF);
END LOOP;
DBMS_LOB.FILECLOSE(L_FIL);
END_BOUNDARY(CONN);
EXCEPTION
WHEN OTHERS THEN
DBMS_LOB.FILECLOSE(L_FIL);
END_BOUNDARY(CONN);
RAISE;
END; --結束處理二進位制附件
END IF; --結束處理附件內容
DROP_DIRECTORY(DT_NAME);
END; --結束過程ATTACHMENT
---------------------------------------------真正傳送郵件的過程--------------------------------------------
PROCEDURE P_EMAIL(P_SENDORADDRESS2 VARCHAR2, --傳送地址
P_RECEIVERADDRESS2 VARCHAR2) --接受地址
IS
L_CONN UTL_SMTP.CONNECTION; --定義連線
BEGIN
/*初始化郵件伺服器資訊，連線郵件伺服器*/
L_CONN := UTL_SMTP.OPEN_CONNECTION(P_SERVER, P_PORT);
UTL_SMTP.HELO(L_CONN, P_SERVER);
/* smtp伺服器登入校驗 */
IF P_NEED_SMTP = 1 THEN
UTL_SMTP.COMMAND(L_CONN, 'AUTH LOGIN', '');
UTL_SMTP.COMMAND(L_CONN, UTL_RAW.CAST_TO_VARCHAR2(UTL_ENCODE.BASE64_ENCODE(UTL_RAW.CAST_TO_RAW(P_USER))));
UTL_SMTP.COMMAND(L_CONN, UTL_RAW.CAST_TO_VARCHAR2(UTL_ENCODE.BASE64_ENCODE(UTL_RAW.CAST_TO_RAW(P_PASS))));
END IF;
/*設定傳送地址和接收地址*/
UTL_SMTP.MAIL(L_CONN, P_SENDORADDRESS2);
UTL_SMTP.RCPT(L_CONN, P_RECEIVERADDRESS2);
/*設定郵件頭*/
UTL_SMTP.OPEN_DATA(L_CONN);
WRITE_DATA(L_CONN, 'Date', TO_CHAR(SYSDATE, 'yyyy-mm-dd hh24:mi:ss'));
/*設定傳送人*/
WRITE_DATA(L_CONN, 'From', P_SENDOR);
/*設定接收人*/
WRITE_DATA(L_CONN, 'To', P_RECEIVER);
/*設定郵件主題*/
WRITE_DATA(L_CONN, 'Subject', P_SUB);
WRITE_DATA(L_CONN, 'Content-Type', MULTIPART_MIME_TYPE);
UTL_SMTP.WRITE_DATA(L_CONN, UTL_TCP.CRLF);
UTL_SMTP.WRITE_DATA(L_CONN, FIRST_BOUNDARY);
WRITE_DATA(L_CONN, 'Content-Type', 'text/plain;charset=gb2312');
--單獨空一行，否則，正文內容不顯示
UTL_SMTP.WRITE_DATA(L_CONN, UTL_TCP.CRLF);
/* 設定郵件正文
把分隔符還原成chr(10)。這主要是為了shell中呼叫該過程，如果有多行，則先把多行的內容合併成一行，並用 l_splite分隔
然後用 l_crlf替換chr(10)。這一步是必須的，否則將不能傳送郵件正文有多行的郵件
*/
WRITE_DATA(L_CONN, '', REPLACE(REPLACE(P_TXT, L_SPLITE, CHR(10)), CHR(10), L_CRLF), '', '');
END_BOUNDARY(L_CONN);
--如果檔名稱不為空，則傳送附件
IF (P_FILENAME IS NOT NULL) THEN
--根據逗號或者分號拆分附件地址
P_SPLITE_STR(P_FILENAME, 2);
--迴圈傳送附件(在同一個郵件中)
FOR K IN 1 .. MY_ACCT_LIST.COUNT LOOP
ATTACHMENT(CONN => L_CONN, FILENAME => MY_ACCT_LIST(K), TRANSFER_ENC => P_ENCODE, DT_NAME => L_DIRECTORY_BASE_NAME ||
TO_CHAR(K));
END LOOP;
END IF;
/*關閉資料寫入*/
UTL_SMTP.CLOSE_DATA(L_CONN);
/*關閉連線*/
UTL_SMTP.QUIT(L_CONN);
/*異常處理*/
EXCEPTION
WHEN OTHERS THEN
NULL;
RAISE;
END;
---------------------------------------------------主過程-----------------------------------------------------
BEGIN
L_SENDORADDRESS := '';
P_SPLITE_STR(P_RECEIVER);--處理郵件地址
FOR K IN 1 .. MY_ADDRESS_LIST.COUNT LOOP
P_EMAIL(L_SENDORADDRESS, MY_ADDRESS_LIST(K));
END LOOP;
/*處理郵件地址，根據逗號分割郵件*/
EXCEPTION
WHEN OTHERS THEN
RAISE;
END;
示例：
exec procsendemail('helloworld','hello test oracle email','xz@sina.com','xz@sina.com','郵件伺服器地址',25,1,'user','pwd','','bit 7');
注意：
1. 如果郵件伺服器地址不正確會出現類似這樣的錯誤：
第 1 行出現錯誤:
ORA-29278: SMTP 臨時性錯誤: 421 Service not available
ORA-06512: 在 "SYS.UTL_SMTP", line 21
ORA-06512: 在 "SYS.UTL_SMTP", line 97
ORA-06512: 在 "SYS.UTL_SMTP", line 139
ORA-06512: 在 line 4
2. 如果使用者名稱、密碼出現錯誤，則會報錯：
第 1 行出現錯誤:
ORA-29279: SMTP 永久性錯誤: 535 authorization failed (#5.7.0)
ORA-06512: 在 "SYS.UTL_SMTP", line 21
ORA-06512: 在 "SYS.UTL_SMTP", line 99
ORA-06512: 在 "SYS.UTL_SMTP", line 159
ORA-06512: 在 line 8
3.如果沒有將使用者名稱密碼進行編碼就直接傳送，會碰到下面的錯誤：
第 1 行出現錯誤:
ORA-29279: SMTP 永久性錯誤: 501 malformed auth input (#5.5.4)
ORA-06512: 在 "SYS.UTL_SMTP", line 21
ORA-06512: 在 "SYS.UTL_SMTP", line 99
ORA-06512: 在 "SYS.UTL_SMTP", line 159
ORA-06512: 在 line 7
4. 如果沒有設定使用者名稱、密碼，或者使用UTL_MAIL包連線到需要授權驗證的郵件伺服器，則會報錯如下：
第 1 行出現錯誤:
ORA-29279: SMTP 永久性錯誤: 554 auth login first
ORA-06512: 在 "SYS.UTL_SMTP", line 21
ORA-06512: 在 "SYS.UTL_SMTP", line 99
ORA-06512: 在 "SYS.UTL_SMTP", line 241
ORA-06512: 在 "SYS.UTL_MAIL", line 424
ORA-06512: 在 "SYS.UTL_MAIL", line 594
ORA-06512: 在 line 2
來自 “ ITPUB部落格 ” ，連結：http://blog.itpub.net/9399028/viewspace-687358/，如需轉載，請註明出處，否則將追究法律責任。
相關文章
- 利用sqlserver Job 及內嵌儲存過程傳送郵件SQLServer儲存過程
- 在SQL Server中使用儲存過程傳送電子郵件SQLServer儲存過程
- 功能較全的oracle傳送郵件過程Oracle
- 成功透過ORACLE傳送郵件Oracle
- Oracle郵件傳送Oracle
- 利用SqlServer系統儲存過程sp_send_dbmail傳送郵件例項（二）SQLServer儲存過程AI
- oracle中發郵件的儲存過程--功能比較強（摘）Oracle儲存過程
- 郵件的傳送
- 郵件傳送
- 傳送郵件
- 用oracle傳送電子郵件Oracle
- oracle 傳送郵件 實現方法Oracle
- 用Oracle傳送郵件procedure (zt)Oracle
- Oracle 發郵件過程Oracle
- Ubuntu的郵件傳送Ubuntu
- SpringBoot整合Mail傳送郵件&傳送模板郵件Spring BootAI
- Azure : 通過 SendGrid 傳送郵件
- BI Publisher通過MuseMail傳送郵件AI
- Java Mail 郵件傳送（二）：簡單封裝的郵件傳送JavaAI封裝
- Laravel 傳送郵件Laravel
- PHP傳送郵件PHP
- Django——郵件傳送Django
- java郵件傳送Java
- Laravel傳送郵件Laravel
- gmail傳送郵件AI
- java傳送郵件Java
- Powershell郵件傳送
- thinkphp 郵件傳送PHP
- centos 傳送郵件CentOS
- phpcms傳送郵件PHP
- 利用Oracle資料庫傳送郵件Oracle資料庫
- oracle的儲存過程Oracle儲存過程
- 使用 MailChimp 傳送郵件 + 調取 API 開發落地頁過程AIAPI
- 儲存過程 傳 datatable儲存過程
- 如何傳送電子郵件到別人郵箱？電子郵件傳送的方法
- 從sybase的儲存過程轉向oracle的儲存過程儲存過程Oracle
- Oracle儲存過程Oracle儲存過程
- golang傳送郵件（qq郵箱）Golang