Delphi寫小執行程式

象C語言一樣，用Delphi也能寫出只有幾十K、十幾K、甚至只有幾K的小程式，本文將 以一個能將Win95桌面藏起來的僅有38K的小程式為例教會讀者這一技巧，同時本文還 將涉及Win95 TrayIcon的顯示。

本程式能寫得很小的訣竅是：根本沒有用任何的 FORM 。也就是說，源程式只有一個 Desktop.dpr 檔案，程式完全用標準的 WINAPI 寫成，由於用到的資源很少，所以程式的體積也很小。當然，用這樣的方法程式設計時不能使用 Delphi的所見即所得的程式設計方式。}

{首先看看程式頭的寫法：}
program DeskPop;
uses Windows, Messages, ShellAPI, sysutils;
{$R *.RES}

{可以看出本程式比普通的 Delphi 程式用到的 Unit 少的多。 下面宣告瞭全域性常量和變數，暫時可以不管他們。}
const
AppName = 'DeskTop Hide';
var
x: integer;
tid: TNotifyIconData;
WndClass: array[0..50] of char;

{現在進入程式的主要部分，首先是定義了一批過程，為了能讓讀者更好地理解，我們先把這些過程跳過去，先說主程式。主程式位於程式的最後，這樣做的好處是可以直接使用程式中定義的過程。主程式十分簡單：}
begin
WinMain;
end.
{看來所有的工作都由 WinMain 完成了。這個 WinMain 使用標準的 WinAPI 函式進行程式設計，主要步驟是：先宣告一個視窗類，然後建立一個主視窗，最後進入訊息迴圈，直到程式結束。}

procedure WinMain;
var
Wnd: hWnd; {宣告視窗控制程式碼(Handle)變數}
Msg: TMsg; {宣告訊息變數}
cls: TWndClass; {視窗類變數}
begin
{ Previous instance running ? If so, exit }
{ 檢查是否程式已經執行，如果已經執行則呼叫Panic過程退出 }
if FindWindow (AppName, Nil) <> 0 then
Panic (AppName + ' is already running.');

{ Register the window class }
{ 這裡的註冊視窗類程式是例行公事，照抄即可}
FillChar (cls, sizeof (cls), 0); {用這一句將視窗類變數cls清零)
cls.lpfnWndProc := @DummyWindowProc; {取回撥函式DummyWindowProc的地址}
cls.hInstance := hInstance; {例項控制程式碼}
cls.lpszClassName := AppName; {視窗類名}
RegisterClass (cls); {註冊視窗類cls}

{ 現在可以建立程式的主視窗了-在本程式中是個虛擬視窗}
{ Now create the dummy window }
Wnd := CreateWindow (AppName, AppName, ws_OverlappedWindow,
cw_UseDefault, cw_UseDefault, cw_UseDefault, cw_UseDefault,
0, 0, hInstance, Nil);
x:= 0; {變數X其實是個開關變數，記錄現在是否已經隱藏了桌面}

{ 如果視窗建立成功，則顯示視窗，並進入訊息迴圈 }
if Wnd <> 0 then
begin
ShowWindow (Wnd, sw_Hide);{本例中視窗是隱藏的}
{ 下面進入訊息迴圈，該迴圈將不斷執行直到 GetMessage返回0 }
while GetMessage (Msg, 0, 0, 0) do
begin
TranslateMessage (Msg);
DispatchMessage (Msg);
end;
end;
end;

{現在看來，程式的主框架很明瞭，但是它還不能完成任何任務。過程 Panic將顯示一個對話方塊後退出程式，它在 Winmain 過程的開始部分被呼叫，其實 Panic的功能很簡單，之所以要寫成一個函式的原因恐怕一方面是結構化程式設計的需要，另一方面藉此避開了 String 和 PChar 的轉換。}
procedure Panic (szMessage: PChar);
begin
if szMessage <> Nil then
MessageBox (0, szMessage, AppName, mb_ok);
Halt (0);
end;

{下面是回撥(Callback)函式 DummyWindowProc，如果說 Winmain 過程是本程式-或者說是本應用或例項的生命，那麼這個回撥函式可以說是主視窗的靈魂。每一個標準的或者說是規範的Windows視窗都有一個回撥函式，以處理發給該視窗的訊息。所謂“回撥”的意思是這個函式不是由程式直接呼叫的，而是由 Windows 系統呼叫(還記得我們在視窗類中給lpfnWndProc賦過值嗎)， 這就是事件驅動程式設計。}
function DummyWindowProc (Wnd: hWnd; Msg, wParam: Word; lParam: LongInt)
:LongInt; stdcall; {注意這裡有一個 stdcall;定義了回撥函式}
var
TrayHandle: THandle;
dc: hDC;
i: Integer;
pm: HMenu;
pt: TPoint;
begin
DummyWindowProc := 0;
{下面兩句是找到 Win95 工作列的控制程式碼}
StrPCopy(@WndClass[0], 'Progman');
TrayHandle := FindWindow(@WndClass[0], nil);
{下面開始處理訊息}
case Msg of
{收到視窗建立訊息 - 在工作列上顯示一個圖示}
wm_Create: // Program initialisation - just set up a tray icon
begin
tid.cbSize := sizeof (tid);
tid.Wnd := Wnd;
tid.uID := 1;
tid.uFlags := nif_Message or nif_Icon or nif_Tip;
tid.uCallBackMessage := wm_User;
tid.hIcon := LoadIcon (hInstance, 'MAINICON');
lstrcpy (tid.szTip,'Desktop is on');
Shell_NotifyIcon (nim_Add, @tid);
end;

wm_Destroy: {收到關閉視窗訊息時的處理}
begin
Shell_NotifyIcon (nim_Delete, @tid);
PostQuitMessage (0);
ShowWindow(TrayHandle, SW_RESTORE);
end;
{收到選單訊息時呼叫 HandleCommand 過程，並退出函式}
wm_Command: // Command notification
begin
HandleCommand (Wnd, LoWord (wParam));
Exit;
end;
{收到其他使用者訊息時的處理}
wm_User: // Had a tray notification - see what to do
{如果單擊了滑鼠左鍵， 則開啟或關閉桌面}
if (lParam = wm_LButtonDown) then
begin
if x = 0 then
begin
ShowWindow(TrayHandle, SW_HIDE);
tid.hIcon := LoadIcon (hInstance, 'offICON');
lstrcpy (tid.szTip,'Desktop is off');
Shell_NotifyIcon (NIM_MODIFY, @tid);
x:=1
end else
begin
ShowWindow(TrayHandle, SW_RESTORE);
tid.hIcon := LoadIcon (hInstance, 'ONICON');
lstrcpy (tid.szTip,'Desktop is on');
Shell_NotifyIcon (NIM_MODIFY, @tid);
x:= 0;
end; {end of if}
end else
{如果是滑鼠右鍵，則動態生成一個彈出式選單}
if (lParam = wm_RButtonDown) then
begin
GetCursorPos (pt);
pm := CreatePopupMenu;
AppendMenu (pm, 0, Ord ('A'), 'About DeskTop Hide...');
AppendMenu (pm, mf_Separator, 0, Nil);
AppendMenu (pm, 0, Ord ('E'), 'Exit DeskTop Hide');
SetForegroundWindow (Wnd);
dc := GetDC (0);
if TrackPopupMenu (pm, tpm_BottomAlign or tpm_RightAlign,
pt.x,GetDeviceCaps(dc,HORZRES){pt.y}, 0, Wnd, Nil)
then SetForegroundWindow (Wnd);
DestroyMenu (pm)
end; {end of if}
end; {end of case}
{在處理過訊息之後，還要呼叫預設函式，以完成標準的Windows程式應該執行的任務，所以這一句非常重要}
DummyWindowProc := DefWindowProc (Wnd, Msg, wParam, lParam);
end;

{這個就是處理選單訊息的過程}
procedure HandleCommand (Wnd: hWnd; Cmd: Word);
begin
case Cmd of
Ord ('A'): MessageBox (0, 'Freeware brian.slack@strath.ac.uk 1997',
AppName, mb_ok);
Ord ('E'): PostMessage (Wnd, wm_Close, 0, 0);
end;
end;

至此我們已經完成了這個只有38K的能將Win95桌面隱藏起來的程式，只要將本文中所有的函式和過程的順序倒置，並將主程式放到最後，即可編譯透過。