Groovy高效程式設計——‘匕首方法’的使用

will的猜想發表於2017-11-08
程式設計
Groovy提供了許多‘匕首方法’（匕首，短小精悍也～如each，eachWithIndex，any，every，grep，join，sort，find，findAll，collect，groupBy，inject，reverse，tokenize, unique，max，min，count，sum等）來提升開發者的開發效率，但常被Java開發人員忽視。在這篇隨筆中我將為您演示各方法的使用。 

each 
遍歷list
def list = ['a', 'b', 'c']
list.each { elem ->
  println elem
}
執行結果：
a
b
c

遍歷map
def map = [name:"山風小子", address:"Shanghai"]
map.each { key, value ->
  println "$key : $value"
}
執行結果：
name : 山風小子
address : Shanghai

eachWithIndex
帶index的each
def list = ['a', 'b', 'c']
list.eachWithIndex { elem, i ->
  println "$i : $elem"
}
執行結果：
0 : a
1 : b
2 : c

any
只要存在一個滿足條件（此例中的條件為elem.length() < 3）的element就返回true，否則返回false
def list = ['a', 'ab', 'abc']
list.any { elem -> 
  elem.length() < 3
}
執行結果：
true

every
所有的element都滿足條件才返回true，否則返回false
def list = ['a', 'ab', 'abc']
list.every { elem -> 
  elem.length() < 3
}
執行結果：
false

grep
符合條件的element會被提取出來，形成一個list
條件以closure的形式傳入
def list = ['a', 'ab', 'abc']
list.grep { elem ->
  elem.length() < 3
}
執行結果：
["a", "ab"]

條件以regex的形式傳入，符合regex的element被提取出來形成一個list
def list = ['a', 'ab', 'abc']
list.grep(~/../)
執行結果：
["ab"]

條件以collection的形式傳入，在collection中的element被提取出來形成一個list，可以看作求兩個collection的交集
def list = ['a', 'ab', 'abc']
list.grep(['a', 'cde', 'ab'])
執行結果：
["a", "ab"]

join
用指定的字元連線collection中的element
def list = [2007, 8, 26]
list.join('-')
執行結果：
2007-8-26

sort
根據指定條件進行排序
def list = [2007, 8, 26]
list.sort { e1, e2 ->
  return e1 - e2
}
執行結果：
[8, 26, 2007]

find
查詢collection中滿足條件的‘第一個’element
def list = [2007, 8, 26]
list.find { elem ->
  elem <30
}
執行結果：
8

findAll
查詢collection中滿足條件的‘所有’element
def list = [2007, 8, 26]
list.findAll { elem ->
  elem < 30
}
執行結果：
[8, 26]

collect
對collection的element進行處理，並將處理結果放到一個新的collection中
def list = ['a', 'b', 'c']
list.collect { elem ->
  elem * 2
}
執行結果：
["aa", "bb", "cc"]

對map進行處理
def map = [name:'山風小子', address:'Shanghai']
map.collect { entry ->
  "${entry.key} : ${entry.value}"
}
執行結果：
[name : 山風小子, address : Shanghai]


groupBy
對collection中的element按給定條件進行分組
def list = ['a', 'b', 'abc', 'ab', 'c', 'bc']
list.groupBy { elem ->
    elem.length()
}
執行結果：
[1:["a", "b", "c"], 2:["ab", "bc"], 3:["abc"]]


inject
一個累積的過程，傳入inject方法的'I'作為sum的初始值，在遍歷collection的過程中，將處理結果("$sum $elem ")儲存到sum中
def list = ["love", "you"]
list.inject('I') { sum, elem -> 
  "$sum $elem "
}
執行結果：
I love  you 

reverse
將collection中各element的次序顛倒一下
def list = ['a', 'b', 'c']
list.reverse()
執行結果：
["c", "b", "a"]

顛倒字串
def list = 'abc'
list.reverse()
執行結果：
cba

tokenize
指定分隔符，取得token集
'a1/b2/c3/d4'.tokenize('/')
執行結果：
["a1", "b2", "c3", "d4"]

unique
去除collection中重複的element
def list = ['a', 'b', 'b', 'a', 'c']
list.unique()
執行結果：
["a", "b", "c"]


max
求最大值
def list = [1, 2, 3]
list.max()
執行結果：
3

按指定的比較內容（此例的比較內容為長度length），在collection中選出最大的element
def list = ['a', 'ab', 'abc']
list.max { elem ->
  elem.length()
}

min與max類似，求最小值，再次就不演示用法了，用法與max相同，將上述程式碼中的max改為min即可

count
計數
def list = ['a', 'ab', 'a']
list.count('a')
執行結果：
2

對字串"aaba"中的a進行計數
def list = "aaba"
list.count('a')
執行結果：
3

sum
求和
def list = [1, 2, 3]
list.sum()
執行結果：
6

求字串的‘和’，其實就是連線字串
def list = ['a', 'b', 'c']
list.sum()
執行結果：
abc

相關文章